gentoo auto-resync : 09:01:2023 - 00:17:07

3 files changed, 327 insertions, 3 deletions

diff --git a/sys-kernel/genkernel/Manifest b/sys-kernel/genkernel/Manifest
index 61a94e082bd0..4489c7a4feeb 100644
--- a/sys-kernel/genkernel/Manifest
+++ b/sys-kernel/genkernel/Manifest
@@ -31,6 +31,7 @@ DIST genkernel-4.0.10.tar.xz 460816 BLAKE2B d5922eede1192bb95ca235106a70118826c2
 DIST genkernel-4.2.6-s390x.patch 39633 BLAKE2B a48aae069b41e2520fce9ac60a79f567225bcb798bfa02ccc5c279427381d3f0e59bb0d8231b7e9760c22a1bccf17ae826d0f01973e32f9a4f0ab60165c8fbdd SHA512 d1db9f2c36cf9c0d7f042ec682c2b61817eda0d21c35515dc313ad8901c7c4239a28937c4b411f796ab38278caaa1fa3a7c7e7d6dd9c8ba3f4f37fbba5988105
 DIST genkernel-4.2.6.tar.xz 488892 BLAKE2B 4dc54c878e25165799ac40e45f28843c057348006a9e1a8dc2dec499e0ef78705104ae6893e15f76fc88cc054137d781cae1c4ec395fba669f6c93ec6fa8d6d9 SHA512 5981be08aac31c1cac22efd66e9cb39e6362cc7cac90dc26dd2089f95f287908dcbfb58a7da0bde6205bf42c57c606b96ed2e190b6d0fed1cfade9bae76b11fb
 DIST genkernel-4.3.1.tar.xz 478784 BLAKE2B 34ba4631c486e08610bc67eddf2b6738e1e4b8f2879d477d686985190390f4c5b948dd9e73f4a18afca484b550a74b1e6b9f21d7ab886a8f1e289a9cb91ebaba SHA512 49f58a2262ff214c7361b3141a684bdfb60c446d30232dfd6fed84b5953d2825095fba9188e270dcd1f00e7fcd884d1ca642473d56dd6f17daf440478639598d
+DIST genkernel-4.3.2.tar.xz 480168 BLAKE2B bde9abb37c0da8b4638618d17ea79eeffe1b8c1192ed11ace6e93541106ecb54d34644016488a1825077a966fa9a48ea655299dd6cd7b037db1292232fd66f5c SHA512 61e48badb5822833e570b800336b41d0ff36275961d956755b65971d98ca4c2feb0fbd88d27bc7caeb6e60ac8748036e7ffcdad8e37d09fee08cfc6174f43b15
 DIST gnupg-1.4.23.tar.bz2 3749353 BLAKE2B ec5e6bef0c7bb2a65813d7852cebeaa24c4855f9d9d9e802070da50b89fff56b747682933aa766dd130f849efcfe28f7aa74f3153405429bcf3845ef29c6dd6e SHA512 78dc52a2010202a4afc8814b29fda657a6c9fe230d5e7db11ae040edd2b0ca819e1baa4dbd6c0d04d36cd353df484e83f52d17759d2891c2cf7025c0b5d36612
 DIST hwids-20210613.tar.gz 3867741 BLAKE2B 64c4b0a83058a2052f7b132241008a3cc75452e93a9a57a9159c357c23fd09ee256abc2b94e700b5d8e8bd4e231ae12932d2c2f32fb03853207739cb3387047d SHA512 4568f6b8c0ca80ec772bd2785d4dc169d1d13a721472a15399158d9a7f31abbe414c5c8cfdf1a3b81cce4e33742a4b6e005e97e3e907643d0afdc8e953624fea
 DIST json-c-0.13.1.tar.gz 639425 BLAKE2B 1da310309f9ce03306a9fd4a161670e460cf0b2222348df7c006902390f74a4cf100aab1ce6ac8a361a278dd917c114a278de5b3445817f3a40ae287478add46 SHA512 e984db2a42b9c95b52c798b2e8dd1b79951a8dcba27370af30c43b9549fbb00008dbcf052a535c528209aaee38e6d1f760168b706905ae72f3e704ed20f8a1a1
@@ -64,5 +65,6 @@ EBUILD genkernel-4.0.10.ebuild 9583 BLAKE2B eb8f46374b3dd8a2f51db002e666ce64b32a
 EBUILD genkernel-4.2.6-r6.ebuild 11948 BLAKE2B 5c2281ee1a0caeea8950ff16d573b95e2590bcc1a5c866c65126ea34880c24d704bcf2eecc3855f04b151283094357d958117574eee515088c31b5d2ee7b0bf5 SHA512 93e7b2018151c954130e9fd89e34c488f9c65131c283bf62d062f86d6a8e6b2e533dba092f347a39249e20215becd8736dfc18d285482db2d789468eb8051f2a
 EBUILD genkernel-4.2.6-r8.ebuild 12019 BLAKE2B e9751fc1ba8f1de8eeea8a10ee9433ffa18afae5217ee051587f2ad65e339bf49553217197085125901f857daf3d116a9596f12febbfb99608a3073c9827069b SHA512 ec696f1243ebf6327521ca5b2fa3298d01978ffba9561f7bedfd28d699978eb7b524593cfd87fe7cead3367ded1b8f98aa3217545698683ced9fdbaefd88abec
 EBUILD genkernel-4.3.1-r1.ebuild 11750 BLAKE2B a33e3b637078bd9f979db80440edd33a48bd48ab4817786eb1440bb47510f0a9b1df74a4763d79889a64afbeacb552a7734dceccb50220215fddeececcab1207 SHA512 705e983c05855c71304050f22e7e066c9a7baa3cbf07c63db3f77194c6345e56de0e2fa3bd241d5ad8c1dbb822f276486a0214cb83028e8dc42e899b2970283f
-EBUILD genkernel-9999.ebuild 11750 BLAKE2B a33e3b637078bd9f979db80440edd33a48bd48ab4817786eb1440bb47510f0a9b1df74a4763d79889a64afbeacb552a7734dceccb50220215fddeececcab1207 SHA512 705e983c05855c71304050f22e7e066c9a7baa3cbf07c63db3f77194c6345e56de0e2fa3bd241d5ad8c1dbb822f276486a0214cb83028e8dc42e899b2970283f
+EBUILD genkernel-4.3.2.ebuild 11750 BLAKE2B f3eca4080a97d4480af8a4595671088b50b1185cecf74b0edc0ccb29c6b993b747d03f3ef80d11e16b6626b68bae4b3468a784f497d8a605a9f8de0df4d99d7c SHA512 46b9d00e57cd655f5e59281a5908b57a074b2ce2f77d4d280edacb8c8d51c0c7f0fab72aaaa00dbe8e98a02470a6197f437ef0f9e8efa9fb569e7c5a3ebe3139
+EBUILD genkernel-9999.ebuild 11750 BLAKE2B f3eca4080a97d4480af8a4595671088b50b1185cecf74b0edc0ccb29c6b993b747d03f3ef80d11e16b6626b68bae4b3468a784f497d8a605a9f8de0df4d99d7c SHA512 46b9d00e57cd655f5e59281a5908b57a074b2ce2f77d4d280edacb8c8d51c0c7f0fab72aaaa00dbe8e98a02470a6197f437ef0f9e8efa9fb569e7c5a3ebe3139
 MISC metadata.xml 480 BLAKE2B 8b1b1655cb13d866985a92755b0696bef00841a7626cb6cd10f39d7a7ad196c1ec2f5895f86e23fc3ee1345c48d7c659346d2bc7bb2a2bdaa9c997511f002fd8 SHA512 5030d4505b077faec4e2eb9cb2dcc47195a1864057bcb5f110314bab97b90b1bdcd3f293f76116a23dd0e694c7c8ee66ed46d39c9b7b0c506b22fe23e86febc4
diff --git a/sys-kernel/genkernel/genkernel-4.3.2.ebuild b/sys-kernel/genkernel/genkernel-4.3.2.ebuild
new file mode 100644
index 000000000000..78336f91ab63
--- /dev/null
+++ b/sys-kernel/genkernel/genkernel-4.3.2.ebuild
@@ -0,0 +1,322 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# genkernel-9999        -> latest Git branch "master"
+# genkernel-VERSION     -> normal genkernel release
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit bash-completion-r1 python-single-r1
+
+# Whenever you bump a GKPKG, check if you have to move
+# or add new patches!
+VERSION_BCACHE_TOOLS="1.0.8_p20141204"
+VERSION_BOOST="1.79.0"
+VERSION_BTRFS_PROGS="5.15"
+VERSION_BUSYBOX="1.34.1"
+VERSION_COREUTILS="8.32"
+VERSION_CRYPTSETUP="2.4.1"
+VERSION_DMRAID="1.0.0.rc16-3"
+VERSION_DROPBEAR="2020.81"
+VERSION_EUDEV="3.2.10"
+VERSION_EXPAT="2.4.1"
+VERSION_E2FSPROGS="1.46.4"
+VERSION_FUSE="2.9.9"
+VERSION_GPG="1.4.23"
+VERSION_HWIDS="20210613"
+VERSION_ISCSI="2.0.878"
+VERSION_JSON_C="0.13.1"
+VERSION_KMOD="29"
+VERSION_LIBAIO="0.3.112"
+VERSION_LIBGCRYPT="1.9.4"
+VERSION_LIBGPGERROR="1.43"
+VERSION_LIBXCRYPT="4.4.26"
+VERSION_LVM="2.02.188"
+VERSION_LZO="2.10"
+VERSION_MDADM="4.1"
+VERSION_POPT="1.18"
+VERSION_STRACE="5.14"
+VERSION_THIN_PROVISIONING_TOOLS="0.9.0"
+VERSION_UNIONFS_FUSE="2.0"
+VERSION_UTIL_LINUX="2.37.2"
+VERSION_XFSPROGS="5.13.0"
+VERSION_XZ="5.2.5"
+VERSION_ZLIB="1.2.11"
+VERSION_ZSTD="1.5.0"
+VERSION_KEYUTILS="1.6.3"
+
+COMMON_URI="
+	https://github.com/g2p/bcache-tools/archive/399021549984ad27bf4a13ae85e458833fe003d7.tar.gz -> bcache-tools-${VERSION_BCACHE_TOOLS}.tar.gz
+	https://boostorg.jfrog.io/artifactory/main/release/${VERSION_BOOST}/source/boost_${VERSION_BOOST//./_}.tar.bz2
+	https://www.kernel.org/pub/linux/kernel/people/kdave/btrfs-progs/btrfs-progs-v${VERSION_BTRFS_PROGS}.tar.xz
+	https://www.busybox.net/downloads/busybox-${VERSION_BUSYBOX}.tar.bz2
+	mirror://gnu/coreutils/coreutils-${VERSION_COREUTILS}.tar.xz
+	https://www.kernel.org/pub/linux/utils/cryptsetup/v$(ver_cut 1-2 ${VERSION_CRYPTSETUP})/cryptsetup-${VERSION_CRYPTSETUP}.tar.xz
+	https://people.redhat.com/~heinzm/sw/dmraid/src/dmraid-${VERSION_DMRAID}.tar.bz2
+	https://matt.ucc.asn.au/dropbear/releases/dropbear-${VERSION_DROPBEAR}.tar.bz2
+	https://dev.gentoo.org/~blueness/eudev/eudev-${VERSION_EUDEV}.tar.gz
+	https://github.com/libexpat/libexpat/releases/download/R_${VERSION_EXPAT//\./_}/expat-${VERSION_EXPAT}.tar.xz
+	https://www.kernel.org/pub/linux/kernel/people/tytso/e2fsprogs/v${VERSION_E2FSPROGS}/e2fsprogs-${VERSION_E2FSPROGS}.tar.xz
+	https://github.com/libfuse/libfuse/releases/download/fuse-${VERSION_FUSE}/fuse-${VERSION_FUSE}.tar.gz
+	mirror://gnupg/gnupg/gnupg-${VERSION_GPG}.tar.bz2
+	https://github.com/gentoo/hwids/archive/hwids-${VERSION_HWIDS}.tar.gz
+	https://github.com/open-iscsi/open-iscsi/archive/${VERSION_ISCSI}.tar.gz -> open-iscsi-${VERSION_ISCSI}.tar.gz
+	https://s3.amazonaws.com/json-c_releases/releases/json-c-${VERSION_JSON_C}.tar.gz
+	https://www.kernel.org/pub/linux/utils/kernel/kmod/kmod-${VERSION_KMOD}.tar.xz
+	https://releases.pagure.org/libaio/libaio-${VERSION_LIBAIO}.tar.gz
+	mirror://gnupg/libgcrypt/libgcrypt-${VERSION_LIBGCRYPT}.tar.bz2
+	mirror://gnupg/libgpg-error/libgpg-error-${VERSION_LIBGPGERROR}.tar.bz2
+	https://github.com/besser82/libxcrypt/archive/v${VERSION_LIBXCRYPT}.tar.gz -> libxcrypt-${VERSION_LIBXCRYPT}.tar.gz
+	https://mirrors.kernel.org/sourceware/lvm2/LVM2.${VERSION_LVM}.tgz
+	https://www.oberhumer.com/opensource/lzo/download/lzo-${VERSION_LZO}.tar.gz
+	https://www.kernel.org/pub/linux/utils/raid/mdadm/mdadm-${VERSION_MDADM}.tar.xz
+	http://ftp.rpm.org/popt/releases/popt-1.x/popt-${VERSION_POPT}.tar.gz
+	https://github.com/strace/strace/releases/download/v${VERSION_STRACE}/strace-${VERSION_STRACE}.tar.xz
+	https://github.com/jthornber/thin-provisioning-tools/archive/v${VERSION_THIN_PROVISIONING_TOOLS}.tar.gz -> thin-provisioning-tools-${VERSION_THIN_PROVISIONING_TOOLS}.tar.gz
+	https://github.com/rpodgorny/unionfs-fuse/archive/v${VERSION_UNIONFS_FUSE}.tar.gz -> unionfs-fuse-${VERSION_UNIONFS_FUSE}.tar.gz
+	https://www.kernel.org/pub/linux/utils/util-linux/v${VERSION_UTIL_LINUX:0:4}/util-linux-${VERSION_UTIL_LINUX}.tar.xz
+	https://www.kernel.org/pub/linux/utils/fs/xfs/xfsprogs/xfsprogs-${VERSION_XFSPROGS}.tar.xz
+	https://tukaani.org/xz/xz-${VERSION_XZ}.tar.gz
+	https://zlib.net/zlib-${VERSION_ZLIB}.tar.gz
+	https://github.com/facebook/zstd/archive/v${VERSION_ZSTD}.tar.gz -> zstd-${VERSION_ZSTD}.tar.gz
+	https://git.kernel.org/pub/scm/linux/kernel/git/dhowells/keyutils.git/snapshot/keyutils-${VERSION_KEYUTILS}.tar.gz
+"
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/${PN}.git"
+	inherit git-r3
+	S="${WORKDIR}/${P}"
+	SRC_URI="${COMMON_URI}"
+else
+	SRC_URI="https://dev.gentoo.org/~mattst88/distfiles/${P}.tar.xz
+		${COMMON_URI}"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Gentoo automatic kernel building scripts"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Genkernel https://gitweb.gentoo.org/proj/genkernel.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+RESTRICT=""
+IUSE="ibm +firmware"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Note:
+# We need sys-devel/* deps like autoconf or automake at _runtime_
+# because genkernel will usually build things like LVM2, cryptsetup,
+# mdadm... during initramfs generation which will require these
+# things.
+DEPEND=""
+RDEPEND="${PYTHON_DEPS}
+	app-arch/cpio
+	>=app-misc/pax-utils-1.2.2
+	app-portage/elt-patches
+	app-portage/portage-utils
+	dev-util/gperf
+	sys-apps/sandbox
+	sys-devel/autoconf
+	sys-devel/autoconf-archive
+	sys-devel/automake
+	sys-devel/bc
+	sys-devel/bison
+	sys-devel/flex
+	sys-devel/libtool
+	virtual/pkgconfig
+	elibc_glibc? ( sys-libs/glibc[static-libs(+)] )
+	firmware? ( sys-kernel/linux-firmware )"
+
+if [[ ${PV} == 9999* ]]; then
+	DEPEND="${DEPEND} app-text/asciidoc"
+fi
+
+PATCHES=(
+)
+
+src_unpack() {
+	if [[ ${PV} == 9999* ]]; then
+		git-r3_src_unpack
+	else
+		local gk_src_file
+		for gk_src_file in ${A} ; do
+			if [[ ${gk_src_file} == genkernel-* ]] ; then
+				unpack "${gk_src_file}"
+			fi
+		done
+	fi
+}
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999* ]] ; then
+		einfo "Updating version tag"
+		GK_V="$(git describe --tags | sed 's:^v::')-git"
+		sed "/^GK_V/s,=.*,='${GK_V}',g" -i "${S}"/genkernel
+		einfo "Producing ChangeLog from Git history..."
+		pushd "${S}/.git" >/dev/null || die
+		git log > "${S}"/ChangeLog || die
+		popd >/dev/null || die
+	fi
+
+	# Update software.sh
+	sed -i \
+		-e "s:VERSION_BCACHE_TOOLS:${VERSION_BCACHE_TOOLS}:"\
+		-e "s:VERSION_BOOST:${VERSION_BOOST}:"\
+		-e "s:VERSION_BTRFS_PROGS:${VERSION_BTRFS_PROGS}:"\
+		-e "s:VERSION_BUSYBOX:${VERSION_BUSYBOX}:"\
+		-e "s:VERSION_COREUTILS:${VERSION_COREUTILS}:"\
+		-e "s:VERSION_CRYPTSETUP:${VERSION_CRYPTSETUP}:"\
+		-e "s:VERSION_DMRAID:${VERSION_DMRAID}:"\
+		-e "s:VERSION_DROPBEAR:${VERSION_DROPBEAR}:"\
+		-e "s:VERSION_EUDEV:${VERSION_EUDEV}:"\
+		-e "s:VERSION_EXPAT:${VERSION_EXPAT}:"\
+		-e "s:VERSION_E2FSPROGS:${VERSION_E2FSPROGS}:"\
+		-e "s:VERSION_FUSE:${VERSION_FUSE}:"\
+		-e "s:VERSION_GPG:${VERSION_GPG}:"\
+		-e "s:VERSION_HWIDS:${VERSION_HWIDS}:"\
+		-e "s:VERSION_ISCSI:${VERSION_ISCSI}:"\
+		-e "s:VERSION_JSON_C:${VERSION_JSON_C}:"\
+		-e "s:VERSION_KMOD:${VERSION_KMOD}:"\
+		-e "s:VERSION_LIBAIO:${VERSION_LIBAIO}:"\
+		-e "s:VERSION_LIBGCRYPT:${VERSION_LIBGCRYPT}:"\
+		-e "s:VERSION_LIBGPGERROR:${VERSION_LIBGPGERROR}:"\
+		-e "s:VERSION_LIBXCRYPT:${VERSION_LIBXCRYPT}:"\
+		-e "s:VERSION_LVM:${VERSION_LVM}:"\
+		-e "s:VERSION_LZO:${VERSION_LZO}:"\
+		-e "s:VERSION_MDADM:${VERSION_MDADM}:"\
+		-e "s:VERSION_MULTIPATH_TOOLS:${VERSION_MULTIPATH_TOOLS}:"\
+		-e "s:VERSION_POPT:${VERSION_POPT}:"\
+		-e "s:VERSION_STRACE:${VERSION_STRACE}:"\
+		-e "s:VERSION_THIN_PROVISIONING_TOOLS:${VERSION_THIN_PROVISIONING_TOOLS}:"\
+		-e "s:VERSION_UNIONFS_FUSE:${VERSION_UNIONFS_FUSE}:"\
+		-e "s:VERSION_USERSPACE_RCU:${VERSION_USERSPACE_RCU}:"\
+		-e "s:VERSION_UTIL_LINUX:${VERSION_UTIL_LINUX}:"\
+		-e "s:VERSION_XFSPROGS:${VERSION_XFSPROGS}:"\
+		-e "s:VERSION_XZ:${VERSION_XZ}:"\
+		-e "s:VERSION_ZLIB:${VERSION_ZLIB}:"\
+		-e "s:VERSION_ZSTD:${VERSION_ZSTD}:"\
+		"${S}"/defaults/software.sh \
+		|| die "Could not adjust versions"
+}
+
+src_compile() {
+	if [[ ${PV} == 9999* ]] ; then
+		emake
+	fi
+}
+
+src_install() {
+	insinto /etc
+	doins "${S}"/genkernel.conf
+
+	doman genkernel.8
+	dodoc AUTHORS ChangeLog README TODO
+	dobin genkernel
+	rm -f genkernel genkernel.8 AUTHORS ChangeLog README TODO genkernel.conf
+
+	if use ibm ; then
+		cp "${S}"/arch/ppc64/kernel-2.6{-pSeries,} || die
+	else
+		cp "${S}"/arch/ppc64/kernel-2.6{.g5,} || die
+	fi
+
+	insinto /usr/share/genkernel
+	doins -r "${S}"/*
+
+	fperms +x /usr/share/genkernel/gen_worker.sh
+	fperms +x /usr/share/genkernel/path_expander.py
+
+	python_fix_shebang "${ED}"/usr/share/genkernel/path_expander.py
+
+	newbashcomp "${FILESDIR}"/genkernel-4.bash "${PN}"
+	insinto /etc
+	doins "${FILESDIR}"/initramfs.mounts
+
+	pushd "${DISTDIR}" &>/dev/null || die
+	insinto /usr/share/genkernel/distfiles
+	doins ${A/${P}.tar.xz/}
+	popd &>/dev/null || die
+}
+
+pkg_postinst() {
+	# Wiki is out of date
+	#echo
+	#elog 'Documentation is available in the genkernel manual page'
+	#elog 'as well as the following URL:'
+	#echo
+	#elog 'https://wiki.gentoo.org/wiki/Genkernel'
+	#echo
+
+	local replacing_version
+	for replacing_version in ${REPLACING_VERSIONS} ; do
+		if ver_test "${replacing_version}" -lt 4 ; then
+			# This is an upgrade which requires user review
+
+			ewarn ""
+			ewarn "Genkernel v4.x is a new major release which touches"
+			ewarn "nearly everything. Be careful, read updated manpage"
+			ewarn "and pay special attention to program output regarding"
+			ewarn "changed kernel command-line parameters!"
+
+			# Show this elog only once
+			break
+		fi
+	done
+
+	if [[ $(find /boot -name 'kernel-genkernel-*' 2>/dev/null | wc -l) -gt 0 ]] ; then
+		ewarn ''
+		ewarn 'Default kernel filename was changed from "kernel-genkernel-<ARCH>-<KV>"'
+		ewarn 'to "vmlinuz-<KV>". Please be aware that due to lexical ordering the'
+		ewarn '*default* boot entry in your boot manager could still point to last kernel'
+		ewarn 'built with genkernel before that name change, resulting in booting old'
+		ewarn 'kernel when not paying attention on boot.'
+	fi
+
+	# Show special warning for users depending on remote unlock capabilities
+	local gk_config="${EROOT}/etc/genkernel.conf"
+	if [[ -f "${gk_config}" ]] ; then
+		if grep -q -E "^SSH=[\"\']?yes" "${gk_config}" 2>/dev/null ; then
+			if ! grep -q dosshd /proc/cmdline 2>/dev/null ; then
+				ewarn ""
+				ewarn "IMPORTANT: SSH is currently enabled in your genkernel config"
+				ewarn "file (${gk_config}). However, 'dosshd' is missing from current"
+				ewarn "kernel command-line. You MUST add 'dosshd' to keep sshd enabled"
+				ewarn "in genkernel v4+ initramfs!"
+			fi
+		fi
+
+		if grep -q -E "^CMD_CALLBACK=.*emerge.*@module-rebuild" "${gk_config}" 2>/dev/null ; then
+			elog ""
+			elog "Please remove 'emerge @module-rebuild' from genkernel config"
+			elog "file (${gk_config}) and make use of new MODULEREBUILD option"
+			elog "instead."
+		fi
+	fi
+
+	local n_root_args=$(grep -o -- '\<root=' /proc/cmdline 2>/dev/null | wc -l)
+	if [[ ${n_root_args} -gt 1 ]] ; then
+		ewarn "WARNING: Multiple root arguments (root=) on kernel command-line detected!"
+		ewarn "If you are appending non-persistent device names to kernel command-line,"
+		ewarn "next reboot could fail in case running system and initramfs do not agree"
+		ewarn "on detected root device name!"
+	fi
+
+	if [[ -d /run ]] ; then
+		local permission_run_expected="drwxr-xr-x"
+		local permission_run=$(stat -c "%A" /run)
+		if [[ "${permission_run}" != "${permission_run_expected}" ]] ; then
+			ewarn "Found the following problematic permissions:"
+			ewarn ""
+			ewarn "    ${permission_run} /run"
+			ewarn ""
+			ewarn "Expected:"
+			ewarn ""
+			ewarn "    ${permission_run_expected} /run"
+			ewarn ""
+			ewarn "This is known to be causing problems for any UDEV-enabled service."
+		fi
+	fi
+}
diff --git a/sys-kernel/genkernel/genkernel-9999.ebuild b/sys-kernel/genkernel/genkernel-9999.ebuild
index 891fef7e0d3f..78336f91ab63 100644
--- a/sys-kernel/genkernel/genkernel-9999.ebuild
+++ b/sys-kernel/genkernel/genkernel-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 # genkernel-9999        -> latest Git branch "master"
@@ -6,7 +6,7 @@
 
 EAPI="7"
 
-PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_COMPAT=( python3_{8..11} )
 
 inherit bash-completion-r1 python-single-r1