gentoo resync : 25.11.2020

1 files changed, 43 insertions, 0 deletions

diff --git a/sys-fs/inotify-tools/inotify-tools-3.20.11.0.ebuild b/sys-fs/inotify-tools/inotify-tools-3.20.11.0.ebuild
new file mode 100644
index 000000000000..5e89f2bc1ca7
--- /dev/null
+++ b/sys-fs/inotify-tools/inotify-tools-3.20.11.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="a set of command-line programs providing a simple interface to inotify"
+HOMEPAGE="https://github.com/inotify-tools/inotify-tools"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~sparc ~x86"
+IUSE="doc"
+
+DEPEND="doc? ( app-doc/doxygen )"
+RDEPEND=""
+
+src_prepare() {
+	default
+
+	# Remove -Werror from CFLAGS (#745069)
+	find -name "Makefile.am" -print0 \
+		| xargs --null sed 's@ -Werror@@' -i || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# only docs installed are doxygen ones, so use /html
+	local myeconfargs=(
+		--disable-static
+		--docdir='$(datarootdir)'/doc/${PF}/html
+		$(use_enable doc doxygen)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}