gentoo auto-resync : 24:02:2024 - 17:40:43

6 files changed, 484 insertions, 0 deletions

diff --git a/sys-kernel/Manifest.gz b/sys-kernel/Manifest.gz
index 7f897e461fe4..439af590264b 100644
--- a/sys-kernel/Manifest.gz
+++ b/sys-kernel/Manifest.gz
diff --git a/sys-kernel/dracut-crypt-ssh/Manifest b/sys-kernel/dracut-crypt-ssh/Manifest
index db8fe17eb9d0..5999ae504292 100644
--- a/sys-kernel/dracut-crypt-ssh/Manifest
+++ b/sys-kernel/dracut-crypt-ssh/Manifest
@@ -1,4 +1,6 @@
 AUX dracut-crypt-ssh-1.0.7-makefile.patch 693 BLAKE2B 538e8917b662824badaa08cf3a65ff5865011a2496caae87a61d4fc03ab4b76da0de8a4558d098683ba5f01de98e86493515e0aa1fda465dbdb601fbeb00e3ad SHA512 304ca0b2c4a3fc26db5070d323350a635cc4ed3d500ba30f5aeaea8fa8bbd71528578c322a90d001a4d1b0bf2f16bdb9acd33bcf75fcc914e47f1a640eb469ad
 DIST dracut-crypt-ssh-1.0.7.tar.gz 19561 BLAKE2B b778d03d792c5ebe0466de7474a6cc821445fe0cd3b216f395d3ea28a17cb4ed3aa6da4b7d6dee86e4481e2ac98d677e3410cd6581c4d8c01ab0ec9564504bf3 SHA512 2958a59c3ff615e89b7631224e248e7e931dd91c566e792b10dffe09b8bd2dfcf2c55eef4e974988f19320e0d732d3dfb14b61713445e1ff3a4a9868dfc4e966
+DIST dracut-crypt-ssh-1.0.8.tar.gz 20931 BLAKE2B 2700bd7781c617b3bd44665971e9fd16727c31b0be76dfa7c121a2e77c250d830907a27e6ea43f6fc9684df0ee54a75093c62d449e5c04a16eb78d2fc572f238 SHA512 37f1f1a0029587ce19f56f5c108a6353230ccbc299b82d260c64dd73984db05ac1bf00ab59125905de95c69dfbf5e8923393f150594c1bdaeb0f70d1bff5c072
 EBUILD dracut-crypt-ssh-1.0.7.ebuild 860 BLAKE2B ebd2864603adc187950c05b4b04822ffcf8e932117d133e944b9955bde0543d4aa0d04fdc8e8803c84a1cad7d9e19c558e79b0ac9cc19816cc5ea703c8bda39c SHA512 14435d01fcab87872160a6c00151b03c069223da1b888718d7ca0de12165e08918af5b2cf627791502d2c59d9a7fa3af8b8d3841477f8bb98eb0c924d502d139
+EBUILD dracut-crypt-ssh-1.0.8.ebuild 813 BLAKE2B b095ba044c6ec39c5cce4edb9071828403d0aa29fcdee47ab06d0baf90752b204e0ada742f3292c788cf56ef145ab4341c90aae65070560cd92c4806c3e549b6 SHA512 04713a813998b363a5143af2df970e76d24a9156aa79283d531c729991dad573504816603720962a15cc6dcf60724360fbaf0c5012357f85f9226d1b5e16d9e9
 MISC metadata.xml 443 BLAKE2B 52a20ed815721e7b01cdfae83831f741049c5137a9957fd7e1324065742e21ca9e0a2564c95df16590ecf346af9bebc2f8195f10e5cadaa161bf25475cd708e9 SHA512 3f82f6b1c7dc0d167bfbaf0ef779c6f63923e90ceaa729c1188ffc043ea5d9392ecc900cec6322ed7d227cdd05f69fb22d32b1999314b9735db70686e43d7353
diff --git a/sys-kernel/dracut-crypt-ssh/dracut-crypt-ssh-1.0.8.ebuild b/sys-kernel/dracut-crypt-ssh/dracut-crypt-ssh-1.0.8.ebuild
new file mode 100644
index 000000000000..3c3850f2a8f9
--- /dev/null
+++ b/sys-kernel/dracut-crypt-ssh/dracut-crypt-ssh-1.0.8.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Early unlocking of encrypted systems via ssh for dracut"
+HOMEPAGE="https://github.com/dracut-crypt-ssh/dracut-crypt-ssh"
+SRC_URI="https://github.com/dracut-crypt-ssh/dracut-crypt-ssh/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="sys-kernel/dracut"
+RDEPEND="${DEPEND}
+	|| (
+		net-misc/connman
+		net-misc/dhcp
+		net-misc/dhcpcd
+		net-misc/netifrc
+		net-misc/networkmanager
+		sys-apps/systemd
+	)
+	net-misc/dropbear"
+
+src_prepare() {
+	default
+
+	# Fix libdir (hard-coded to "lib64")
+	sed "s@/lib64/@/$(get_libdir)/@" \
+		-i modules/60crypt-ssh/module-setup.sh \
+		|| die
+}
+
+src_configure() {
+	tc-export CC
+	default
+}
diff --git a/sys-kernel/linux-firmware/Manifest b/sys-kernel/linux-firmware/Manifest
index a4c89704ae89..98cfe43df488 100644
--- a/sys-kernel/linux-firmware/Manifest
+++ b/sys-kernel/linux-firmware/Manifest
@@ -1,8 +1,10 @@
 AUX linux-firmware-copy-firmware-r3.patch 2210 BLAKE2B 06aa2fa8b9dce583aba07f0b64f05a8efa83d9c0f6fdf0820b28238396ad461a24edc0de7bec114ae235b4cf3c9b1d237db154d846b55c6ed6020d990d11fa41 SHA512 6c77ae4f439cfa53b113806841c55d127943dd57436a7fb6531a2f2103fa956184d312f904f6dd00abb8731907fb60d1ea13e7027d277d41d24fb7030f4c6a17
+AUX linux-firmware-copy-firmware-r4.patch 1538 BLAKE2B 65712bb1b6ba0d4c2a04f2e202a4a9ee272aca364813825f568a6544b7b63537fc44a4304269fd323c9299f8dce4744414f8fe859958d5f9b52d57c9822615b4 SHA512 56694eb4ae6ec13093f1e3f86df9f5494109693f6456ed6d3ad2b2041deae0ce36e2919d256025f7442fcf0e966c0954ce4634c717e4e7cb68fc6d34ae5554f3
 DIST linux-firmware-20240115.tar.xz 363994604 BLAKE2B 00a0874cfbafe0fe57a841510c71e54e836efad65564b7fa30c334c2bcf909e235129035a6fa4ba090089492fb07beab945be82b3801ce8353fca20fa426ac85 SHA512 65100216a0dbe97ea0cdf3104dd59c95cafe883bd8c2a40f9369acb55d6f7260c1b51f233987d2f89cce93b2a952721a0484a6314cda49455986c597ff2050dd
 DIST linux-firmware-20240220.tar.xz 368128968 BLAKE2B 6eefe70f8b55619d58b2ed538cd3eb85e013e231d1cb474fefc48f8af6a2f61a763ef73793eed30e17c67fd83a80b9c91f0af6c7b049861fa57c088dc9604d71 SHA512 faa4fbe3556b67e2adc9afebb8a3909ac853eeb0b9b43eafe1aa9144e633a6356e11af7c3ee008e654ae928dd2ffcd4261bee3e63a3bee4cae7cd3b442916299
 EBUILD linux-firmware-20240115-r3.ebuild 11122 BLAKE2B 882535f2161b96598beb84454d49bdb7903df8e4bfc18e15627dc309e0c6894109b7476de633da69e020be37a23441414d7c692d7783b8357eaa3b21099893e4 SHA512 79ad81ff34aad14f102ec628701ece559d92c0fb1c41ab8fb1bee8fdef93611d72100e6f3aa09059828f79706df4654cc337c9d2cc6309bd2a2e92a535ca6058
 EBUILD linux-firmware-20240115.ebuild 11383 BLAKE2B 4bce49693e7e86f69da95cfd9123aa6e63bf39aeb2777408e54e6e9e633e877283244d346cb4c413ce144b6c2147f67433886c3d405078f9cb13bf4f0174c637 SHA512 7e4d282aab026c4de7e07925108967c8d523474dd8d5b88979716d7139a73bbaa0c384ba0ad6509fd661a1749c26165a8a23d8a70821fec3b2aefb0fd2bfe089
 EBUILD linux-firmware-20240220-r1.ebuild 11295 BLAKE2B 8ba2fa814fcafff9092a68f5c12e9c82b657a1b3d1ea8423f0da67aaf809cd8e9ba33993d56d6d23e83813a7194219e2bb564c6b0d26dcd307cfc40554511445 SHA512 aea3c8e11e41a973d73c2986e432b8b44b4c6476a9af94e26af7824cdbb37a9e90126a151fd1e5886b224fb60525a82e80111ea87ed68b397c0f6a66af6624cb
+EBUILD linux-firmware-20240220-r2.ebuild 11117 BLAKE2B 2296570c1d59e82e34a3e913f386c358e87981daa33dcc41953f0d001eafeb42af7a051bcb040faeb884fc78df795651124a364a80fe15f67abf6e91d3f08a7f SHA512 f962a441f8891649d81501e15edfae5f5ca16979dd981ab7a9eef71579ca751652671f1a58d2efc318e38f0867c30387a93f173e33aea5d00f281ce42889b46e
 EBUILD linux-firmware-99999999.ebuild 11247 BLAKE2B 5beb777e773325535aa9b0ca75d20bb2c9dd2ae6aec098947b0eda7b5a9d140c898530ed0e8623168052bbf0a84b795a05718e07c241be946f8904d36dafdfdf SHA512 f5ff962e300cd5f4c2a74e6dd89ec2f9acdfccc836c2d2562246ee8599a8be44760626b7dfa1e193f1c1b8e6f630184cee39a25313f4b5410397e678b7c788a4
 MISC metadata.xml 1289 BLAKE2B 109336d30e5ec5fb5e679cff9b31e6f69c0b4f629e2aaf4d0d7b6c0db78c1ddcbbb0b283f724f2758207324b622c2af9dfe15874ab34b34876e3e4f58cb5ced6 SHA512 9b925b26bb58a39360ab5ff3cdd7d88bd489645e73f101209f0813a0b926b15dae34f28db05ff6419a0a62fab2ac84ae0546b5007ce17ad3611188bf7aeda3e5
diff --git a/sys-kernel/linux-firmware/files/linux-firmware-copy-firmware-r4.patch b/sys-kernel/linux-firmware/files/linux-firmware-copy-firmware-r4.patch
new file mode 100644
index 000000000000..f8b713bfe0f5
--- /dev/null
+++ b/sys-kernel/linux-firmware/files/linux-firmware-copy-firmware-r4.patch
@@ -0,0 +1,35 @@
+--- a/copy-firmware.sh	2024-02-24 10:47:41.073251066 -0500
++++ b/copy-firmware.sh	2024-02-24 10:25:45.283922934 -0500
+@@ -50,6 +50,16 @@ while test $# -gt 0; do
+             shift
+             ;;
+ 
++        --firmware-list)
++            if [ -n "$2" ]; then
++                FIRMWARE_LIST=`cat $2`
++                shift 2
++            else
++                echo "ERROR: '--firmware-list' requires a non-empty option argument of firmware files to install"
++                exit 1
++            fi
++            ;;
++
+         -*)
+             if test "$compress" = "cat"; then
+                 echo "ERROR: unknown command-line option: $1"
+@@ -85,6 +95,7 @@ fi
+ # shellcheck disable=SC2162 # file/folder name can include escaped symbols
+ grep -E '^(RawFile|File):' WHENCE | sed -E -e 's/^(RawFile|File): */\1 /;s/"//g' | while read k f; do
+     test -f "$f" || continue
++	   [ -n "${FIRMWARE_LIST}" ]  && if ! echo "${FIRMWARE_LIST}" | grep -q "${f}"; then continue; fi
+     install -d "$destdir/$(dirname "$f")"
+     $verbose "copying/compressing file $f$compext"
+     if test "$compress" != "cat" && test "$k" = "RawFile"; then
+@@ -107,6 +118,7 @@ fi
+ 
+ # shellcheck disable=SC2162 # file/folder name can include escaped symbols
+ grep -E '^Link:' WHENCE | sed -e 's/^Link: *//g;s/-> //g' | while read f d; do
++	   [ -n "${FIRMWARE_LIST}" ]  && if ! echo "${FIRMWARE_LIST}" | grep -q "${f}"; then continue; fi
+     if test -L "$f$compext"; then
+         test -f "$destdir/$f$compext" && continue
+         $verbose "copying link $f$compext"
diff --git a/sys-kernel/linux-firmware/linux-firmware-20240220-r2.ebuild b/sys-kernel/linux-firmware/linux-firmware-20240220-r2.ebuild
new file mode 100644
index 000000000000..472d2802f8f3
--- /dev/null
+++ b/sys-kernel/linux-firmware/linux-firmware-20240220-r2.ebuild
@@ -0,0 +1,405 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit linux-info mount-boot savedconfig multiprocessing
+
+# In case this is a real snapshot, fill in commit below.
+# For normal, tagged releases, leave blank
+MY_COMMIT=""
+
+if [[ ${PV} == 99999999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/linux/kernel/git/firmware/${PN}.git"
+else
+	if [[ -n "${MY_COMMIT}" ]]; then
+		SRC_URI="https://git.kernel.org/cgit/linux/kernel/git/firmware/linux-firmware.git/snapshot/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${MY_COMMIT}"
+	else
+		SRC_URI="https://mirrors.edge.kernel.org/pub/linux/kernel/firmware/${P}.tar.xz"
+	fi
+
+	KEYWORDS="-alpha -amd64 -arm -arm64 -hppa -ia64 -loong -m68k -mips -ppc -ppc64 -riscv -s390 -sparc -x86"
+fi
+
+DESCRIPTION="Linux firmware files"
+HOMEPAGE="https://git.kernel.org/?p=linux/kernel/git/firmware/linux-firmware.git"
+
+LICENSE="GPL-2 GPL-2+ GPL-3 BSD MIT || ( MPL-1.1 GPL-2 )
+	redistributable? ( linux-fw-redistributable BSD-2 BSD BSD-4 ISC MIT )
+	unknown-license? ( all-rights-reserved )"
+SLOT="0"
+IUSE="bindist compress-xz compress-zstd deduplicate initramfs +redistributable savedconfig unknown-license"
+REQUIRED_USE="initramfs? ( redistributable )
+	?? ( compress-xz compress-zstd )
+	savedconfig? ( !deduplicate )"
+
+RESTRICT="binchecks strip test
+	!bindist? ( bindist )
+	unknown-license? ( bindist )"
+
+BDEPEND="initramfs? ( app-alternatives/cpio )
+	compress-xz? ( app-arch/xz-utils )
+	compress-zstd? ( app-arch/zstd )
+	deduplicate? ( app-misc/rdfind )"
+
+#add anything else that collides to this
+RDEPEND="!savedconfig? (
+		redistributable? (
+			!sys-firmware/alsa-firmware[alsa_cards_ca0132]
+			!sys-block/qla-fc-firmware
+			!sys-firmware/iwl1000-ucode
+			!sys-firmware/iwl6005-ucode
+			!sys-firmware/iwl6030-ucode
+			!sys-firmware/iwl3160-ucode
+			!sys-firmware/iwl7260-ucode
+			!sys-firmware/iwl3160-7260-bt-ucode
+			!sys-firmware/raspberrypi-wifi-ucode
+		)
+		unknown-license? (
+			!sys-firmware/alsa-firmware[alsa_cards_korg1212]
+			!sys-firmware/alsa-firmware[alsa_cards_maestro3]
+			!sys-firmware/alsa-firmware[alsa_cards_sb16]
+			!sys-firmware/alsa-firmware[alsa_cards_ymfpci]
+		)
+	)"
+
+QA_PREBUILT="*"
+PATCHES=( "${FILESDIR}"/${PN}-copy-firmware-r4.patch )
+
+pkg_pretend() {
+	use initramfs && mount-boot_pkg_pretend
+}
+
+pkg_setup() {
+	if use compress-xz || use compress-zstd ; then
+		local CONFIG_CHECK
+
+		if kernel_is -ge 5 19; then
+			use compress-xz && CONFIG_CHECK="~FW_LOADER_COMPRESS_XZ"
+			use compress-zstd && CONFIG_CHECK="~FW_LOADER_COMPRESS_ZSTD"
+		else
+			use compress-xz && CONFIG_CHECK="~FW_LOADER_COMPRESS"
+			if use compress-zstd; then
+				eerror "Kernels <5.19 do not support ZSTD-compressed firmware files"
+			fi
+		fi
+		linux-info_pkg_setup
+	fi
+}
+
+src_unpack() {
+	if [[ ${PV} == 99999999* ]]; then
+		git-r3_src_unpack
+	else
+		default
+		# rename directory from git snapshot tarball
+		if [[ ${#GIT_COMMIT} -gt 8 ]]; then
+			mv ${PN}-*/ ${P} || die
+		fi
+	fi
+}
+
+src_prepare() {
+
+	default
+
+	find . -type f -not -perm 0644 -print0 \
+		| xargs --null --no-run-if-empty chmod 0644 \
+		|| die
+
+	chmod +x copy-firmware.sh || die
+
+	if use initramfs; then
+		if [[ -d "${S}/amd-ucode" ]]; then
+			local UCODETMP="${T}/ucode_tmp"
+			local UCODEDIR="${UCODETMP}/kernel/x86/microcode"
+			mkdir -p "${UCODEDIR}" || die
+			echo 1 > "${UCODETMP}/early_cpio"
+
+			local amd_ucode_file="${UCODEDIR}/AuthenticAMD.bin"
+			cat "${S}"/amd-ucode/*.bin > "${amd_ucode_file}" || die "Failed to concat amd cpu ucode"
+
+			if [[ ! -s "${amd_ucode_file}" ]]; then
+				die "Sanity check failed: '${amd_ucode_file}' is empty!"
+			fi
+
+			pushd "${UCODETMP}" &>/dev/null || die
+			find . -print0 | cpio --quiet --null -o -H newc -R 0:0 > "${S}"/amd-uc.img
+			popd &>/dev/null || die
+			if [[ ! -s "${S}/amd-uc.img" ]]; then
+				die "Failed to create '${S}/amd-uc.img'!"
+			fi
+		else
+			# If this will ever happen something has changed which
+			# must be reviewed
+			die "'${S}/amd-ucode' not found!"
+		fi
+	fi
+
+	# whitelist of misc files
+	local misc_files=(
+		copy-firmware.sh
+		README.md
+		WHENCE
+		LICEN[CS]E.*
+	)
+
+	# whitelist of images with a free software license
+	local free_software=(
+		# keyspan_pda (GPL-2+)
+		keyspan_pda/keyspan_pda.fw
+		keyspan_pda/xircom_pgs.fw
+		# dsp56k (GPL-2+)
+		dsp56k/bootstrap.bin
+		# ath9k_htc (BSD GPL-2+ MIT)
+		ath9k_htc/htc_7010-1.4.0.fw
+		ath9k_htc/htc_9271-1.4.0.fw
+		# pcnet_cs, 3c589_cs, 3c574_cs, serial_cs (dual GPL-2/MPL-1.1)
+		cis/LA-PCM.cis
+		cis/PCMLM28.cis
+		cis/DP83903.cis
+		cis/NE2K.cis
+		cis/tamarack.cis
+		cis/PE-200.cis
+		cis/PE520.cis
+		cis/3CXEM556.cis
+		cis/3CCFEM556.cis
+		cis/MT5634ZLX.cis
+		cis/RS-COM-2P.cis
+		cis/COMpad2.cis
+		cis/COMpad4.cis
+		# serial_cs (GPL-3)
+		cis/SW_555_SER.cis
+		cis/SW_7xx_SER.cis
+		cis/SW_8xx_SER.cis
+		# dvb-ttpci (GPL-2+)
+		av7110/bootcode.bin
+		# usbdux, usbduxfast, usbduxsigma (GPL-2+)
+		usbdux_firmware.bin
+		usbduxfast_firmware.bin
+		usbduxsigma_firmware.bin
+		# brcmfmac (GPL-2+)
+		brcm/brcmfmac4330-sdio.Prowise-PT301.txt
+		brcm/brcmfmac43340-sdio.meegopad-t08.txt
+		brcm/brcmfmac43362-sdio.cubietech,cubietruck.txt
+		brcm/brcmfmac43362-sdio.lemaker,bananapro.txt
+		brcm/brcmfmac43430a0-sdio.jumper-ezpad-mini3.txt
+		"brcm/brcmfmac43430a0-sdio.ONDA-V80 PLUS.txt"
+		brcm/brcmfmac43430-sdio.AP6212.txt
+		brcm/brcmfmac43430-sdio.Hampoo-D2D3_Vi8A1.txt
+		brcm/brcmfmac43430-sdio.MUR1DX.txt
+		brcm/brcmfmac43430-sdio.raspberrypi,3-model-b.txt
+		brcm/brcmfmac43455-sdio.raspberrypi,3-model-b-plus.txt
+		brcm/brcmfmac4356-pcie.gpd-win-pocket.txt
+		# isci (GPL-2)
+		isci/isci_firmware.bin
+		# carl9170 (GPL-2+)
+		carl9170-1.fw
+		# atusb (GPL-2+)
+		atusb/atusb-0.2.dfu
+		atusb/atusb-0.3.dfu
+		atusb/rzusb-0.3.bin
+		# mlxsw_spectrum (dual BSD/GPL-2)
+		mellanox/mlxsw_spectrum-13.1420.122.mfa2
+		mellanox/mlxsw_spectrum-13.1530.152.mfa2
+		mellanox/mlxsw_spectrum-13.1620.192.mfa2
+		mellanox/mlxsw_spectrum-13.1702.6.mfa2
+		mellanox/mlxsw_spectrum-13.1703.4.mfa2
+		mellanox/mlxsw_spectrum-13.1910.622.mfa2
+		mellanox/mlxsw_spectrum-13.2000.1122.mfa2
+	)
+
+	# blacklist of images with unknown license
+	local unknown_license=(
+		korg/k1212.dsp
+		ess/maestro3_assp_kernel.fw
+		ess/maestro3_assp_minisrc.fw
+		yamaha/ds1_ctrl.fw
+		yamaha/ds1_dsp.fw
+		yamaha/ds1e_ctrl.fw
+		ttusb-budget/dspbootcode.bin
+		emi62/bitstream.fw
+		emi62/loader.fw
+		emi62/midi.fw
+		emi62/spdif.fw
+		ti_3410.fw
+		ti_5052.fw
+		mts_mt9234mu.fw
+		mts_mt9234zba.fw
+		whiteheat.fw
+		whiteheat_loader.fw
+		cpia2/stv0672_vp4.bin
+		vicam/firmware.fw
+		edgeport/boot.fw
+		edgeport/boot2.fw
+		edgeport/down.fw
+		edgeport/down2.fw
+		edgeport/down3.bin
+		sb16/mulaw_main.csp
+		sb16/alaw_main.csp
+		sb16/ima_adpcm_init.csp
+		sb16/ima_adpcm_playback.csp
+		sb16/ima_adpcm_capture.csp
+		sun/cassini.bin
+		acenic/tg1.bin
+		acenic/tg2.bin
+		adaptec/starfire_rx.bin
+		adaptec/starfire_tx.bin
+		yam/1200.bin
+		yam/9600.bin
+		ositech/Xilinx7OD.bin
+		qlogic/isp1000.bin
+		myricom/lanai.bin
+		yamaha/yss225_registers.bin
+		lgs8g75.fw
+	)
+
+	if use !unknown-license; then
+		einfo "Removing files with unknown license ..."
+		rm -v "${unknown_license[@]}" || die
+	fi
+
+	if use !redistributable; then
+		# remove files _not_ in the free_software or unknown_license lists
+		# everything else is confirmed (or assumed) to be redistributable
+		# based on upstream acceptance policy
+		einfo "Removing non-redistributable files ..."
+		local OLDIFS="${IFS}"
+		local IFS=$'\n'
+		set -o pipefail
+		find ! -type d -printf "%P\n" \
+			| grep -Fvx -e "${misc_files[*]}" -e "${free_software[*]}" -e "${unknown_license[*]}" \
+			| xargs -d '\n' --no-run-if-empty rm -v
+
+		[[ ${?} -ne 0 ]] && die "Failed to remove non-redistributable files"
+
+		IFS="${OLDIFS}"
+	fi
+
+	restore_config ${PN}.conf
+}
+
+src_install() {
+
+	local FW_OPTIONS=( "-v" )
+	local files_to_keep=
+
+	if use savedconfig; then
+		if [[ -s "${S}/${PN}.conf" ]]; then
+			files_to_keep="${T}/files_to_keep.lst"
+			grep -v '^#' "${S}/${PN}.conf" 2>/dev/null > "${files_to_keep}" || die
+			[[ -s "${files_to_keep}" ]] || die "grep failed, empty config file?"
+			FW_OPTIONS+=( "--firmware-list" "${files_to_keep}" )
+		fi
+	fi
+
+	! use deduplicate && FW_OPTIONS+=( "--ignore-duplicates" )
+	FW_OPTIONS+=( "${ED}/lib/firmware" )
+	./copy-firmware.sh "${FW_OPTIONS[@]}"
+
+	pushd "${ED}/lib/firmware" &>/dev/null || die
+
+	# especially use !redistributable will cause some broken symlinks
+	einfo "Removing broken symlinks ..."
+	find * -xtype l -print -delete || die
+
+	# remove empty directories, bug #396073
+	find -type d -empty -delete || die
+
+	# sanity check
+	if ! ( shopt -s failglob; : * ) 2>/dev/null; then
+		eerror "No files to install. Check your USE flag settings"
+		eerror "and the list of files in your saved configuration."
+		die "Refusing to install an empty package"
+	fi
+
+	# create config file
+	echo "# Remove files that shall not be installed from this list." > "${S}"/${PN}.conf || die
+	find * ! -type d >> "${S}"/${PN}.conf || die
+	save_config "${S}"/${PN}.conf
+
+	if use compress-xz || use compress-zstd; then
+		einfo "Compressing firmware ..."
+		local target
+		local ext
+		local compressor
+
+		if use compress-xz; then
+			ext=xz
+			compressor="xz -T1 -C crc32"
+		elif use compress-zstd; then
+			ext=zst
+			compressor="zstd -15 -T1 -C -q --rm"
+		fi
+
+		# rename symlinks
+		while IFS= read -r -d '' f; do
+			# skip symlinks pointing to directories
+			[[ -d ${f} ]] && continue
+
+			target=$(readlink "${f}")
+			[[ $? -eq 0 ]] || die
+			ln -sf "${target}".${ext} "${f}" || die
+			mv -T "${f}" "${f}".${ext} || die
+		done < <(find . -type l -print0) || die
+
+		find . -type f ! -path "./amd-ucode/*" -print0 | \
+			xargs -0 -P $(makeopts_jobs) -I'{}' ${compressor} '{}' || die
+
+	fi
+
+	popd &>/dev/null || die
+
+	if use initramfs ; then
+		insinto /boot
+		doins "${S}"/amd-uc.img
+	fi
+
+	dodoc README.md
+	# some licenses require copyright and permission notice to be included
+	use bindist && dodoc WHENCE LICEN[CS]E.*
+}
+
+pkg_preinst() {
+	if use savedconfig; then
+		ewarn "USE=savedconfig is active. You must handle file collisions manually."
+	fi
+
+	# Fix 'symlink is blocked by a directory' Bug #871315
+	if has_version "<${CATEGORY}/${PN}-20220913-r2" ; then
+		rm -rf "${EROOT}"/lib/firmware/qcom/LENOVO/21BX
+	fi
+
+	# Make sure /boot is available if needed.
+	use initramfs && mount-boot_pkg_preinst
+}
+
+pkg_postinst() {
+	elog "If you are only interested in particular firmware files, edit the saved"
+	elog "configfile and remove those that you do not want."
+
+	local ver
+	for ver in ${REPLACING_VERSIONS}; do
+		if ver_test ${ver} -lt 20190514; then
+			elog
+			elog 'Starting with version 20190514, installation of many firmware'
+			elog 'files is controlled by USE flags. Please review your USE flag'
+			elog 'and package.license settings if you are missing some files.'
+			break
+		fi
+	done
+
+	# Don't forget to umount /boot if it was previously mounted by us.
+	use initramfs && mount-boot_pkg_postinst
+}
+
+pkg_prerm() {
+	# Make sure /boot is mounted so that we can remove /boot/amd-uc.img!
+	use initramfs && mount-boot_pkg_prerm
+}
+
+pkg_postrm() {
+	# Don't forget to umount /boot if it was previously mounted by us.
+	use initramfs && mount-boot_pkg_postrm
+}