gentoo resync : 03.11.2019

3 files changed, 180 insertions, 4 deletions

diff --git a/sys-libs/readline/Manifest b/sys-libs/readline/Manifest
index 6f40cecaaf81..ea700212ee67 100644
--- a/sys-libs/readline/Manifest
+++ b/sys-libs/readline/Manifest
@@ -24,7 +24,8 @@ DIST readline70-004 1501 BLAKE2B cebce69a21bee3a4d6a908de09f371d65eab6af51a8dc0f
 DIST readline70-005 1641 BLAKE2B f720508f698b113c6328018f7e6e8775c7c79afc464047405a5c3dae017d611535017dfc2759c11483bb536fab1e9bf72c7a9d3c769b7aea3bd2cee9686bd522 SHA512 eeb27f4f9195cb905d5891f26480d58f59c885dde3457f7a30ff57760ac772e2333ee8aeae979214949f3b52030285b10db013e307ee7311abab677a4427e878
 DIST readline80-001 927 BLAKE2B 95e3ac33ff4adb65813274864c17781056a8ea065f9a76571b4a6bcb2ebab090c3a021fa2b621832c11b5995e48a8a26dd6e3a8f5864a8e8b520bfcf85d7c4ab SHA512 a148cda6ac97935d51ede1bbacf847d7d2cba8861cf3941d32e3da2f45f16dcc05b20845b63d4264692520db8329e1236cf2bc4fd8ccbe6e40921bbbdeb2cb1c
 EBUILD readline-6.3_p8-r3.ebuild 4368 BLAKE2B b9308a93bbedafd88a53d72b7011c2e0c57c8ba3be64cc19769ccd72ee22bf32e314def9607477d3e1749064245b6e32311c35efeeb20f715fcf2b67e38328c2 SHA512 adca104b265358729e3e736bbb5c1261c3f63b76e8d32db1b460060d9481f4bf7ee3d2d0d662659fc8b1a841bfb80bfb1b4394f4885160070a570031ef270f8a
-EBUILD readline-7.0_p5.ebuild 4821 BLAKE2B ec04ad644d658e46329030b2b970c9b6b69b41d81fe24c90902170976f65dc276cd0fdde91a24ec3e811c6259af9481835c693ef1d7120c85d2091b08f98a26d SHA512 b64a43ce5eafa885a6b8665735241c85b75d5d9523cc62e60b73e4dba7bfee8be655a41f9bdf0eff99c7e57c761de26f9ac860126c901af673fe0af93803c78d
+EBUILD readline-7.0_p5-r1.ebuild 4859 BLAKE2B d35369cacab95a988b8d5168ccdfc45e3a66b08483e6a0359b89adab78d5a3e90f3d893c544c3e36c3462b0cc3b0fa40620ca1a6f56f52f8d0169e49d71fda97 SHA512 861600127c9c1015182d70e264787079fa2d3e583bc5bd9b2b8ce6e0369e08172d03bf6daa1776d276ee275605c45b246b5f4f9460dbcacd5817c8200a9a5bec
 EBUILD readline-8.0.ebuild 4790 BLAKE2B 42833b30980fc6593bf4d21a74866467f23c5814c7eed4f26cfbe16343f78c99ae2b4c340e2f8b893a8ba728e6f677ffda22e451eca6bc539a0ac8113a6a5f79 SHA512 f8763e2bb3900626e4392bf0afb8672778f105bcaad146b61a78cab36f6b4a5fcf14b019a202c514b73f64353af0b42ac320c81fc9ca12881c034f82daec7ec6
+EBUILD readline-8.0_p1-r1.ebuild 4856 BLAKE2B e2196b310a064d321278860c53eccfefedfec9411c11f632281496b9dff318a01e18156d7539bb35dc6366a2f025ca4211aba2cd8b8b70b8e05566c2d7188f6b SHA512 8d8709911c6fb4387097ec6d37334cb59b669a4eaa7ff0b4e0c171ca351e24f3008eabc44ba81a9214251412ee624668bee33b9396af3e818d3113ef25efe4ab
 EBUILD readline-8.0_p1.ebuild 4818 BLAKE2B 9088e7a27a355c2ee20e5ce491196b806df4480597a949c2a3191f306845abda51669aac2e9bfecd44fcd62a914f66c1ea789393ed6bf62bd1e2a66afab8181a SHA512 d414288e8c571712d311c874c1150ba1271bc48e574f3768eca30e4d8a99548b83d840a8e6356782d80d8bdec9de15ec39cbf93aa35c4ceaba1d53a03f767c58
 MISC metadata.xml 472 BLAKE2B 8d3717ac6980105677b10449a1aabca9f9347066f73802241b904101172690bb789b8071f3670dd91ad2af0223c7bc5fb4ed594dc8af3aff20b17bdd681f7630 SHA512 f19a6f0d6aed18903778adc5ad45fdae39c4388e4f09e7cb8a110b798e8cc7ab1739ff813a227ad08ef1166309e1ead57c200b7fe42499a06db97af9f4bce173
diff --git a/sys-libs/readline/readline-7.0_p5.ebuild b/sys-libs/readline/readline-7.0_p5-r1.ebuild
index 04e6ade437a4..0facdfe5f115 100644
--- a/sys-libs/readline/readline-7.0_p5.ebuild
+++ b/sys-libs/readline/readline-7.0_p5-r1.ebuild
@@ -42,9 +42,9 @@ esac
 LICENSE="GPL-3"
 SLOT="0/7"  # subslot matches SONAME major
 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 ~riscv s390 sh sparc x86 ~amd64-linux ~x86-linux"
-IUSE="static-libs utils"
+IUSE="static-libs +unicode utils"
 
-RDEPEND=">=sys-libs/ncurses-5.9-r3:0=[static-libs?,${MULTILIB_USEDEP}]"
+RDEPEND=">=sys-libs/ncurses-5.9-r3:0=[static-libs?,unicode?,${MULTILIB_USEDEP}]"
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
@@ -70,7 +70,7 @@ src_prepare() {
 
 	# Force ncurses linking. #71420
 	# Use pkg-config to get the right values. #457558
-	local ncurses_libs=$($(tc-getPKG_CONFIG) ncurses --libs)
+	local ncurses_libs=$($(tc-getPKG_CONFIG) ncurses$(usex unicode w '') --libs)
 	sed -i \
 		-e "/^SHLIB_LIBS=/s:=.*:='${ncurses_libs}':" \
 		support/shobj-conf || die
diff --git a/sys-libs/readline/readline-8.0_p1-r1.ebuild b/sys-libs/readline/readline-8.0_p1-r1.ebuild
new file mode 100644
index 000000000000..6b36ff730e5f
--- /dev/null
+++ b/sys-libs/readline/readline-8.0_p1-r1.ebuild
@@ -0,0 +1,175 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic multilib-minimal preserve-libs toolchain-funcs usr-ldscript
+
+# Official patches
+# See ftp://ftp.cwru.edu/pub/bash/readline-7.0-patches/
+PLEVEL="${PV##*_p}"
+MY_PV="${PV/_p*}"
+MY_PV="${MY_PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+[[ ${PV} != *_p* ]] && PLEVEL=0
+patches() {
+	[[ ${PLEVEL} -eq 0 ]] && return 1
+	local opt=$1
+	eval set -- {1..${PLEVEL}}
+	set -- $(printf "${PN}${MY_PV/\.}-%03d " "$@")
+	if [[ ${opt} == -s ]] ; then
+		echo "${@/#/${DISTDIR}/}"
+	else
+		local u
+		for u in ftp://ftp.cwru.edu/pub/bash mirror://gnu/${PN} ; do
+			printf "${u}/${PN}-${MY_PV}-patches/%s " "$@"
+		done
+	fi
+}
+
+DESCRIPTION="Another cute console display library"
+HOMEPAGE="https://tiswww.case.edu/php/chet/readline/rltop.html"
+
+case ${PV} in
+	*_alpha*|*_beta*|*_rc*)
+		SRC_URI+=" ftp://ftp.cwru.edu/pub/bash/${MY_P}.tar.gz"
+	;;
+	*)
+		SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.gz $(patches)"
+	;;
+esac
+
+LICENSE="GPL-3"
+SLOT="0/8"  # subslot matches SONAME major
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs +unicode utils"
+
+RDEPEND=">=sys-libs/ncurses-5.9-r3:0=[static-libs?,unicode?,${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.0-no_rpath.patch
+	"${FILESDIR}"/${PN}-6.2-rlfe-tgoto.patch #385091
+	"${FILESDIR}"/${PN}-7.0-headers.patch
+	"${FILESDIR}"/${PN}-8.0-headers.patch
+)
+
+# Needed because we don't want the patches being unpacked
+# (which emits annoying and useless error messages)
+src_unpack() {
+	unpack ${MY_P}.tar.gz
+}
+
+src_prepare() {
+	[[ ${PLEVEL} -gt 0 ]] && eapply -p0 $(patches -s)
+	default
+
+	# Force ncurses linking. #71420
+	# Use pkg-config to get the right values. #457558
+	local ncurses_libs=$($(tc-getPKG_CONFIG) ncurses$(usex unicode w '') --libs)
+	sed -i \
+		-e "/^SHLIB_LIBS=/s:=.*:='${ncurses_libs}':" \
+		support/shobj-conf || die
+	sed -i \
+		-e "/^[[:space:]]*LIBS=.-lncurses/s:-lncurses:${ncurses_libs}:" \
+		examples/rlfe/configure || die
+
+	# fix building under Gentoo/FreeBSD; upstream FreeBSD deprecated
+	# objformat for years, so we don't want to rely on that.
+	sed -i -e '/objformat/s:if .*; then:if true; then:' support/shobj-conf || die
+
+	ln -s ../.. examples/rlfe/readline || die # for local readline headers
+}
+
+src_configure() {
+	# fix implicit decls with widechar funcs
+	append-cppflags -D_GNU_SOURCE
+	# https://lists.gnu.org/archive/html/bug-readline/2010-07/msg00013.html
+	append-cppflags -Dxrealloc=_rl_realloc -Dxmalloc=_rl_malloc -Dxfree=_rl_free
+
+	# Make sure configure picks a better ar than `ar`. #484866
+	export ac_cv_prog_AR=$(tc-getAR)
+
+	# Force the test since we used sed above to force it.
+	export bash_cv_termcap_lib=ncurses
+
+	# Control cross-compiling cases when we know the right answer.
+	# In cases where the C library doesn't support wide characters, readline
+	# itself won't work correctly, so forcing the answer below should be OK.
+	if tc-is-cross-compiler ; then
+		use kernel_Winnt || export bash_cv_func_sigsetjmp='present'
+		export bash_cv_func_ctype_nonascii='yes'
+		export bash_cv_wcwidth_broken='no' #503312
+	fi
+
+	# This is for rlfe, but we need to make sure LDFLAGS doesn't change
+	# so we can re-use the config cache file between the two.
+	append-ldflags -L.
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--cache-file="${BUILD_DIR}"/config.cache
+		--with-curses
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+
+	if use utils && multilib_is_native_abi && ! tc-is-cross-compiler ; then
+		# code is full of AC_TRY_RUN()
+		mkdir -p examples/rlfe || die
+		cd examples/rlfe || die
+		ECONF_SOURCE="${S}"/examples/rlfe \
+		econf --cache-file="${BUILD_DIR}"/config.cache
+	fi
+}
+
+multilib_src_compile() {
+	emake
+
+	if use utils && multilib_is_native_abi && ! tc-is-cross-compiler ; then
+		# code is full of AC_TRY_RUN()
+		cd examples/rlfe || die
+		local l
+		for l in readline history ; do
+			ln -s ../../shlib/lib${l}$(get_libname)* lib${l}$(get_libname) || die
+			ln -s ../../lib${l}.a lib${l}.a || die
+		done
+		emake
+	fi
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi ; then
+		gen_usr_ldscript -a readline history #4411
+
+		if use utils && ! tc-is-cross-compiler; then
+			dobin examples/rlfe/rlfe
+		fi
+	fi
+}
+
+multilib_src_install_all() {
+	HTML_DOCS="doc/history.html doc/readline.html doc/rluserman.html" einstalldocs
+	dodoc USAGE
+	docinto ps
+	dodoc doc/*.ps
+}
+pkg_preinst() {
+	# bug #29865
+	# Reappeared in #595324 with paludis so keeping this for now...
+	preserve_old_lib /$(get_libdir)/lib{history,readline}.so.{4,5,6,7}
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /$(get_libdir)/lib{history,readline}.so.{4,5,6,7}
+}