gentoo auto-resync : 03:08:2023 - 04:52:21

2 files changed, 166 insertions, 0 deletions

diff --git a/sys-libs/binutils-libs/Manifest b/sys-libs/binutils-libs/Manifest
index b96fd149c39d..8582fe02dec0 100644
--- a/sys-libs/binutils-libs/Manifest
+++ b/sys-libs/binutils-libs/Manifest
@@ -14,6 +14,8 @@ DIST binutils-2.39.tar.xz 25167756 BLAKE2B ac6a5296c6586d53eaadcbffc5c399a6d79ed
 DIST binutils-2.40-patches-5.tar.xz 293628 BLAKE2B b7ed1d1fbf38b420661f984b9519b3d863da45b2a873773a521310021b0c1d5d7c24c152adb3e8a999d40f5619c0e54962114590ec9528380089977af0c30b74 SHA512 6e6df932b18ca20fe245b3ff8d3d06dbdae4daadaec3b668fa44e086d4e8ff56439681b2d810ebc74173b6348020edacb176e8c3cbf20657cce04297b97f4f83
 DIST binutils-2.40-patches-6.tar.xz 299212 BLAKE2B 3a68a924e9747fdd0486327a5bd2490cb72376f2cb6c6a60030d8c6b71357150d956a1e71d91683d43b571cb5bf738270880f72ef175d6c8faa257b090abeb8b SHA512 984dab529276ab4f9d215f643c7c18bd1793f438aaad0be158d209787c9c4a6bb68b10bec2065d3fe14a1594d5f1c29f55b2e9bac34a6f489f4b466c02e24766
 DIST binutils-2.40.tar.xz 25241484 BLAKE2B 8d799f7c595f878b9af5b17a490021dd8b8300ac2fe0ed8574c012929d22d2d0493e003a3e631a9436e8e712da801779b777c566167fe42b0bde119ffa5ad1c2 SHA512 a37e042523bc46494d99d5637c3f3d8f9956d9477b748b3b1f6d7dfbb8d968ed52c932e88a4e946c6f77b8f48f1e1b360ca54c3d298f17193f3b4963472f6925
+DIST binutils-2.41-patches-1.tar.xz 13260 BLAKE2B b7431ec92d5ce0e5d4438b31ca356c8d5366bee9aa8ff2f098a77c2add5b7539f733d0a18988337490af34c9192affbb6ccdf56b97413a8dca3192fb2125b313 SHA512 30548e4f3187444dbfa82587b5b8a0d2ab9d536aa06a572393a195649759149124d79c488c07919850c7ed4940481b852462d5a1aa52ed9162d81d6d3b290377
+DIST binutils-2.41.tar.xz 26765692 BLAKE2B 3bccec2b52f7e82a727121bf2a2e51a6249ba63dcd74c665fd834e858645c912ffd8245d848435288b938852830b482905606f55c40df4061215fd75c52ffc75 SHA512 5df45d0bd6ddabdce4f35878c041e46a92deef01e7dea5facc97fd65cc06b59abc6fba0eb454b68e571c7e14038dc823fe7f2263843e6e627b7444eaf0fe9374
 EBUILD binutils-libs-2.34-r2.ebuild 3633 BLAKE2B 4bb2862dc364c5f64597d2fb22f867028ee85c4d8a14ab85e28c2f5dab43cdb2a690e91b43d1a7994081df9c21be6c9850b808f01d71e18b97c1439ad1890fcb SHA512 84a368c4c1ba2a3f4e1b3043f531deab5457b0169d83b38bada72b857e9a86a7ca86cb317a062216ee7d2b87e39c6648e8bbd62e676507c638ea6fcfc9efda28
 EBUILD binutils-libs-2.35.2.ebuild 4055 BLAKE2B 5a2eed3c0e4a9f23742fe73258504faa0c52a975f9a53b9eaade40bd7f2af66d8524b4b08c02bf88770be79fa2163045b0721d5036860fc7b6c24e865e7da59e SHA512 da95193b41c9776c8f352c1008c3f7e64713ccf3f474f603cb390437e8ccdf0c6a32f5093281294d62441d671b7148a9955c235a8474810c8c8b029eb97d1765
 EBUILD binutils-libs-2.36.1-r2.ebuild 4008 BLAKE2B 142641749140de7c690cf5e3bd812ec1f00f47fa8cc023903d0d4dc5b1a772dc44bc131602f70e89b9aad8f38c60b6109b4ed4ca4316015d831658d2f836d321 SHA512 a3c474362ed1a51f754ac647b1b4a455603d144c4ea162668b0a0d5db2080b72b04760bcbd6cfe7a39443a1fa674a13502f4424ad3c34d57e5aa17176b88a376
@@ -22,4 +24,5 @@ EBUILD binutils-libs-2.38-r2.ebuild 4758 BLAKE2B 9de4470b987db46dd9647023f5750c2
 EBUILD binutils-libs-2.39-r5.ebuild 4766 BLAKE2B ee4275f3555984c95e8063a6858e761bb19485c51f7f5f88dbdb36dcd4f0491f9ea3044d8b3a9aca79a079ab9c8374a2fd1ae64a706738720b740aa497b03995 SHA512 a595fc95ec0dc535d09f864ebda797085d3f3c81acca7671c9aafc9edc19b329bbcb7112df17f9a66a34fda98803ff989144b7f24091d0cb293859855ffdca08
 EBUILD binutils-libs-2.40-r5.ebuild 5007 BLAKE2B 3170efa253aa7e9ba4351593b344e3e9dc317fc70ed8f1c034bfe7142870e6a8866c9a75c4e494a5c0f00eb6c7debdb8448cb8f78d646642524684d26d372c49 SHA512 1d57e7404b41d31d6f7b4c4e9a7aedbf229b3e811bd34f46cbc953308d3f125a5563e7b59c392615737b3890b4b7568433d748b365399936b5e6476575704d53
 EBUILD binutils-libs-2.40-r7.ebuild 5012 BLAKE2B e158d44b4c9cfda0942e138dcd0a003dae67f8d00f81c99fc24de4f94380316c67692417357daf6547140fea2beca8d8fc09d3df622d357a6693844157fbeca5 SHA512 e952d4cc9ab96d1f143a2a9ecbdb7d52829f57f56cc755559132df1d796763342f10797c4562037ddc11ef240a1a3cd51ba05ca0c077ab6ada7ea3b122013445
+EBUILD binutils-libs-2.41.ebuild 5012 BLAKE2B 50b82cfe51d0f14f1771a8b50aae2ac308ad26c00ead7e0474c8f38341c39f4c558ff139a0d5e9381581ab3937d8c91fba18a0c23b5b7b9253bdb16de1c04627 SHA512 2dba92fccb7235443dbbed48b7bfe8e92e4fb156d1ea9949704b24db24ca503790d424950b48022a869ffcd4e52e19ca42c98050278cda0ffda3ac15a35af577
 MISC metadata.xml 612 BLAKE2B ceaafd9fd1421e9f3993e003d0029c92a78054c7a2b90bd78afc05370ad19c931c6a7c150545cfb7d57165168e0fdaf3a00dde1905b328826a91cbc70d9548a8 SHA512 c8d33bb8d1c62c7e95758624ed0febbc9d40e9f141bfd280837b3207bcd771412158d71c0cb5548d60be0b236f6fe103621daf7efa8875191982859b566ffa8d
diff --git a/sys-libs/binutils-libs/binutils-libs-2.41.ebuild b/sys-libs/binutils-libs/binutils-libs-2.41.ebuild
new file mode 100644
index 000000000000..377c162c2ef1
--- /dev/null
+++ b/sys-libs/binutils-libs/binutils-libs-2.41.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PATCH_VER=1
+PATCH_DEV=dilfridge
+
+inherit libtool toolchain-funcs multilib-minimal
+
+MY_PN="binutils"
+MY_P="${MY_PN}-${PV}"
+PATCH_BINUTILS_VER=${PATCH_BINUTILS_VER:-${PV}}
+PATCH_DEV=${PATCH_DEV:-dilfridge}
+
+DESCRIPTION="Core binutils libraries (libbfd, libopcodes, libiberty) for external packages"
+HOMEPAGE="https://sourceware.org/binutils/"
+SRC_URI="mirror://gnu/binutils/${MY_P}.tar.xz
+	https://dev.gentoo.org/~${PATCH_DEV}/distfiles/${MY_P}.tar.xz
+	https://dev.gentoo.org/~${PATCH_DEV}/distfiles/${MY_PN}-${PATCH_BINUTILS_VER}-patches-${PATCH_VER}.tar.xz"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0/${PV%_p?}"
+IUSE="64-bit-bfd cet multitarget nls static-libs test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos ~x64-solaris"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	nls? ( sys-devel/gettext )
+	test? ( dev-util/dejagnu )
+"
+DEPEND="sys-libs/zlib[${MULTILIB_USEDEP}]"
+# Need a newer binutils-config that'll reset include/lib symlinks for us.
+RDEPEND="${DEPEND}
+	>=sys-devel/binutils-config-5
+"
+
+S="${WORKDIR}/${MY_P%_p?}"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/bfd.h
+)
+
+src_prepare() {
+	if [[ -n ${PATCH_VER} ]] ; then
+		einfo "Applying binutils-${PATCH_BINUTILS_VER} patchset ${PATCH_VER}"
+		eapply "${WORKDIR}/patch"/*.patch
+	fi
+
+	# Fix cross-compile relinking issue, bug #626402
+	elibtoolize
+
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		# somehow libtool/configure is messed up and (custom patch at
+		# upstream?) and misdetects (basically assumes) nm can be called
+		# with -B arg -- can't run eautoreconf (fails), so patch up
+		# manually, this would break any target that needs -B to nm
+		sed -i -e 's/lt_cv_path_NM="$tmp_nm -B"/lt_cv_path_NM="$tmp_nm"/' \
+			libctf/configure || die
+	fi
+
+	# See https://www.gnu.org/software/make/manual/html_node/Parallel-Output.html
+	# Avoid really confusing logs from subconfigure spam, makes logs far
+	# more legible.
+	export MAKEOPTS="--output-sync=line ${MAKEOPTS}"
+
+	default
+}
+
+pkgversion() {
+	printf "Gentoo ${PVR}"
+	[[ -n ${PATCHVER} ]] && printf " p${PATCHVER}"
+}
+
+multilib_src_configure() {
+	local myconf=(
+		--enable-obsolete
+		--enable-shared
+		--enable-threads
+		# Newer versions (>=2.24) make this an explicit option. #497268
+		--enable-install-libiberty
+		--disable-werror
+		--with-bugurl="https://bugs.gentoo.org/"
+		--with-pkgversion="$(pkgversion)"
+		$(use_enable static-libs static)
+		# The binutils eclass enables this flag for all bi-arch builds,
+		# but other tools often don't care about that support.  Put it
+		# beyond a flag if people really want it, but otherwise leave
+		# it disabled as it can slow things down on 32bit arches. #438522
+		$(use_enable 64-bit-bfd)
+		# This only disables building in the zlib subdir.
+		# For binutils itself, it'll use the system version. #591516
+		--without-zlib
+		--with-system-zlib
+		# We only care about the libs, so disable programs. #528088
+		--disable-{binutils,etc,ld,gas,gold,gprof,gprofng}
+		# Disable modules that are in a combined binutils/gdb tree. #490566
+		--disable-{gdb,libdecnumber,readline,sim}
+		# Strip out broken static link flags.
+		# https://gcc.gnu.org/PR56750
+		--without-stage1-ldflags
+		# We pull in all USE-flags that change ABI in an incompatible
+		# way. #666100
+		# USE=multitarget change size of global arrays
+		# USE=64-bit-bfd changes data structures of exported API
+		--with-extra-soversion-suffix=gentoo-${CATEGORY}-${PN}-$(usex multitarget mt st)-$(usex 64-bit-bfd 64 def)
+
+		# avoid automagic dependency on (currently prefix) systems
+		# systems with debuginfod library, bug #754753
+		--without-debuginfod
+
+		# Revisit if it's useful, we do have binutils[zstd] though
+		--without-zstd
+
+		# Allow user to opt into CET for host libraries.
+		# Ideally we would like automagic-or-disabled here.
+		# But the check does not quite work on i686: bug #760926.
+		$(use_enable cet)
+	)
+
+	# mips can't do hash-style=gnu ...
+	if [[ $(tc-arch) != mips ]] ; then
+		myconf+=( --enable-default-hash-style=gnu )
+	fi
+
+	use multitarget && myconf+=( --enable-targets=all --enable-64-bit-bfd )
+
+	use nls \
+		&& myconf+=( --without-included-gettext ) \
+		|| myconf+=( --disable-nls )
+
+	if [[ ${CHOST} == *-darwin* ]] && use nls ; then
+		# fix underlinking in opcodes
+		sed -i -e 's/@SHARED_LDFLAGS@/@SHARED_LDFLAGS@ -lintl/' \
+			"${S}"/opcodes/Makefile.in || die
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+
+	# Prevent makeinfo from running as we don't build docs here.
+	# bug #622652
+	sed -i \
+		-e '/^MAKEINFO/s:=.*:= true:' \
+		Makefile || die
+}
+
+multilib_src_compile() {
+	emake V=1
+}
+
+multilib_src_install() {
+	emake V=1 DESTDIR="${D}" install
+
+	# Provided by sys-devel/gdb instead
+	rm "${ED}"/usr/share/info/sframe-spec.info || die
+
+	# Provide libiberty.h directly.
+	dosym libiberty/libiberty.h /usr/include/libiberty.h
+}
+
+multilib_src_install_all() {
+	use static-libs || find "${ED}"/usr -name '*.la' -delete
+}