gentoo resync : 20.03.2022

3 files changed, 229 insertions, 2 deletions

diff --git a/sys-libs/libxcrypt/Manifest b/sys-libs/libxcrypt/Manifest
index e211b022f112..7004e3b6c94c 100644
--- a/sys-libs/libxcrypt/Manifest
+++ b/sys-libs/libxcrypt/Manifest
@@ -3,8 +3,10 @@ DIST libxcrypt-4.4.20-autotools.tar.xz 628688 BLAKE2B 4c23af2a765495758e52c8e95d
 DIST libxcrypt-4.4.25-autotools.tar.xz 614652 BLAKE2B f0f4fbf92585fdd8d328aaa68811ea15bdf75778363ea4bc46a75fb76bb065f044708446d655356ebbf2834f8b14bac40fbe700b510b09ce101f750667a04298 SHA512 30f38a54c8e5cbd31c463223913079f9869d38ed38a2f64c57778ac4cf1b6f557caa527073df54ca8396bb7220807b84afcae2f9790f6604af1561a4b277874e
 DIST libxcrypt-4.4.26-autotools.tar.xz 617808 BLAKE2B 9fb8e31b22a085c0d0d5ab2ee3fb69fbebaccee2281e9be7d745218b5b92d949ffd3aa9c385671d58c93a654e16b943a33284b0b4737d52d26e43e2f7840fe74 SHA512 22c72cacd87c5751c4160413738fdf52c8fee300dcad01b289a6eaf892439883b9478103f791f5f53c8e5e2f2dd81057e5fda45e7cf7fdfd3ba93dd811bc01e3
 DIST libxcrypt-4.4.27-autotools.tar.xz 619240 BLAKE2B 13dd5730fded0684c8e7321fee8a786663ff1080a6ca248bd718c4f6c9f6bd2853689c347be9f9ae51ebc1281aaa2143dfc020149382d259e7eefe66ac8b675e SHA512 f13ae1e69bf5850abb47a28f9ac3e3b0a8b3123adc53d39fd39a26d53847bf6e3fdca751e086cd80ce4e5d9ee419b09148c247cbe5f663b3019b66f82cdc5f5c
+DIST libxcrypt-4.4.28-autotools.tar.xz 618560 BLAKE2B c56d510201651e36cbd950b5a0a32273fdbce1f053109aa5867b2c6a57e2a896c34c981c1a2e732a8f34539b754ebe7f50d1b5bf59f9549a75ad6420921f3e1d SHA512 3c60fd32dea308152c4272522c29668c83e88bea47c98b9fe796ed70f5460ad2a9616ffbe789c03e417b28d3c792361b16031bda3d8bc5b6c06f0ebdc66c8217
 EBUILD libxcrypt-4.4.20.ebuild 5797 BLAKE2B 888564715e7df7e8d19461ec5e9654ec6b0423148bfd6c9169d61cd12ebe30a6c8384092748bc5459be370b7bad0d615883dbfc51a5dff28abbd43ad57e79199 SHA512 dde0ff01e886294442779aea22148a8ccf17c47357b379f7d3c93ea49412233536a61972197909759b4957deac66afd703056a8c658f6b40fe78b85b85d0c930
 EBUILD libxcrypt-4.4.25-r1.ebuild 6394 BLAKE2B eb7f84bae0267f33a4f3ea17af79891802395eb361cf04565de6d9fafd31f8ca58bada24cb9c54bbae5ef171b822f4a63c94d777a8f81b69369faf40cc1ae2d0 SHA512 415b9151344e36ea65262fcdf51e3dd37c6e3ab11a2ecf15a575b2cf18740aee168c61f4502409d5d7617b8bc17f38c5decacc013125018ec72841f094b63fc6
 EBUILD libxcrypt-4.4.26-r1.ebuild 6402 BLAKE2B 72b434330bc6e591fb053fa472a64e40c45fa34a5c8c355fd3236f62a024c36bd49bb7420239f559cd3fce87931551d2c5340c705e91a6219d0e0c9f3e976041 SHA512 01fced1a1a1cf6838cd8b57ed141a1df3c30843e29b6b4b93bc1656cb729d79882a2d28916e917aa8c0b687bd6c8d6aab51cfc5e3d0b744a74ba59430049fba3
-EBUILD libxcrypt-4.4.27.ebuild 6402 BLAKE2B 72b434330bc6e591fb053fa472a64e40c45fa34a5c8c355fd3236f62a024c36bd49bb7420239f559cd3fce87931551d2c5340c705e91a6219d0e0c9f3e976041 SHA512 01fced1a1a1cf6838cd8b57ed141a1df3c30843e29b6b4b93bc1656cb729d79882a2d28916e917aa8c0b687bd6c8d6aab51cfc5e3d0b744a74ba59430049fba3
+EBUILD libxcrypt-4.4.27.ebuild 6394 BLAKE2B eb7f84bae0267f33a4f3ea17af79891802395eb361cf04565de6d9fafd31f8ca58bada24cb9c54bbae5ef171b822f4a63c94d777a8f81b69369faf40cc1ae2d0 SHA512 415b9151344e36ea65262fcdf51e3dd37c6e3ab11a2ecf15a575b2cf18740aee168c61f4502409d5d7617b8bc17f38c5decacc013125018ec72841f094b63fc6
+EBUILD libxcrypt-4.4.28.ebuild 6402 BLAKE2B 72b434330bc6e591fb053fa472a64e40c45fa34a5c8c355fd3236f62a024c36bd49bb7420239f559cd3fce87931551d2c5340c705e91a6219d0e0c9f3e976041 SHA512 01fced1a1a1cf6838cd8b57ed141a1df3c30843e29b6b4b93bc1656cb729d79882a2d28916e917aa8c0b687bd6c8d6aab51cfc5e3d0b744a74ba59430049fba3
 MISC metadata.xml 831 BLAKE2B f8761f3758acf79afea36926a6488afb73c433a8faa599aa09a3bbc01b6c733d7264d7b584606158312825f099a1176623c70625a317a837de5bb20501f5ed22 SHA512 826ea578d9d3e651767e8f670d2bbb918c11e26ca5dc1c52ff7fbd513c39bee2d9423ecf16e47e2603f5a8c7b6979fd27eacde84182deb5a67004c9a3be281cb
diff --git a/sys-libs/libxcrypt/libxcrypt-4.4.27.ebuild b/sys-libs/libxcrypt/libxcrypt-4.4.27.ebuild
index 9bebb1243fee..c9559428437e 100644
--- a/sys-libs/libxcrypt/libxcrypt-4.4.27.ebuild
+++ b/sys-libs/libxcrypt/libxcrypt-4.4.27.ebuild
@@ -20,7 +20,7 @@ fi
 
 LICENSE="LGPL-2.1+ public-domain BSD BSD-2"
 SLOT="0/1"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 IUSE="+compat split-usr static-libs system test"
 REQUIRED_USE="split-usr? ( system )"
 RESTRICT="!test? ( test )"
diff --git a/sys-libs/libxcrypt/libxcrypt-4.4.28.ebuild b/sys-libs/libxcrypt/libxcrypt-4.4.28.ebuild
new file mode 100644
index 000000000000..9bebb1243fee
--- /dev/null
+++ b/sys-libs/libxcrypt/libxcrypt-4.4.28.ebuild
@@ -0,0 +1,225 @@
+# Copyright 2004-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+# NEED_BOOTSTRAP is for developers to quickly generate a tarball
+# for publishing to the tree.
+NEED_BOOTSTRAP="no"
+inherit multibuild multilib python-any-r1 toolchain-funcs multilib-minimal
+
+DESCRIPTION="Extended crypt library for descrypt, md5crypt, bcrypt, and others"
+HOMEPAGE="https://github.com/besser82/libxcrypt"
+if [[ ${NEED_BOOTSTRAP} == "yes" ]] ; then
+	inherit autotools
+	SRC_URI="https://github.com/besser82/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+else
+	SRC_URI="https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-autotools.tar.xz"
+fi
+
+LICENSE="LGPL-2.1+ public-domain BSD BSD-2"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+compat split-usr static-libs system test"
+REQUIRED_USE="split-usr? ( system )"
+RESTRICT="!test? ( test )"
+
+DEPEND="system? (
+		elibc_glibc? (
+			sys-libs/glibc[-crypt(+)]
+			!sys-libs/glibc[crypt(+)]
+		)
+		!sys-libs/musl
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="dev-lang/perl
+	test? ( $(python_gen_any_dep 'dev-python/passlib[${PYTHON_USEDEP}]') )"
+
+python_check_deps() {
+	has_version -b "dev-python/passlib[${PYTHON_USEDEP}]"
+}
+
+pkg_pretend() {
+	if has "distcc" ${FEATURES} ; then
+		ewarn "Please verify all distcc nodes are using the same versions of GCC (>= 10) and Binutils!"
+		ewarn "Older/mismatched versions of GCC may lead to a misbehaving library: bug #823179."
+
+		if [[ ${BUILD_TYPE} != "binary" ]] && tc-is-gcc && [[ $(gcc-major-version) -lt 10 ]] ; then
+			die "libxcrypt is known to fail to build or be broken at runtime with < GCC 10 (bug #823179)!"
+		fi
+	fi
+}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=(
+		$(usex compat 'xcrypt_compat' '')
+		xcrypt_nocompat
+	)
+
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# WARNING: Please read on bumping or applying patches!
+	#
+	# There are two circular dependencies to be aware of:
+	# 1)
+	#	if we're bootstrapping configure and makefiles:
+	#		libxcrypt -> automake -> perl -> libxcrypt
+	#
+	#   mitigation:
+	#		toolchain@ manually runs `make dist` after running autoconf + `./configure`
+	#		and the ebuild uses that.
+	#		(Don't include the pre-generated Perl artefacts.)
+	#
+	#	solution for future:
+	#		Upstream are working on producing `make dist` tarballs.
+	#		https://github.com/besser82/libxcrypt/issues/134#issuecomment-871833573
+	#
+	# 2)
+	#	configure *unconditionally* needs Perl at build time to generate
+	#	a list of enabled algorithms based on the set passed to `configure`:
+	#		libxcrypt -> perl -> libxcrypt
+	#
+	#	mitigation:
+	#		None at the moment.
+	#
+	#	solution for future:
+	#		Not possible right now. Upstream intend on depending on Perl for further
+	#		configuration options.
+	#		https://github.com/besser82/libxcrypt/issues/134#issuecomment-871833573
+	#
+	# Therefore, on changes (inc. bumps):
+	#	* You must check whether upstream have started providing tarballs with bootstrapped
+	#	  auto{conf,make};
+	#
+	#	* diff the build system changes!
+	#
+	if [[ ${NEED_BOOTSTRAP} == "yes" ]] ; then
+		# Facilitate our split variant build for compat + non-compat
+		eapply "${FILESDIR}"/${PN}-4.4.19-multibuild.patch
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	# Avoid possible "illegal instruction" errors with gold
+	# bug #821496
+	tc-ld-disable-gold
+
+	multibuild_foreach_variant multilib-minimal_src_configure
+}
+
+get_xclibdir() {
+	printf -- "%s/%s/%s\n" \
+		"$(usex split-usr '' '/usr')" \
+		"$(get_libdir)" \
+		"$(usex system '' 'xcrypt')"
+}
+
+multilib_src_configure() {
+	local -a myconf=(
+		--disable-werror
+		--libdir="${EPREFIX}"$(get_xclibdir)
+		--with-pkgconfigdir="${EPREFIX}/usr/$(get_libdir)/pkgconfig"
+		--includedir="${EPREFIX}/usr/include/$(usex system '' 'xcrypt')"
+	)
+
+	case "${MULTIBUILD_ID}" in
+		xcrypt_compat-*)
+			myconf+=(
+				--disable-static
+				--disable-xcrypt-compat-files
+				--enable-obsolete-api=yes
+			)
+			;;
+		xcrypt_nocompat-*)
+			myconf+=(
+				--enable-obsolete-api=no
+				$(use_enable static-libs static)
+			)
+		;;
+		*) die "Unexpected MULTIBUILD_ID: ${MULTIBUILD_ID}";;
+	esac
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+}
+
+src_compile() {
+	multibuild_foreach_variant multilib-minimal_src_compile
+}
+
+multilib_src_test() {
+	emake check
+}
+
+src_test() {
+	multibuild_foreach_variant multilib-minimal_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant multilib-minimal_src_install
+
+	(
+		shopt -s failglob || die "failglob failed"
+
+		# Make sure our man pages do not collide with glibc or man-pages.
+		for manpage in "${ED}"/usr/share/man/man3/crypt{,_r}.?*; do
+			mv -n "${manpage}" "$(dirname "${manpage}")/xcrypt_$(basename "${manpage}")" \
+				|| die "mv failed"
+		done
+	) || die "failglob error"
+
+	# Remove useless stuff from installation
+	find "${ED}"/usr/share/doc/${PF} -type l -delete || die
+	find "${ED}" -name '*.la' -delete || die
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	# Don't install the libcrypt.so symlink for the "compat" version
+	case "${MULTIBUILD_ID}" in
+		xcrypt_compat-*)
+			rm "${ED}"$(get_xclibdir)/libcrypt$(get_libname) \
+				|| die "failed to remove extra compat libraries"
+		;;
+		xcrypt_nocompat-*)
+			if use split-usr; then
+				(
+					if use static-libs; then
+						# .a files are installed to /$(get_libdir) by default
+						# Move static libraries to /usr prefix or portage will abort
+						shopt -s nullglob || die "failglob failed"
+						static_libs=( "${ED}"/$(get_xclibdir)/*.a )
+
+						if [[ -n ${static_libs[*]} ]]; then
+							dodir "/usr/$(get_xclibdir)"
+							mv "${static_libs[@]}" "${ED}/usr/$(get_xclibdir)" \
+								|| die "Moving static libs failed"
+						fi
+					fi
+
+					if use system; then
+						# Move versionless .so symlinks from /$(get_libdir) to /usr/$(get_libdir)
+						# to allow linker to correctly find shared libraries.
+						shopt -s failglob || die "failglob failed"
+
+						for lib_file in "${ED}"$(get_xclibdir)/*$(get_libname); do
+							lib_file_basename="$(basename "${lib_file}")"
+							lib_file_target="$(basename "$(readlink -f "${lib_file}")")"
+							dosym "../../$(get_libdir)/${lib_file_target}" "/usr/$(get_xclibdir)/${lib_file_basename}"
+						done
+
+						rm "${ED}"$(get_xclibdir)/*$(get_libname) || die "Removing symlinks in incorrect location failed"
+					fi
+				)
+			fi
+		;;
+		*) die "Unexpected MULTIBUILD_ID: ${MULTIBUILD_ID}";;
+	esac
+}