summaryrefslogtreecommitdiff
path: root/sys-block/tgt/tgt-1.0.84.ebuild
diff options
context:
space:
mode:
authorV3n3RiX <venerix@koprulu.sector>2022-08-06 20:10:31 +0100
committerV3n3RiX <venerix@koprulu.sector>2022-08-06 20:10:31 +0100
commit944b3df0f275eea0fd7808913d72a0b280df0c33 (patch)
treeec33697fafd5ce7028b7619baef7a6d27bb74362 /sys-block/tgt/tgt-1.0.84.ebuild
parent7e17b5aabc330abb894f2b90bef0e3fcbcd180d2 (diff)
gentoo auto-resync : 06:08:2022 - 20:10:30
Diffstat (limited to 'sys-block/tgt/tgt-1.0.84.ebuild')
-rw-r--r--sys-block/tgt/tgt-1.0.84.ebuild58
1 files changed, 58 insertions, 0 deletions
diff --git a/sys-block/tgt/tgt-1.0.84.ebuild b/sys-block/tgt/tgt-1.0.84.ebuild
new file mode 100644
index 000000000000..43d1f60ba296
--- /dev/null
+++ b/sys-block/tgt/tgt-1.0.84.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs systemd
+
+DESCRIPTION="Linux SCSI target framework (tgt)"
+HOMEPAGE="http://stgt.sourceforge.net"
+SRC_URI="https://github.com/fujita/tgt/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="fcoe fcp ibmvio infiniband rbd"
+
+DEPEND="
+ app-text/docbook-xsl-stylesheets
+ dev-libs/libxslt
+ dev-perl/Config-General
+ rbd? ( sys-cluster/ceph )
+ infiniband? ( sys-cluster/rdma-core )
+"
+RDEPEND="${DEPEND}
+ dev-libs/libaio
+ sys-apps/sg3_utils"
+
+pkg_setup() {
+ tc-export CC
+}
+
+src_prepare() {
+ default
+ sed -i -e 's:\($(CC)\) $^:\1 $(LDFLAGS) $^:' usr/Makefile || die
+ # make sure xml docs are generated before trying to install them
+ sed -i -e "s@install: @& all @g" doc/Makefile || die
+ sed -i -e 's|-Werror||g' usr/Makefile || die
+}
+
+src_compile() {
+ local myconf
+ use ibmvio && myconf="${myconf} IBMVIO=1"
+ use infiniband && myconf="${myconf} ISCSI_RDMA=1"
+ use fcp && myconf="${myconf} FCP=1"
+ use fcoe && myconf="${myconf} FCOE=1"
+ use rbd && myconf="${myconf} CEPH_RBD=1"
+
+ emake -C usr/ KERNELSRC="${KERNEL_DIR}" ISCSI=1 ${myconf}
+ emake -C doc
+}
+
+src_install() {
+ emake install-programs install-scripts install-doc DESTDIR="${D}" docdir=/usr/share/doc/${PF}
+ newinitd "${FILESDIR}"/tgtd.initd tgtd
+ newconfd "${FILESDIR}"/tgtd.confd tgtd
+ systemd_dounit "${S}"/scripts/tgtd.service
+ dodir /etc/tgt
+ keepdir /etc/tgt
+}