gentoo resync : 29.12.2022

1 files changed, 45 insertions, 0 deletions

diff --git a/sys-apps/s6-linux-utils/s6-linux-utils-2.6.0.0.ebuild b/sys-apps/s6-linux-utils/s6-linux-utils-2.6.0.0.ebuild
new file mode 100644
index 000000000000..36d949ef12f9
--- /dev/null
+++ b/sys-apps/s6-linux-utils/s6-linux-utils-2.6.0.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Set of tiny linux utilities"
+HOMEPAGE="https://www.skarnet.org/software/s6-linux-utils/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND=">=dev-libs/skalibs-2.12.0.0:="
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir=/usr/$(get_libdir)
+		--libdir=/usr/$(get_libdir)/${PN}
+		--with-dynlib=/usr/$(get_libdir)
+		--with-lib=/usr/$(get_libdir)/skalibs
+		--with-sysdeps=/usr/$(get_libdir)/skalibs
+		--disable-allstatic
+		--disable-static-libc
+	)
+
+	econf "${myconf[@]}"
+}