gentoo resync : 24.12.2018

2 files changed, 85 insertions, 0 deletions

diff --git a/sys-fs/ecryptfs-utils/Manifest b/sys-fs/ecryptfs-utils/Manifest
index a33d962a5afa..d305ebb2a199 100644
--- a/sys-fs/ecryptfs-utils/Manifest
+++ b/sys-fs/ecryptfs-utils/Manifest
@@ -1,3 +1,4 @@
 DIST ecryptfs-utils_108.orig.tar.gz 659465 BLAKE2B a4497470e1aeb3122da1c612a4bb9a32bbae960fad165b5d30543ccaf5682d877927b881956e109c2910eb46e456470ffc0f8fc1f3766f6767741d28d05dc802 SHA512 856d8fac587921f1b5cd0b4ff269c7db8941b6b183506c5bc2e640a77994293f3e09ecfaef94f12c00f2378e756ecec252d3f59eebbabb4229105f8be87653ba
 EBUILD ecryptfs-utils-108-r1.ebuild 1993 BLAKE2B e7ea0bc62ed23edce0712e788ca0f7946e83ba627c0129caf0beca7421437834ef7da24f163175c9ba090d69344ee01e0d0f66ffab87a4abb10308dbc1f498d0 SHA512 97a3e55a90b6853f50f91abdf7c74fc044109d5cf1901a6e37445c4fab9cede404f7eb52e24830e8a023f468312992f8dc1a02b6a1410eb200acfa6c0d19db48
+EBUILD ecryptfs-utils-108-r2.ebuild 2026 BLAKE2B ba2261645849b3dd993473e1cc6d3b0d5e4b8f3cf65d805c1591e0fc17cc91709c54d925f6318ee436a3ab010f3f88f83c3b79faaa60e77670f6f888a24d6735 SHA512 fb8ede2b2b95219963de607af73d07146e2004960822c1e23344d046d61a77c6e3d1aa09c57761e7587d7935505b5ac04b86b3033016022de1b6e82750c8aad4
 MISC metadata.xml 727 BLAKE2B f84dadf31a97d3f4e30ba3ede03ace3ed2a327c94b8a30e25dd1e391c197a231924361d2c31fec85bd893e64540925d6ca943fde1c26b95d9db077a7615b768b SHA512 87eaf8fc34e2f5ca0a2c60aa0d051901f6353e65eb6f63e29e26594588c69dd5f14039a6153bd5bc295a06674d8bb625fa43ccfd7f334188d8333f307405ab5a
diff --git a/sys-fs/ecryptfs-utils/ecryptfs-utils-108-r2.ebuild b/sys-fs/ecryptfs-utils/ecryptfs-utils-108-r2.ebuild
new file mode 100644
index 000000000000..8ffcfa24ccca
--- /dev/null
+++ b/sys-fs/ecryptfs-utils/ecryptfs-utils-108-r2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit flag-o-matic pam python-single-r1 linux-info autotools
+
+DESCRIPTION="eCryptfs userspace utilities"
+HOMEPAGE="https://launchpad.net/ecryptfs"
+SRC_URI="https://launchpad.net/ecryptfs/trunk/${PV}/+download/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="doc gpg gtk nls openssl pam pkcs11 python suid tpm"
+
+RDEPEND=">=sys-apps/keyutils-1.0
+	>=dev-libs/libgcrypt-1.2.0:0
+	dev-libs/nss
+	gpg? ( app-crypt/gpgme )
+	gtk? ( x11-libs/gtk+:2 )
+	openssl? ( >=dev-libs/openssl-0.9.7:= )
+	pam? ( sys-libs/pam )
+	pkcs11? (
+		>=dev-libs/openssl-0.9.7:=
+		>=dev-libs/pkcs11-helper-1.04
+	)
+	python? ( ${PYTHON_DEPS} )
+	tpm? ( app-crypt/trousers )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext
+	>=dev-util/intltool-0.41.0
+	python? ( dev-lang/swig )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+
+	CONFIG_CHECK="~ECRYPT_FS"
+	linux-info_pkg_setup
+}
+
+src_configure() {
+	append-cppflags -D_FILE_OFFSET_BITS=64
+
+	econf \
+		--enable-nss \
+		--with-pamdir=$(getpam_mod_dir) \
+		$(use_enable doc docs) \
+		$(use_enable gpg) \
+		$(use_enable gtk gui) \
+		$(use_enable nls) \
+		$(use_enable openssl) \
+		$(use_enable pam) \
+		$(use_enable pkcs11 pkcs11-helper) \
+		$(use_enable python pywrap) \
+		$(use_enable tpm tspi)
+}
+
+src_install(){
+	emake DESTDIR="${D}" install
+
+	if use python; then
+		echo "ecryptfs-utils" > "${D}$(python_get_sitedir)/ecryptfs-utils.pth" || die
+	fi
+
+	use suid && fperms u+s /sbin/mount.ecryptfs_private
+
+	find "${ED}" -name '*.la' -exec rm -f '{}' + || die
+}
+
+pkg_postinst() {
+	if use suid; then
+		ewarn
+		ewarn "You have chosen to install ${PN} with the binary setuid root. This"
+		ewarn "means that if there are any undetected vulnerabilities in the binary,"
+		ewarn "then local users may be able to gain root access on your machine."
+		ewarn
+	fi
+}