gentoo resync : 31.05.2021

1 files changed, 71 insertions, 0 deletions

diff --git a/sys-kernel/pf-sources/pf-sources-5.12_p3.ebuild b/sys-kernel/pf-sources/pf-sources-5.12_p3.ebuild
new file mode 100644
index 000000000000..fed5b00b686c
--- /dev/null
+++ b/sys-kernel/pf-sources/pf-sources-5.12_p3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Define what default functions to run
+ETYPE="sources"
+
+# No 'experimental' USE flag provided, but we still want to use genpatches
+K_EXP_GENPATCHES_NOUSE="1"
+
+# Just get basic genpatches, -pf patch set already includes vanilla-linux updates
+K_GENPATCHES_VER="1"
+
+# -pf already sets EXTRAVERSION to kernel Makefile
+K_NOSETEXTRAVERSION="1"
+
+# Not supported by the Gentoo security team
+K_SECURITY_UNSUPPORTED="1"
+
+# We want the very basic patches from gentoo-sources, experimental patch is
+# already included in pf-sources
+K_WANT_GENPATCHES="base extras"
+
+SHPV="${PV/_p*/}"
+
+inherit kernel-2 optfeature
+detect_version
+
+DESCRIPTION="Linux kernel fork that includes the pf-kernel patchset and Gentoo's genpatches"
+HOMEPAGE="https://gitlab.com/post-factum/pf-kernel/-/wikis/README
+	https://dev.gentoo.org/~mpagano/genpatches/"
+SRC_URI="${KERNEL_URI}
+	https://github.com/pfactum/pf-kernel/compare/v${SHPV}...v${SHPV}-pf${PV/*_p/}.diff -> ${P}.patch
+	https://dev.gentoo.org/~mpagano/genpatches/tarballs/genpatches-${SHPV}-${K_GENPATCHES_VER}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/genpatches/tarballs/genpatches-${SHPV}-${K_GENPATCHES_VER}.extras.tar.xz
+	https://raw.githubusercontent.com/GKernelCI/linux-patches/${SHPV}/5020_BMQ-and-PDS-io-scheduler-v${SHPV}-r0.patch
+	https://raw.githubusercontent.com/GKernelCI/linux-patches/${SHPV}/5021_BMQ-and-PDS-gentoo-defaults-v${SHPV}-r0.patch"
+
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+S="${WORKDIR}/linux-${PVR}-pf"
+
+PATCHES=( "${DISTDIR}/${P}.patch"
+	"${DISTDIR}/5020_BMQ-and-PDS-io-scheduler-v${SHPV}-r0.patch"
+	"${DISTDIR}/5021_BMQ-and-PDS-gentoo-defaults-v${SHPV}-r0.patch" )
+
+K_EXTRAEINFO="For more info on pf-sources and details on how to report problems,
+	see: ${HOMEPAGE}."
+
+pkg_setup() {
+	ewarn ""
+	ewarn "${PN} is *not* supported by the Gentoo Kernel Project in any way."
+	ewarn "If you need support, please contact the pf developers directly."
+	ewarn "Do *not* open bugs in Gentoo's bugzilla unless you have issues with"
+	ewarn "the ebuilds. Thank you."
+	ewarn ""
+
+	kernel-2_pkg_setup
+}
+
+src_prepare() {
+	# kernel-2_src_prepare doesn't apply PATCHES().
+	default
+}
+
+pkg_postinst() {
+	kernel-2_pkg_postinst
+
+	optfeature "userspace KSM helper" sys-process/uksmd
+}