gentoo resync : 21.09.2018

4 files changed, 158 insertions, 13 deletions

diff --git a/www-client/links/Manifest b/www-client/links/Manifest
index 844b9a7b0cbb..9537fb4ecdc8 100644
--- a/www-client/links/Manifest
+++ b/www-client/links/Manifest
@@ -1,7 +1,7 @@
 DIST links-2.14.tar.bz2 6535707 BLAKE2B e0a2f804e05fde94be50ee2dce1453c0c616aac29bd91a73f78b1976119aa5cfa8aa4b3df5e7feeb193bba74fbe3b32be50f4947babb4115a3e79835c2c241fb SHA512 d03b091957e0a2e06605fcf7c9bc56d48ebbcdc695f4ce894901540008455a9bc6544abdecd787faa041e2dbdff28b0d6ddcc9d26528d39d7d72750655c73575
 DIST links-2.16.tar.bz2 6697222 BLAKE2B dba0f00acf14e7994d3eeea7f77df897941690d959c2aa90924bb1256f310a6ddc969e2dc7ca8ca775f2ec06acebbabb30b35088a9cc6100b01f7fa6dfaeaaa8 SHA512 3ce169e214eae0f997c1f8647d354dc0803c9118a97dcd2594d62af23336890272f4b027d3ab0a0e151672d1506e50da0f0e561999c5841f0f183f32a279b14a
-DIST links2_2.10-2.debian.tar.xz 13964 BLAKE2B 2de4e49281a53d37d3d9bc53b5e49c3bac534f3ba5d7a57748f3ef998e6ff7f5309b5d6c7a00f72d623525fc1413fc15d1585ffa84c186d684467539cb807cef SHA512 01101edef00ede0b95857ea28d305e98198306c428b79bb9c05da16285d8b4052b7f800f7def67a945d498db440745d81b7e3b6a03c9b077d5bcf5da1cb2691e
-DIST links2_2.14-5.debian.tar.xz 15332 BLAKE2B 20c1d0f5a9eeac2f56bfc8d2e00f343ada5ac28e741fdb9635810f7e39563f0f052f7be0492923c3caf6f000246639bf3ae19ebd5dfb3d8fdfe4e4655dd0bac8 SHA512 d8038515c29998be9510723cdaa2b961d65141fd0b0f863e2fac80f41009a100f0bd824acd97735d089c932c1b5a979f0ed523d773721485b4418ec44df38872
-EBUILD links-2.14-r1.ebuild 3262 BLAKE2B b36cb0efef6a64cbdda852843f94b1c628e5fbf834682f827703c78428350a2b2e43797d62a2e266cda5995a333951ba1324e206a4e7f8459bbc2791b595d3fb SHA512 fdedb189b11a0583e9f3fb492764b34397677b826da1963c39ff714449e53bc2741f9d942534089af0e52de5c8214833506f9693c754854b325970e491574f15
-EBUILD links-2.16.ebuild 3274 BLAKE2B 9f581eb2186c4ed5a0807b7620af67cde5362548cd2c887abd3d99fbf77a932a36fe3a48844185943f807d5892ce70237e3e8751ef4dadaa89c31fb5ac1c8772 SHA512 4aee5abcd8d78fecdbe64842d9010858640c2feefe644d7eeb7a9037aedb6f92dca6066d2606b0c140f505d2343971758f70d4052d27dc350010dd80d8aaa1b4
+DIST links-2.17.tar.bz2 6694577 BLAKE2B a762dd810d8d939c3276ca13ed8460cc486d275e3436015440527fdbe16adc29ccf4ff26c59de2354c50cab5fbc6ce72d4b94cc6e731e4295f86f892eaf0af64 SHA512 871a3a2cbc210467f4ffd830ba2966f2ebc0ec9ed4a1de018d032cec4b550e58f6858875478647c627ec746bb76810a4b97603575f2d21b5ea650c612684c8d5
+EBUILD links-2.14-r1.ebuild 3154 BLAKE2B 2a7da112c77549c395a25ef5e10e07370f4cef1662b7165f26757b56db9752389bfdea21c24f2ab6d579a9673bad742dab3450280ee9fb37483bd4e6a26e0859 SHA512 7466c89b39e13047cb68de185499bab9e8d89fb6df88610104bf3e8f0693fc0d3f2c03817a5b12de66e63344d07bb318e2675360a29ddf1a03c31797434a3b4e
+EBUILD links-2.16.ebuild 3164 BLAKE2B f6eabfc12eefb0bf2cb96ec494ee464c0c581afca3b4e4142f616e007122158d9bb0c8ef06acf26860377a1c84dbd7eb1b2ef3697604ab9b783a886046c938d0 SHA512 f28d9f11d8a1bf6e156b9ca79a0160861fd5fbb2c3dac81b5c690623e22e1966b0c59fd11134fcf5687b2906a33d537983082e2f1cb0fc7d57485b1328901cbd
+EBUILD links-2.17.ebuild 3164 BLAKE2B f6eabfc12eefb0bf2cb96ec494ee464c0c581afca3b4e4142f616e007122158d9bb0c8ef06acf26860377a1c84dbd7eb1b2ef3697604ab9b783a886046c938d0 SHA512 f28d9f11d8a1bf6e156b9ca79a0160861fd5fbb2c3dac81b5c690623e22e1966b0c59fd11134fcf5687b2906a33d537983082e2f1cb0fc7d57485b1328901cbd
 MISC metadata.xml 345 BLAKE2B 5d91a968b8b9185cc9c61d02a1980369e5cf8c87bef6a5de4e05d3b375473548d3cbec311920d52cd7aad4517fbc2ddb2d900d520e5b1d2b3445e1424ac16662 SHA512 40528fd846439acf44ddf1e49a65d7195aecb6d78e9d20d3d734fbb48b4cef842975cbe8383a8feba6e6894ebe0fa6b7cbc27c1ac663cc563aa1e8884e09c7d9
diff --git a/www-client/links/links-2.14-r1.ebuild b/www-client/links/links-2.14-r1.ebuild
index c7f507092747..c7d830ce887c 100644
--- a/www-client/links/links-2.14-r1.ebuild
+++ b/www-client/links/links-2.14-r1.ebuild
@@ -5,12 +5,9 @@ EAPI=6
 
 inherit autotools desktop xdg
 
-DEBIAN_REVISION=2.10-2
-
 DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
 HOMEPAGE="http://links.twibright.com/"
-SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2
-	mirror://debian/pool/main/${PN:0:1}/${PN}2/${PN}2_${DEBIAN_REVISION}.debian.tar.xz"
+SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2"
 
 LICENSE="GPL-2"
 SLOT="2"
diff --git a/www-client/links/links-2.16.ebuild b/www-client/links/links-2.16.ebuild
index fc5b0de6a65b..de56fbdef90b 100644
--- a/www-client/links/links-2.16.ebuild
+++ b/www-client/links/links-2.16.ebuild
@@ -5,13 +5,9 @@ EAPI=6
 
 inherit autotools desktop xdg
 
-DEBIAN_REVISION=2.14-5
-
 DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
 HOMEPAGE="http://links.twibright.com/"
-SRC_URI="
-	http://${PN}.twibright.com/download/${P}.tar.bz2
-	mirror://debian/pool/main/${PN:0:1}/${PN}2/${PN}2_${DEBIAN_REVISION}.debian.tar.xz"
+SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2"
 
 LICENSE="GPL-2"
 SLOT="2"
diff --git a/www-client/links/links-2.17.ebuild b/www-client/links/links-2.17.ebuild
new file mode 100644
index 000000000000..de56fbdef90b
--- /dev/null
+++ b/www-client/links/links-2.17.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools desktop xdg
+
+DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
+HOMEPAGE="http://links.twibright.com/"
+SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 fbcon gpm ipv6 jpeg libevent libressl livecd lzma ssl suid svga tiff unicode X zlib"
+
+GRAPHICS_DEPEND="media-libs/libpng:0="
+
+RDEPEND="
+	bzip2? (
+		app-arch/bzip2
+	)
+	fbcon? (
+		${GRAPHICS_DEPEND}
+	)
+	gpm? (
+		sys-libs/gpm
+	)
+	jpeg? (
+		virtual/jpeg:0
+	)
+	libevent? (
+		dev-libs/libevent:0=
+	)
+	livecd? (
+		${GRAPHICS_DEPEND}
+		sys-libs/gpm
+		virtual/jpeg:0
+	)
+	lzma? (
+		app-arch/xz-utils
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	svga? (
+		${GRAPHICS_DEPEND}
+		media-libs/svgalib
+	)
+	tiff? (
+		media-libs/tiff:0
+	)
+	X? (
+		${GRAPHICS_DEPEND}
+		x11-libs/libXext
+	)
+	zlib? (
+		sys-libs/zlib
+	)"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	fbcon? ( virtual/os-headers )
+	livecd? ( virtual/os-headers )"
+
+REQUIRED_USE="!livecd? ( fbcon? ( gpm ) )
+	svga? ( suid )"
+
+DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
+
+src_prepare() {
+	xdg_src_prepare
+
+	if use unicode; then
+		pushd intl > /dev/null || die
+		./gen-intl || die
+		./synclang || die
+		popd > /dev/null || die
+	fi
+
+	# error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
+	sed -i \
+		-e '/AC_PROG_CXX/s:dnl ::' \
+		-e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' \
+		configure.in || die #467020
+
+	# Upstream configure produced by broken autoconf-2.13. This also fixes
+	# toolchain detection.
+	mv configure.in configure.ac || die
+	eautoreconf #131440 and #103483#c23
+}
+
+src_configure() {
+	local myconf
+
+	if use livecd; then
+		export ac_cv_lib_gpm_Gpm_Open=yes
+		myconf+=' --with-fb --with-libjpeg'
+	else
+		export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
+	fi
+
+	if use X || use fbcon || use svga || use livecd; then
+		myconf+=' --enable-graphics'
+	fi
+
+	econf \
+		--without-directfb \
+		$(use_with ipv6) \
+		$(use_with ssl) \
+		$(use_with zlib) \
+		$(use_with bzip2) \
+		$(use_with lzma) \
+		$(use_with svga svgalib) \
+		$(use_with X x) \
+		$(use_with fbcon fb) \
+		$(use_with libevent) \
+		$(use_with jpeg libjpeg) \
+		$(use_with tiff libtiff) \
+		${myconf}
+}
+
+src_install() {
+	HTML_DOCS="doc/links_cal/*"
+	default
+
+	if use X; then
+		newicon Links_logo.png links.png
+		make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
+		local d="${ED}"/usr/share/applications
+		echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop || die
+		if use ssl; then
+			sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
+			"${d}"/*.desktop || die
+		fi
+	fi
+
+	use suid && fperms 4755 /usr/bin/links
+}
+
+pkg_preinst() {
+	use X && xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	use X && xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	use X && xdg_pkg_postrm
+}