reinit the tree, so we can have metadata

1 files changed, 44 insertions, 0 deletions

diff --git a/sys-devel/autoconf/autoconf-9999.ebuild b/sys-devel/autoconf/autoconf-9999.ebuild
new file mode 100644
index 000000000000..9495cddbedd9
--- /dev/null
+++ b/sys-devel/autoconf/autoconf-9999.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
+		http://git.savannah.gnu.org/r/${PN}.git"
+	# We need all the tags in order to figure out the right version.
+	# The git-r3 eclass doesn't support that, so have to stick to 2.
+	inherit git-2
+else
+	SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
+		ftp://alpha.gnu.org/pub/gnu/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~arm-linux ~x86-linux"
+fi
+
+inherit toolchain-autoconf
+
+DESCRIPTION="Used to create autoconfiguration files"
+HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
+
+LICENSE="GPL-3"
+SLOT="${PV}"
+IUSE="emacs"
+
+DEPEND=">=sys-devel/m4-1.4.16
+	>=dev-lang/perl-5.6"
+RDEPEND="${DEPEND}
+	!~sys-devel/${P}:2.5
+	>=sys-devel/autoconf-wrapper-13"
+[[ ${PV} == "9999" ]] && DEPEND+=" >=sys-apps/texinfo-4.3"
+PDEPEND="emacs? ( app-emacs/autoconf-mode )"
+
+src_prepare() {
+	# Avoid the "dirty" suffix in the git version by generating it
+	# before we run later stages which might modify source files.
+	local ver=$(./build-aux/git-version-gen .tarball-version)
+	echo "${ver}" > .tarball-version
+
+	autoreconf -f -i || die
+
+	toolchain-autoconf_src_prepare
+}