gentoo auto-resync : 04:10:2022 - 07:16:51

1 files changed, 56 insertions, 0 deletions

diff --git a/sys-apps/pkgcore/pkgcore-0.12.13-r3.ebuild b/sys-apps/pkgcore/pkgcore-0.12.13-r3.ebuild
new file mode 100644
index 000000000000..f78ff72a16ad
--- /dev/null
+++ b/sys-apps/pkgcore/pkgcore-0.12.13-r3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pkgcore/pkgcore.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="a framework for package management"
+HOMEPAGE="https://github.com/pkgcore/pkgcore"
+
+LICENSE="BSD MIT"
+SLOT="0"
+
+RDEPEND="
+	>=app-shells/bash-5.0
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+if [[ ${PV} == *9999 ]]; then
+	RDEPEND+=" ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]"
+else
+	RDEPEND+=" ~dev-python/snakeoil-0.9.12[${PYTHON_USEDEP}]"
+fi
+BDEPEND="
+	test? (
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests setup.py
+
+src_test() {
+	# With PYTHONDONTWRITEBYTECODE=, python will try rebuild all sorts of modules.
+	# https://bugs.gentoo.org/840266
+	local -x SANDBOX_PREDICT=${SANDBOX_PREDICT}
+	addpredict /
+
+	local -x PYTHONDONTWRITEBYTECODE=
+	distutils-r1_src_test
+}
+
+python_install_all() {
+	local DOCS=( NEWS.rst )
+	[[ ${PV} == *9999 ]] || doman man/*
+	distutils-r1_python_install_all
+}