gentoo auto-resync : 23:09:2022 - 23:30:45

1 files changed, 47 insertions, 0 deletions

diff --git a/www-apps/owncloud/owncloud-10.11.0.ebuild b/www-apps/owncloud/owncloud-10.11.0.ebuild
new file mode 100644
index 000000000000..71d8e6808dff
--- /dev/null
+++ b/www-apps/owncloud/owncloud-10.11.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit webapp
+
+DESCRIPTION="Web-based storage application where all your data is under your own control"
+HOMEPAGE="https://owncloud.org"
+SRC_URI="https://download.owncloud.com/server/stable/${P}.tar.bz2"
+LICENSE="AGPL-3"
+
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+curl mysql postgres +sqlite"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+DEPEND=""
+RDEPEND=">=dev-lang/php-7.0[curl?,filter,gd,hash(+),intl,json(+),mysql?,pdo,posix,postgres?,session,simplexml,sqlite?,xmlreader,xmlwriter,zip]
+	virtual/httpd-php"
+
+S=${WORKDIR}/${PN}
+
+pkg_setup() {
+	webapp_pkg_setup
+}
+
+src_install() {
+	webapp_src_preinst
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+	dodir "${MY_HTDOCSDIR}"/data
+
+	webapp_serverowned -R "${MY_HTDOCSDIR}"/apps
+	webapp_serverowned -R "${MY_HTDOCSDIR}"/data
+	webapp_serverowned -R "${MY_HTDOCSDIR}"/config
+	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	elog "Additional applications (calendar, ...) are no longer provided by default."
+	elog "You can install them after login via the applications management page"
+	elog "(check the recommended tab). No application data is lost."
+	webapp_pkg_postinst
+}