gentoo resync : 31.12.2017 (final resync this year)

1 files changed, 45 insertions, 0 deletions

diff --git a/sys-devel/binutils-config/binutils-config-5.1-r1.ebuild b/sys-devel/binutils-config/binutils-config-5.1-r1.ebuild
new file mode 100644
index 000000000000..ef7b1bd5c11d
--- /dev/null
+++ b/sys-devel/binutils-config/binutils-config-5.1-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit prefix
+
+DESCRIPTION="Utility to change the binutils version being used"
+HOMEPAGE="https://www.gentoo.org/"
+SRC_URI=""
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+# We also RDEPEND on sys-apps/findutils which is in base @system
+RDEPEND="sys-apps/gentoo-functions
+	!<app-admin/eselect-1.4.5
+	!<sys-devel/binutils-2.25.1
+"
+
+S=${WORKDIR}
+
+src_install() {
+	newbin "${FILESDIR}"/${PN}-${PV} ${PN}
+	use prefix && eprefixify "${ED}"/usr/bin/${PN}
+	sed -i "s:@PV@:${PVR}:g" "${ED}"/usr/bin/${PN} || die
+	doman "${FILESDIR}"/${PN}.8
+
+	insinto /usr/share/eselect/modules
+	doins "${FILESDIR}"/binutils.eselect
+}
+
+pkg_preinst() {
+	# Force a refresh when upgrading from an older version that symlinked
+	# in all the libs & includes that binutils-libs handles. #528088
+	if has_version "<${CATEGORY}/${PN}-5" ; then
+		local bc current
+		bc="${ED}/usr/bin/binutils-config"
+		if current=$("${bc}" -c) ; then
+			"${bc}" "${current}"
+		fi
+	fi
+}