gentoo auto-resync : 20:01:2024 - 02:08:45

2 files changed, 326 insertions, 0 deletions

diff --git a/sys-kernel/genkernel/Manifest b/sys-kernel/genkernel/Manifest
index 7f126fcd6eac..7095932aa142 100644
--- a/sys-kernel/genkernel/Manifest
+++ b/sys-kernel/genkernel/Manifest
@@ -21,6 +21,7 @@ DIST eudev-3.2.10.tar.gz 1961960 BLAKE2B 3708c78fad3abad6aa4b2beaaa325e25e118621
 DIST expat-2.4.1.tar.xz 445024 BLAKE2B 2ae66d284a03176ef7290093f59bb7ad98011dfbf3c7c3515ba4e4b99f849474def6ce6d9844c944fed22d86ac4ea1a38863646be914d9432eda7b69d890be65 SHA512 9dc760dbf701f75e55c4479d81417622f8c750d8473498458a382a4c2932a2976a059cb3589f88855188e5173ec7868d285c4601428e0ca625df7a59cf975191
 DIST expat-2.5.0.tar.xz 460560 BLAKE2B 670298d076ff3b512a0212170d40cb04c601a11d6b152f215a5302ad3238c69c2386393d7a6c70bc284be35ce97bf27d87115c3391f4bc17406e509d739d3e31 SHA512 2da73b991b7c0c54440485c787e5edeb3567230204e31b3cac1c3a6713ec6f9f1554d3afffc0f8336168dfd5df02db4a69bcf21b4d959723d14162d13ab87516
 DIST fuse-2.9.9.tar.gz 1813177 BLAKE2B 9e9141380bda46eb0bcce325c6fd293fe3844fe884a4952bb38d4b89dc48b728ffcc891038b3a7a861f05acfacce9dd7bb0e11d600609f3ad0ab278ccbe98847 SHA512 3d82fafd04f2924299bb09d2bb144935fa004a43fb9a6568e2e1cc5a60fded2efa1711029a0d7f12b3e6e4501f7217f2ee3545646d89da8dece083cb390f23e2
+DIST genkernel-4.3.10.tar.xz 484664 BLAKE2B ec1c44e633927c2c2fa12e22f428f6667ff5a768071aeecafb370f0e5ba0953c694661048a25f904a602f5acfc3a07a2be7042f4c247ab483d7241452c8df77a SHA512 443bc5c1980271d958255089a7981738979672a540e803789ee4a08d16e69e2a866266ae566da78dc02a3f31a4a9d049d302cab14392e931028040936ea7a512
 DIST genkernel-4.3.2.tar.xz 480168 BLAKE2B bde9abb37c0da8b4638618d17ea79eeffe1b8c1192ed11ace6e93541106ecb54d34644016488a1825077a966fa9a48ea655299dd6cd7b037db1292232fd66f5c SHA512 61e48badb5822833e570b800336b41d0ff36275961d956755b65971d98ca4c2feb0fbd88d27bc7caeb6e60ac8748036e7ffcdad8e37d09fee08cfc6174f43b15
 DIST genkernel-4.3.3.tar.xz 478772 BLAKE2B 60061335cf965df4add578cc59f0b548eddb4efab3ae96ddfcfaa116f85ffdf97ae5d667456f7da9257664945ce6748f987b8ae687c077b71ad1023ade23374d SHA512 2f543fda8451bf283ab835fdfbf3649fe561af9aa1356fe92e74b0ac248223f8f09c83ffa4d9f54bf74428b0c194f9decd21715a97e7a906e6e56576a4eab163
 DIST genkernel-4.3.5.tar.xz 479312 BLAKE2B ba38b33832138492e56316bf5bd985ea831be51006ccd2aaf1503b69d706ef39fbd94e007edd3014376796319f887107e9ecbed81ce6259afa05a0d788a3aa1f SHA512 22e7d45492add9f5d8cf3523f1cf8d5364a164db9cd4858c020086514fc3312e1739845ae716eddc6f6306748ed95a770b2a75b818bc8542003169257853ec89
@@ -60,6 +61,7 @@ DIST zlib-1.2.11.tar.gz 607698 BLAKE2B 6bfc4bca5dcadba8a0d4121a2b3ed0bfe440c2610
 DIST zlib-1.2.13.tar.gz 1497445 BLAKE2B 73cd65f287d662a988287205b74e93d516d6a74e18555d0f1a2777557e73e81249b45341c687fe97e65406a7210f77b8914ed146bac517d3fcc4c9fcb16546d3 SHA512 99f0e843f52290e6950cc328820c0f322a4d934a504f66c7caa76bd0cc17ece4bf0546424fc95135de85a2656fed5115abb835fd8d8a390d60ffaf946c8887ad
 DIST zstd-1.5.0.tar.gz 1867111 BLAKE2B e503d17478b94128eb3ec578178f9d7023e941434dcc07790e12fd6c9933518f34fba5d7795ab7b145e4e499597644a6edd2830106649c5a749c962d5afe2f31 SHA512 25b657529a698eec891f92ff4a085d1fd95d2ff938ce52c8a4ff6163eb0b668ec642dd09e0db190652638cd92371006afa01d8e437437762c4097ad301675c33
 DIST zstd-1.5.5.tar.gz 2368543 BLAKE2B 7680e27a0adacfb809d9fc81e06d3f99bf74df30374d3b5cb2d58f667dd1b7d5c41697e608592709e17c0e32277f20a6d615edee409b5d7cdcb15da2799a2350 SHA512 99109ec0e07fa65c2101c9cb36be56b672bbd0ee69d265f924718e61f9192ae8385c8d9e4d0c318be9edfa6d849fd3d60e5f164fa120961449429ea3c5dab6b6
+EBUILD genkernel-4.3.10.ebuild 11874 BLAKE2B 361f7468e92f96956bb5816416706befc161b44afe54a1f8b8afacc4db955bdba6d5827235669f3f856869e92bc95c67caa0b037f41a190fb5211241f7e18674 SHA512 a2acd1bda056d0572eee47aa30e05696b5882ef29b251dadd839e7b02d5af851abeabf5c511b7151775c3f4bc20bc47eaffe38b4bca24874e380005588ab4ec4
 EBUILD genkernel-4.3.2-r1.ebuild 11814 BLAKE2B c1df24ccd2c4f4b86089be357abbb707636b8b4044c4a4bb01f174fafb34b9a2ca9010f95eab4652032276929856f8780eedd2ebdf3c597b083236897ee35358 SHA512 c641f5f79d28fad0a83b69127f61990b6866d3eec122c682cc9b0ec9a7095260b5d85604679ef999501713d0e5fdf5bdc9feb5de25979c4e766248dfbe8e9047
 EBUILD genkernel-4.3.3.ebuild 11776 BLAKE2B 48ccc69eb2bdfcf78acd6a464f5bcdcd2a323d81a283d30529e3b673015284e4741f8d2f5da6009358bf2a7d81fb80c500f0149c2eae1331d93dcfdb842693f4 SHA512 d495a829b1ae85dca0429e3351d78d7c62245cbbc3b608ecdb94da9d199e1dd12a5acf4731ea0cda43ea10a9c360f0496d23527955b78b8694fc5b377469719e
 EBUILD genkernel-4.3.5-r1.ebuild 11841 BLAKE2B a09cf59d383f7ea193e28f0eba9f74d0571919a8547fae13de5d651148bb2b9bb07b78d4500a3aaf162b302710251cd71414854779ac040cfe08a7059a0a4e2f SHA512 731ec3991f5d19201517bc0fe1835643daf53fe71619be0d32e205cf2791cca8cef663e1f265c1dc3b03fe3c619d402fa2b65994b6d8a678b22476e95676fb98
diff --git a/sys-kernel/genkernel/genkernel-4.3.10.ebuild b/sys-kernel/genkernel/genkernel-4.3.10.ebuild
new file mode 100644
index 000000000000..83566bbbf9f0
--- /dev/null
+++ b/sys-kernel/genkernel/genkernel-4.3.10.ebuild
@@ -0,0 +1,324 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# genkernel-9999        -> latest Git branch "master"
+# genkernel-VERSION     -> normal genkernel release
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit bash-completion-r1 python-single-r1
+
+# Whenever you bump a GKPKG, check if you have to move
+# or add new patches!
+VERSION_BCACHE_TOOLS="1.0.8_p20141204"
+VERSION_BOOST="1.79.0"
+VERSION_BTRFS_PROGS="6.3.2"
+VERSION_BUSYBOX="1.36.1"
+VERSION_COREUTILS="9.3"
+VERSION_CRYPTSETUP="2.6.1"
+VERSION_DMRAID="1.0.0.rc16-3"
+VERSION_DROPBEAR="2022.83"
+VERSION_EUDEV="3.2.10"
+VERSION_EXPAT="2.5.0"
+VERSION_E2FSPROGS="1.46.4"
+VERSION_FUSE="2.9.9"
+VERSION_GPG="1.4.23"
+VERSION_HWIDS="20210613"
+VERSION_ISCSI="2.1.8"
+VERSION_JSON_C="0.13.1"
+VERSION_KMOD="30"
+VERSION_LIBAIO="0.3.113"
+VERSION_LIBGCRYPT="1.9.4"
+VERSION_LIBGPGERROR="1.43"
+VERSION_LIBXCRYPT="4.4.36"
+VERSION_LVM="2.02.188"
+VERSION_LZO="2.10"
+VERSION_MDADM="4.1"
+VERSION_POPT="1.18"
+VERSION_STRACE="6.4"
+VERSION_THIN_PROVISIONING_TOOLS="0.9.0"
+VERSION_UNIONFS_FUSE="2.0"
+VERSION_USERSPACE_RCU="0.14.0"
+VERSION_UTIL_LINUX="2.38.1"
+VERSION_XFSPROGS="6.3.0"
+VERSION_XZ="5.4.3"
+VERSION_ZLIB="1.2.13"
+VERSION_ZSTD="1.5.5"
+VERSION_KEYUTILS="1.6.3"
+
+COMMON_URI="
+	https://github.com/g2p/bcache-tools/archive/399021549984ad27bf4a13ae85e458833fe003d7.tar.gz -> bcache-tools-${VERSION_BCACHE_TOOLS}.tar.gz
+	https://boostorg.jfrog.io/artifactory/main/release/${VERSION_BOOST}/source/boost_${VERSION_BOOST//./_}.tar.bz2
+	https://www.kernel.org/pub/linux/kernel/people/kdave/btrfs-progs/btrfs-progs-v${VERSION_BTRFS_PROGS}.tar.xz
+	https://www.busybox.net/downloads/busybox-${VERSION_BUSYBOX}.tar.bz2
+	mirror://gnu/coreutils/coreutils-${VERSION_COREUTILS}.tar.xz
+	https://www.kernel.org/pub/linux/utils/cryptsetup/v$(ver_cut 1-2 ${VERSION_CRYPTSETUP})/cryptsetup-${VERSION_CRYPTSETUP}.tar.xz
+	https://people.redhat.com/~heinzm/sw/dmraid/src/dmraid-${VERSION_DMRAID}.tar.bz2
+	https://matt.ucc.asn.au/dropbear/releases/dropbear-${VERSION_DROPBEAR}.tar.bz2
+	https://dev.gentoo.org/~blueness/eudev/eudev-${VERSION_EUDEV}.tar.gz
+	https://github.com/libexpat/libexpat/releases/download/R_${VERSION_EXPAT//\./_}/expat-${VERSION_EXPAT}.tar.xz
+	https://www.kernel.org/pub/linux/kernel/people/tytso/e2fsprogs/v${VERSION_E2FSPROGS}/e2fsprogs-${VERSION_E2FSPROGS}.tar.xz
+	https://github.com/libfuse/libfuse/releases/download/fuse-${VERSION_FUSE}/fuse-${VERSION_FUSE}.tar.gz
+	mirror://gnupg/gnupg/gnupg-${VERSION_GPG}.tar.bz2
+	https://github.com/gentoo/hwids/archive/hwids-${VERSION_HWIDS}.tar.gz
+	https://github.com/open-iscsi/open-iscsi/archive/${VERSION_ISCSI}.tar.gz -> open-iscsi-${VERSION_ISCSI}.tar.gz
+	https://s3.amazonaws.com/json-c_releases/releases/json-c-${VERSION_JSON_C}.tar.gz
+	https://www.kernel.org/pub/linux/utils/kernel/kmod/kmod-${VERSION_KMOD}.tar.xz
+	https://releases.pagure.org/libaio/libaio-${VERSION_LIBAIO}.tar.gz
+	mirror://gnupg/libgcrypt/libgcrypt-${VERSION_LIBGCRYPT}.tar.bz2
+	mirror://gnupg/libgpg-error/libgpg-error-${VERSION_LIBGPGERROR}.tar.bz2
+	https://github.com/besser82/libxcrypt/releases/download/v${VERSION_LIBXCRYPT}/libxcrypt-${VERSION_LIBXCRYPT}.tar.xz
+	https://mirrors.kernel.org/sourceware/lvm2/LVM2.${VERSION_LVM}.tgz
+	https://www.oberhumer.com/opensource/lzo/download/lzo-${VERSION_LZO}.tar.gz
+	https://www.kernel.org/pub/linux/utils/raid/mdadm/mdadm-${VERSION_MDADM}.tar.xz
+	http://ftp.rpm.org/popt/releases/popt-1.x/popt-${VERSION_POPT}.tar.gz
+	https://github.com/strace/strace/releases/download/v${VERSION_STRACE}/strace-${VERSION_STRACE}.tar.xz
+	https://github.com/jthornber/thin-provisioning-tools/archive/v${VERSION_THIN_PROVISIONING_TOOLS}.tar.gz -> thin-provisioning-tools-${VERSION_THIN_PROVISIONING_TOOLS}.tar.gz
+	https://github.com/rpodgorny/unionfs-fuse/archive/v${VERSION_UNIONFS_FUSE}.tar.gz -> unionfs-fuse-${VERSION_UNIONFS_FUSE}.tar.gz
+	https://lttng.org/files/urcu/userspace-rcu-${VERSION_USERSPACE_RCU}.tar.bz2
+	https://www.kernel.org/pub/linux/utils/util-linux/v${VERSION_UTIL_LINUX:0:4}/util-linux-${VERSION_UTIL_LINUX}.tar.xz
+	https://www.kernel.org/pub/linux/utils/fs/xfs/xfsprogs/xfsprogs-${VERSION_XFSPROGS}.tar.xz
+	https://tukaani.org/xz/xz-${VERSION_XZ}.tar.gz
+	https://zlib.net/zlib-${VERSION_ZLIB}.tar.gz
+	https://github.com/facebook/zstd/archive/v${VERSION_ZSTD}.tar.gz -> zstd-${VERSION_ZSTD}.tar.gz
+	https://git.kernel.org/pub/scm/linux/kernel/git/dhowells/keyutils.git/snapshot/keyutils-${VERSION_KEYUTILS}.tar.gz
+"
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/${PN}.git"
+	inherit git-r3
+	S="${WORKDIR}/${P}"
+	SRC_URI="${COMMON_URI}"
+else
+	SRC_URI="https://dev.gentoo.org/~bkohler/dist/${P}.tar.xz
+		${COMMON_URI}"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Gentoo automatic kernel building scripts"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Genkernel https://gitweb.gentoo.org/proj/genkernel.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+RESTRICT=""
+IUSE="ibm +firmware"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Note:
+# We need sys-devel/* deps like autoconf or automake at _runtime_
+# because genkernel will usually build things like LVM2, cryptsetup,
+# mdadm... during initramfs generation which will require these
+# things.
+DEPEND=""
+RDEPEND="${PYTHON_DEPS}
+	app-alternatives/cpio
+	>=app-misc/pax-utils-1.2.2
+	app-portage/elt-patches
+	app-portage/portage-utils
+	dev-util/gperf
+	sys-apps/sandbox
+	dev-build/autoconf
+	dev-build/autoconf-archive
+	dev-build/automake
+	app-alternatives/bc
+	app-alternatives/yacc
+	app-alternatives/lex
+	dev-build/libtool
+	virtual/pkgconfig
+	elibc_glibc? ( sys-libs/glibc[static-libs(+)] )
+	firmware? ( sys-kernel/linux-firmware )"
+
+if [[ ${PV} == 9999* ]]; then
+	DEPEND="${DEPEND} app-text/asciidoc"
+fi
+
+PATCHES=(
+)
+
+src_unpack() {
+	if [[ ${PV} == 9999* ]]; then
+		git-r3_src_unpack
+	else
+		local gk_src_file
+		for gk_src_file in ${A} ; do
+			if [[ ${gk_src_file} == genkernel-* ]] ; then
+				unpack "${gk_src_file}"
+			fi
+		done
+	fi
+}
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999* ]] ; then
+		einfo "Updating version tag"
+		GK_V="$(git describe --tags | sed 's:^v::')-git"
+		sed "/^GK_V/s,=.*,='${GK_V}',g" -i "${S}"/genkernel
+		einfo "Producing ChangeLog from Git history..."
+		pushd "${S}/.git" >/dev/null || die
+		git log > "${S}"/ChangeLog || die
+		popd >/dev/null || die
+	fi
+
+	# Update software.sh
+	sed -i \
+		-e "s:VERSION_BCACHE_TOOLS:${VERSION_BCACHE_TOOLS}:"\
+		-e "s:VERSION_BOOST:${VERSION_BOOST}:"\
+		-e "s:VERSION_BTRFS_PROGS:${VERSION_BTRFS_PROGS}:"\
+		-e "s:VERSION_BUSYBOX:${VERSION_BUSYBOX}:"\
+		-e "s:VERSION_COREUTILS:${VERSION_COREUTILS}:"\
+		-e "s:VERSION_CRYPTSETUP:${VERSION_CRYPTSETUP}:"\
+		-e "s:VERSION_DMRAID:${VERSION_DMRAID}:"\
+		-e "s:VERSION_DROPBEAR:${VERSION_DROPBEAR}:"\
+		-e "s:VERSION_EUDEV:${VERSION_EUDEV}:"\
+		-e "s:VERSION_EXPAT:${VERSION_EXPAT}:"\
+		-e "s:VERSION_E2FSPROGS:${VERSION_E2FSPROGS}:"\
+		-e "s:VERSION_FUSE:${VERSION_FUSE}:"\
+		-e "s:VERSION_GPG:${VERSION_GPG}:"\
+		-e "s:VERSION_HWIDS:${VERSION_HWIDS}:"\
+		-e "s:VERSION_ISCSI:${VERSION_ISCSI}:"\
+		-e "s:VERSION_JSON_C:${VERSION_JSON_C}:"\
+		-e "s:VERSION_KMOD:${VERSION_KMOD}:"\
+		-e "s:VERSION_LIBAIO:${VERSION_LIBAIO}:"\
+		-e "s:VERSION_LIBGCRYPT:${VERSION_LIBGCRYPT}:"\
+		-e "s:VERSION_LIBGPGERROR:${VERSION_LIBGPGERROR}:"\
+		-e "s:VERSION_LIBXCRYPT:${VERSION_LIBXCRYPT}:"\
+		-e "s:VERSION_LVM:${VERSION_LVM}:"\
+		-e "s:VERSION_LZO:${VERSION_LZO}:"\
+		-e "s:VERSION_MDADM:${VERSION_MDADM}:"\
+		-e "s:VERSION_MULTIPATH_TOOLS:${VERSION_MULTIPATH_TOOLS}:"\
+		-e "s:VERSION_POPT:${VERSION_POPT}:"\
+		-e "s:VERSION_STRACE:${VERSION_STRACE}:"\
+		-e "s:VERSION_THIN_PROVISIONING_TOOLS:${VERSION_THIN_PROVISIONING_TOOLS}:"\
+		-e "s:VERSION_UNIONFS_FUSE:${VERSION_UNIONFS_FUSE}:"\
+		-e "s:VERSION_USERSPACE_RCU:${VERSION_USERSPACE_RCU}:"\
+		-e "s:VERSION_UTIL_LINUX:${VERSION_UTIL_LINUX}:"\
+		-e "s:VERSION_XFSPROGS:${VERSION_XFSPROGS}:"\
+		-e "s:VERSION_XZ:${VERSION_XZ}:"\
+		-e "s:VERSION_ZLIB:${VERSION_ZLIB}:"\
+		-e "s:VERSION_ZSTD:${VERSION_ZSTD}:"\
+		"${S}"/defaults/software.sh \
+		|| die "Could not adjust versions"
+}
+
+src_compile() {
+	if [[ ${PV} == 9999* ]] ; then
+		emake
+	fi
+}
+
+src_install() {
+	insinto /etc
+	doins "${S}"/genkernel.conf
+
+	doman genkernel.8
+	dodoc AUTHORS ChangeLog README TODO
+	dobin genkernel
+	rm -f genkernel genkernel.8 AUTHORS ChangeLog README TODO genkernel.conf
+
+	if use ibm ; then
+		cp "${S}"/arch/ppc64/kernel-2.6{-pSeries,} || die
+	else
+		cp "${S}"/arch/ppc64/kernel-2.6{.g5,} || die
+	fi
+
+	insinto /usr/share/genkernel
+	doins -r "${S}"/*
+
+	fperms +x /usr/share/genkernel/gen_worker.sh
+	fperms +x /usr/share/genkernel/path_expander.py
+
+	python_fix_shebang "${ED}"/usr/share/genkernel/path_expander.py
+
+	newbashcomp "${FILESDIR}"/genkernel-4.bash "${PN}"
+	insinto /etc
+	doins "${FILESDIR}"/initramfs.mounts
+
+	pushd "${DISTDIR}" &>/dev/null || die
+	insinto /usr/share/genkernel/distfiles
+	doins ${A/${P}.tar.xz/}
+	popd &>/dev/null || die
+}
+
+pkg_postinst() {
+	# Wiki is out of date
+	#echo
+	#elog 'Documentation is available in the genkernel manual page'
+	#elog 'as well as the following URL:'
+	#echo
+	#elog 'https://wiki.gentoo.org/wiki/Genkernel'
+	#echo
+
+	local replacing_version
+	for replacing_version in ${REPLACING_VERSIONS} ; do
+		if ver_test "${replacing_version}" -lt 4 ; then
+			# This is an upgrade which requires user review
+
+			ewarn ""
+			ewarn "Genkernel v4.x is a new major release which touches"
+			ewarn "nearly everything. Be careful, read updated manpage"
+			ewarn "and pay special attention to program output regarding"
+			ewarn "changed kernel command-line parameters!"
+
+			# Show this elog only once
+			break
+		fi
+	done
+
+	if [[ $(find /boot -name 'kernel-genkernel-*' 2>/dev/null | wc -l) -gt 0 ]] ; then
+		ewarn ''
+		ewarn 'Default kernel filename was changed from "kernel-genkernel-<ARCH>-<KV>"'
+		ewarn 'to "vmlinuz-<KV>". Please be aware that due to lexical ordering the'
+		ewarn '*default* boot entry in your boot manager could still point to last kernel'
+		ewarn 'built with genkernel before that name change, resulting in booting old'
+		ewarn 'kernel when not paying attention on boot.'
+	fi
+
+	# Show special warning for users depending on remote unlock capabilities
+	local gk_config="${EROOT}/etc/genkernel.conf"
+	if [[ -f "${gk_config}" ]] ; then
+		if grep -q -E "^SSH=[\"\']?yes" "${gk_config}" 2>/dev/null ; then
+			if ! grep -q dosshd /proc/cmdline 2>/dev/null ; then
+				ewarn ""
+				ewarn "IMPORTANT: SSH is currently enabled in your genkernel config"
+				ewarn "file (${gk_config}). However, 'dosshd' is missing from current"
+				ewarn "kernel command-line. You MUST add 'dosshd' to keep sshd enabled"
+				ewarn "in genkernel v4+ initramfs!"
+			fi
+		fi
+
+		if grep -q -E "^CMD_CALLBACK=.*emerge.*@module-rebuild" "${gk_config}" 2>/dev/null ; then
+			elog ""
+			elog "Please remove 'emerge @module-rebuild' from genkernel config"
+			elog "file (${gk_config}) and make use of new MODULEREBUILD option"
+			elog "instead."
+		fi
+	fi
+
+	local n_root_args=$(grep -o -- '\<root=' /proc/cmdline 2>/dev/null | wc -l)
+	if [[ ${n_root_args} -gt 1 ]] ; then
+		ewarn "WARNING: Multiple root arguments (root=) on kernel command-line detected!"
+		ewarn "If you are appending non-persistent device names to kernel command-line,"
+		ewarn "next reboot could fail in case running system and initramfs do not agree"
+		ewarn "on detected root device name!"
+	fi
+
+	if [[ -d /run ]] ; then
+		local permission_run_expected="drwxr-xr-x"
+		local permission_run=$(stat -c "%A" /run)
+		if [[ "${permission_run}" != "${permission_run_expected}" ]] ; then
+			ewarn "Found the following problematic permissions:"
+			ewarn ""
+			ewarn "    ${permission_run} /run"
+			ewarn ""
+			ewarn "Expected:"
+			ewarn ""
+			ewarn "    ${permission_run_expected} /run"
+			ewarn ""
+			ewarn "This is known to be causing problems for any UDEV-enabled service."
+		fi
+	fi
+}