gentoo auto-resync : 15:01:2025 - 06:41:45

4 files changed, 131 insertions, 6 deletions

diff --git a/sys-fs/Manifest.gz b/sys-fs/Manifest.gz
index 8dd944112809..ce2591ff1813 100644
--- a/sys-fs/Manifest.gz
+++ b/sys-fs/Manifest.gz
diff --git a/sys-fs/dd-rescue/Manifest b/sys-fs/dd-rescue/Manifest
index 8acd9205f608..5c420f43452b 100644
--- a/sys-fs/dd-rescue/Manifest
+++ b/sys-fs/dd-rescue/Manifest
@@ -1,6 +1,8 @@
 AUX dd-rescue-1.99.13-musl.patch 3604 BLAKE2B 677ccabb3a6b45aadbf521cfca23a7b3ac1984110f44fdff93e3e65b8d7d1a1807a17f7110a0a37b5868db77af039bed50291fa80e263940f1bd99dd516c09a0 SHA512 211bbcc064fb40aaf059f5bd843a760b8cdc6a580365e088e4be7331a8c1b85ff3fd34095bdb559a2fe449044c07c87eb979978cad30d2ca676c77f1541bcc96
 DIST dd_rescue-1.99.13.tar.bz2 182574 BLAKE2B da16f37dffc702695d49517aed9a33ce4d00b5e9903c363deaf4b4ed8b5294246d0fe78e977b8a6f6128b9b643a8986437359c78726695fc8e68be41bb11d93e SHA512 2276128fe176dce3ecbd6aa8e0d00b9547887f0498ce0cd135e61dbf882c521e22e2afce3539a73496da1d0472cd9582971a30eb558ce3211820c8d0358c8241
 DIST dd_rescue-1.99.17.tar.bz2 199774 BLAKE2B fd235ce5cb9d80960451f5a65eef0fdc73cd21f684210037056bc5a4952af40e5d494cf541f9e87b76d5d18508caa221c2f4919d537580d4eb58fd67a0c65177 SHA512 8bdd63ed48413607e1da004f497feec8b8a990488348105d30d4d7e56e342b54b4e6439270e581e434b4b0edcf55ab11490739b0c6563358c59b5a64a390a0df
+DIST dd_rescue-1.99.20.tar.bz2 208147 BLAKE2B 145868765b1126a219d2bf9de2e974ba1824d11efd15d58097674ada52bdd4f8909bbf7b4c11a2dd7314639ce487bd4e526cbcbd82d82d43349366ad1284257c SHA512 eb40916f972a486262d4dc03baafdc4b70b0fdc473cd1c20061f64737a99dcceb5ee56334e36f8fa441a0b1d352763d5b8fc153a2ef8403a5b2295f11273c8c2
 EBUILD dd-rescue-1.99.13-r1.ebuild 2753 BLAKE2B 9e2ff1e3ad5734d328982ae834322c770ea97041c37e4ec4f12e1d2c3d97c735f1e1365724ec974fae7a6fc28dd7651d8e2f14db5292cee54857dbc9123f6f85 SHA512 c94d8d29bb62171a50bf9f0279efed9c42aeb37644da633555d3c81db466435e5f47b8e044dd9c4cd94b2e0cd822389da00d00595639c02e42f558f3831b0b3f
-EBUILD dd-rescue-1.99.17.ebuild 2908 BLAKE2B dd03c111a29554f5693bf8536ee23b2c2838df76cff6402d1a9b86de3777e72dc41cf573d2a223db590623a92adb36e237cd5aa277723adbbb909059aff78af6 SHA512 ac1a624362513e4a0805cffff07571cda6eb69774c9a64b55d0782fd4b63087154f66d5ec1f3898531d05d34a2c43c02557d99509a18bbfd05911ec9cb39e068
+EBUILD dd-rescue-1.99.17.ebuild 2817 BLAKE2B ba00aa05e9e2e0b5dd834baf70d848a8b0b1621575c35495d3347c31f5f35641f48de0506c5189eb568e3eeabfe3487a222d59a6e8ec805ca19f5075b838fea8 SHA512 9711cb732bd226948e30497e158ef055bcb69e1496aeb1e882261c55434780fa8ade4be6f773f2143e1f58e5db9f15b2e0b5db91bd4c96e627b6093221663714
+EBUILD dd-rescue-1.99.20.ebuild 2817 BLAKE2B ba00aa05e9e2e0b5dd834baf70d848a8b0b1621575c35495d3347c31f5f35641f48de0506c5189eb568e3eeabfe3487a222d59a6e8ec805ca19f5075b838fea8 SHA512 9711cb732bd226948e30497e158ef055bcb69e1496aeb1e882261c55434780fa8ade4be6f773f2143e1f58e5db9f15b2e0b5db91bd4c96e627b6093221663714
 MISC metadata.xml 254 BLAKE2B f3a9f843cf94243d1129711770df727fcdc8808bca829ef784819cab6f5410dfa463cfed85182f8228c7de796a674dd602653ad3ef817a62c0c3e7198b23befe SHA512 b9fcd3084a7e197f6138e1ce8b0eff99c4c203c37a7d5c40de207040ba1501ef0e5b2f4e00216a567037bcd6d3394fdec6ff587484c9ba2fca9d04f431733b7c
diff --git a/sys-fs/dd-rescue/dd-rescue-1.99.17.ebuild b/sys-fs/dd-rescue/dd-rescue-1.99.17.ebuild
index 49fa8eb2ea56..f4d8e24954eb 100644
--- a/sys-fs/dd-rescue/dd-rescue-1.99.17.ebuild
+++ b/sys-fs/dd-rescue/dd-rescue-1.99.17.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -16,7 +16,7 @@ S="${WORKDIR}/${MY_P}"
 LICENSE="|| ( GPL-2 GPL-3 )"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
-IUSE="cpu_flags_x86_aes cpu_flags_x86_avx2 lzo lzma cpu_flags_x86_rdrand cpu_flags_x86_sha cpu_flags_x86_sse4_2 static test xattr"
+IUSE="cpu_flags_x86_avx2 lzo lzma cpu_flags_x86_sse4_2 static test xattr"
 RESTRICT="!test? ( test )"
 
 RDEPEND="
@@ -81,14 +81,13 @@ _emake() {
 	local os=$(usex kernel_linux Linux IDK)
 
 	# HAVE_LZO is special as it's checked for emptiness in test_crypt.sh.
+	# We could try make RDRND and friends controlled via USE but it's too brittle,
+	# see bug #947105.
 	emake \
 		MACH="${arch}" \
 		OS="${os}" \
 		HAVE_SSE42=$(usex cpu_flags_x86_sse4_2 1 0) \
-		HAVE_AES=$(usex cpu_flags_x86_aes 1 0) \
 		HAVE_AVX2=$(usex cpu_flags_x86_avx2 1 0) \
-		HAVE_SHA=$(usex cpu_flags_x86_sha 1 0) \
-		HAVE_RDRND=$(usex cpu_flags_x86_rdrand 1 0) \
 		HAVE_LZMA=$(usex lzma 1 0) \
 		HAVE_LZO=$(usev lzo 1) \
 		HAVE_OPENSSL=0 \
diff --git a/sys-fs/dd-rescue/dd-rescue-1.99.20.ebuild b/sys-fs/dd-rescue/dd-rescue-1.99.20.ebuild
new file mode 100644
index 000000000000..f4d8e24954eb
--- /dev/null
+++ b/sys-fs/dd-rescue/dd-rescue-1.99.20.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_PN="${PN/-/_}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Similar to dd but can copy from source with errors"
+HOMEPAGE="http://www.garloff.de/kurt/linux/ddrescue/"
+SRC_URI="http://www.garloff.de/kurt/linux/ddrescue/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="cpu_flags_x86_avx2 lzo lzma cpu_flags_x86_sse4_2 static test xattr"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	lzo? ( dev-libs/lzo )
+	xattr? ( sys-apps/attr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		lzo? (
+			app-arch/lzop
+		)
+	)
+"
+
+src_prepare() {
+	default
+
+	if ! use cpu_flags_x86_sse4_2; then
+		sed -i \
+			-e 's:^CC_FLAGS_CHECK(-msse4.2,SSE42):#&:' \
+			configure.ac || die
+	fi
+
+	if ! use cpu_flags_x86_avx2; then
+		sed -i \
+			-e 's:^CC_FLAGS_CHECK(-mavx2,AVX2):#&:' \
+			configure.ac || die
+	fi
+
+	eautoreconf
+
+	sed -i \
+		-e 's:\(-ldl\):$(LDFLAGS) \1:' \
+		-e 's:\(-shared\):$(CFLAGS) $(LDFLAGS) \1:' \
+		Makefile || die
+}
+
+src_configure() {
+	use static && append-ldflags -static
+
+	# OpenSSL is only used by a random helper tool we don't install.
+	export ac_cv_header_attr_xattr_h=$(usex xattr)
+	export ac_cv_header_openssl_evp_h=no
+	export ac_cv_lib_crypto_EVP_aes_192_ctr=no
+	export ac_cv_lib_lzo2_lzo1x_1_compress=$(usex lzo)
+	export ac_cv_header_lzo_lzo1x_h=$(usex lzo)
+	export ac_cv_header_lzma_h=$(usex lzma)
+	export ac_cv_lib_lzma_lzma_easy_encoder=$(usex lzma)
+	econf
+}
+
+_emake() {
+	local arch
+	case ${ARCH} in
+		x86)   arch=i386;;
+		amd64) arch=x86_64;;
+		arm)   arch=arm;;
+		arm64) arch=aarch64;;
+	esac
+
+	local os=$(usex kernel_linux Linux IDK)
+
+	# HAVE_LZO is special as it's checked for emptiness in test_crypt.sh.
+	# We could try make RDRND and friends controlled via USE but it's too brittle,
+	# see bug #947105.
+	emake \
+		MACH="${arch}" \
+		OS="${os}" \
+		HAVE_SSE42=$(usex cpu_flags_x86_sse4_2 1 0) \
+		HAVE_AVX2=$(usex cpu_flags_x86_avx2 1 0) \
+		HAVE_LZMA=$(usex lzma 1 0) \
+		HAVE_LZO=$(usev lzo 1) \
+		HAVE_OPENSSL=0 \
+		RPM_OPT_FLAGS="${CFLAGS} ${CPPFLAGS}" \
+		CFLAGS_OPT='$(CFLAGS)' \
+		LDFLAGS="${LDFLAGS} -Wl,-rpath,${EPREFIX}/usr/$(get_libdir)/${PN}" \
+		CC="$(tc-getCC)" \
+		"$@"
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	if ! use lzo ; then
+		sed -i \
+			-e '/^LZOP=/s:LZOP=.*:LZOP=:' \
+			-e '/^LZOP=/a exit 0' \
+			test_lzo.sh || die
+	fi
+
+	_emake check
+}
+
+src_install() {
+	# easier to install by hand than trying to make sense of the Makefile.
+	dobin dd_rescue
+	dodir /usr/$(get_libdir)/${PN}
+	cp -pPR libddr_*.so "${ED}"/usr/$(get_libdir)/${PN}/ || die
+	dodoc README.dd_rescue
+	doman dd_rescue.1
+	use lzo && doman ddr_lzo.1
+}