gentoo auto-resync : 15:08:2023 - 21:27:55

3 files changed, 87 insertions, 0 deletions

diff --git a/sys-power/autosuspend/Manifest b/sys-power/autosuspend/Manifest
new file mode 100644
index 000000000000..01cd2c87495d
--- /dev/null
+++ b/sys-power/autosuspend/Manifest
@@ -0,0 +1,3 @@
+DIST autosuspend-5.0.0.gh.tar.gz 179353 BLAKE2B 747f06ea84304acfeca78aa413745c56a63506be039696968e94a43199ee9e4cfa080b187b284a60e16e03bd22674973eaa7ed4728727016a05de12aca94fc9e SHA512 4d1d14e2cc8c7dc7ed1bfa41556ea8afe51785cef3965863fe307469a13f865b76df9a53c531aefef18308a2d57867631d86d59ea189cc56a108f1bdeaf4d369
+EBUILD autosuspend-5.0.0.ebuild 1749 BLAKE2B 52778e6969a283a1c393b14494786dce42977412ac974d4938159152756e173cba8c8579741c6537220a30e80c7a1d7344b4212dbfc431a986e10619f7b8f12f SHA512 5612dd35318b9d4e8058f912fbb3dcf5204e2ebde7a19fadff7ebb430baaf12126bbaa2add22c33146fdc7e230b3063a29ead1df17f0cc6fdcd11d16861b1b00
+MISC metadata.xml 416 BLAKE2B 9dcebfd78a698f4e5af188a1dc6e23a78ea6691da624f31951d14df92351c651d84632b14dcce43eeb69a5248ab4a3fe7c7f2c85d41128fb48022da3cddf88c5 SHA512 c8a7aa757cf2a8d9c6482d3926f7a5c2d3870e91b8a84125d5ff67eb44ba8d475270ac9dc91c60e3f3b8550f5ed82b3faa3e126adbd3dd7a1317c978b7b6614c
diff --git a/sys-power/autosuspend/autosuspend-5.0.0.ebuild b/sys-power/autosuspend/autosuspend-5.0.0.ebuild
new file mode 100644
index 000000000000..eb6e1694c159
--- /dev/null
+++ b/sys-power/autosuspend/autosuspend-5.0.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="A daemon to automatically suspend and wake up a system"
+HOMEPAGE="
+	https://github.com/languitar/autosuspend
+	https://autosuspend.readthedocs.io
+"
+SRC_URI="
+	https://github.com/languitar/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dbus mpd test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/portalocker[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	mpd? ( dev-python/python-mpd2[${PYTHON_USEDEP}] )
+"
+
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/icalendar[${PYTHON_USEDEP}]
+		dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/pytest-datadir[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		dev-python/python-mpd2[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/tzlocal[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	tests/test_checks_util.py::TestNetworkMixin::test_file_url
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc/source \
+						dev-python/furo \
+						dev-python/recommonmark \
+						dev-python/sphinx-autodoc-typehints \
+						dev-python/sphinx-issues \
+						dev-python/sphinxcontrib-plantuml
+
+python_test() {
+	# Disable code coverage in tests by setting addopts to the empty value.
+	epytest -o addopts=
+}
+
+src_install() {
+	distutils-r1_src_install
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/sys-power/autosuspend/metadata.xml b/sys-power/autosuspend/metadata.xml
new file mode 100644
index 000000000000..619a131e65bd
--- /dev/null
+++ b/sys-power/autosuspend/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Florian Schmaus</name>
+		<email>flow@gentoo.org</email>
+	</maintainer>
+	<use>
+		<flag name="mpd">Enable support for the Music Player Daemon</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">languitar/autosuspend</remote-id>
+	</upstream>
+</pkgmetadata>