gentoo auto-resync : 12:01:2024 - 19:10:40

2 files changed, 167 insertions, 0 deletions

diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index b855d0ab379e..b3049c045a30 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -5,11 +5,13 @@ DIST openrc-0.49.tar.gz 250228 BLAKE2B 82305af995aa0ef043481839a88b833d300dfae36
 DIST openrc-0.50.tar.gz 250416 BLAKE2B b5b8eb54d03f727f43928399e2af3ac08a4a416469dae2baf30e91e2cbf2076a298d7683440febbb89b021152b6d40df37df3e081200da5620d501c1ce7ba0df SHA512 54f41d4794bf07b1b4ef6a2f4be88baad4abba32b4cfe885e2a58faf56876bf7c4d46f29b4629b04c56fe9f2efb45b7f8596a45a422ad2f417fd09fe489d8ed3
 DIST openrc-0.51.tar.gz 250746 BLAKE2B 903bae3781fbe1771827f18d6df998c07cc95e59838721ac4f3c083dacd053526ee1125ce40f953d64d08ec5bc2ec1329b8dc66878c12254538a8cea79af45de SHA512 2844e54c90abf8c2f515d8033f9fe3bd51f7e1026d73488c5fe81c6bfbe5fc2df904aefedee729a3300476805495fb59e3c88f0e77df6c5127b0bcf4034b4843
 DIST openrc-0.52.1.tar.gz 250843 BLAKE2B abecc2ef7e23b4142f97a97fcbf99f5991571feea8aaffab6acaae0f82a9717481343aa9f158638b74f28ab4a7eb67d12f587dc91e0a375b9a06f23b6b4bf109 SHA512 741f3f0752217b9ce159d00362d688738c5a84512ddd30c44f4f7f451d7950315a5e1de79eaf5e7b1cf6539a04f59600fbe82cc2a6ad966b735c2eb4d4f35717
+DIST openrc-0.53.tar.gz 251051 BLAKE2B df6452607d1d16de8a3addb5fc13ec7f9a7f2de9b2aa6eef61787e49e9a16659a1475432e13b58d5fe372aeff7051b487c094920379ffc2f8295357370d5f997 SHA512 e4d3eb6f42cd891e553da171bb9aefc06b5a2d842bba9cb13d8199ad46023f37c173f925415d3571f58d5a508a319df39240cedfe8d8b47bb17cc7171f031a25
 EBUILD openrc-0.48.ebuild 4547 BLAKE2B e0fdbd7a9668d0b0cac96e67cae7c9ca05b995857a16784e9c71dc2504d9e9f546c08f5163ec9f18c93b641a1e3a8333d74df07659215bd8b11356a0d48640f7 SHA512 caca44a4aefe5fa61be9e023c14b80d65630db0fdea7e3ed76b31b33168dcfd38228c3c3599e8217cd76fdfb28f44536816efe9c2a90fb053960886c174fe044
 EBUILD openrc-0.49.ebuild 4555 BLAKE2B 708488c77fc079d6481417f6d182b8f513bd85d5d905f3ac2454a2baa995f64cada2ad3febe1cf0c36901da34c31c25c4412958aa332868e1a0999cb7d634378 SHA512 ac43059aa5c472c7ac4ab4023ab67057c83518ee526894f2abe6bb325c154104f43150e33130eeb9b87d7ac09b6d20c1dc8c2d74496ed909db510693aa7e3333
 EBUILD openrc-0.50-r1.ebuild 4551 BLAKE2B 0cf7b6d9f9b3dd0d045102b6c8e218c361f5f2522f8c4b64fa857ec9c1378bf3ee119f4f4510c51942d0b881f0dd3cf024ab010f4daec6ee3928fee0706355c3 SHA512 f740307122201cbc01c1708f690bd541740384cba564c8bf4fd1d6a81f021e307eb4decaf2173be6db86386d3f7b18ce5632a1b7e5ef37715ecf0dd2d9da82f1
 EBUILD openrc-0.50.ebuild 4578 BLAKE2B 4f2bb99655f14bd4f7000074f8367c1b3566467f8d67b435ea511d526de65b80b137c517890b57b38b2d1b63503331cd874d78385f78c73b1cd621ea911cd015 SHA512 3480b661862a4caea524247f23151786e7b44dddd42d777384025cc6b035eaaebb89cb17a5efa7c461a9d793e3622ca8588c115e26390f16934a99b60a6fa345
 EBUILD openrc-0.51.ebuild 4551 BLAKE2B 0cf7b6d9f9b3dd0d045102b6c8e218c361f5f2522f8c4b64fa857ec9c1378bf3ee119f4f4510c51942d0b881f0dd3cf024ab010f4daec6ee3928fee0706355c3 SHA512 f740307122201cbc01c1708f690bd541740384cba564c8bf4fd1d6a81f021e307eb4decaf2173be6db86386d3f7b18ce5632a1b7e5ef37715ecf0dd2d9da82f1
 EBUILD openrc-0.52.1.ebuild 4551 BLAKE2B 0cf7b6d9f9b3dd0d045102b6c8e218c361f5f2522f8c4b64fa857ec9c1378bf3ee119f4f4510c51942d0b881f0dd3cf024ab010f4daec6ee3928fee0706355c3 SHA512 f740307122201cbc01c1708f690bd541740384cba564c8bf4fd1d6a81f021e307eb4decaf2173be6db86386d3f7b18ce5632a1b7e5ef37715ecf0dd2d9da82f1
+EBUILD openrc-0.53.ebuild 4551 BLAKE2B 2f9507225108ef3c1e09d48325df8716d82b3435d692a8a9318dc0a8444481a03772b3039a32c904f96b04940e3967780cb299fc77a6280b9745e5c3839b968c SHA512 f9cc1f8474e7777d88edb283ffd942c3d5243c2dbab936217566c778edbd8ea1c797d48ed0c2422c302bcf51d33fb046e6140bf5ada83b72fb1311f77cc55bc3
 EBUILD openrc-9999.ebuild 4555 BLAKE2B 708488c77fc079d6481417f6d182b8f513bd85d5d905f3ac2454a2baa995f64cada2ad3febe1cf0c36901da34c31c25c4412958aa332868e1a0999cb7d634378 SHA512 ac43059aa5c472c7ac4ab4023ab67057c83518ee526894f2abe6bb325c154104f43150e33130eeb9b87d7ac09b6d20c1dc8c2d74496ed909db510693aa7e3333
 MISC metadata.xml 842 BLAKE2B 696a5ccdf7eca47ac64ee7f317817a06d93664bcbaa3e94cc4420cc9452c97781d69b6b259350a4c5caf681c2e3394019f9f208eec661c861f3f6e3f5c214542 SHA512 dee510e527b885c19b57f5831081d47a422c88d65b7d50dc5c3e74c0a439ddbd1d1d87e241734d08e35a7551b500ab25d01f7a6be73e36dccde576df59974f36
diff --git a/sys-apps/openrc/openrc-0.53.ebuild b/sys-apps/openrc/openrc-0.53.ebuild
new file mode 100644
index 000000000000..b81bd00d2247
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.53.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson pam
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} =~ ^9{4,}$ ]]; then
+	EGIT_REPO_URI="https://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/OpenRC/openrc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit bash debug ncurses pam newnet +netifrc selinux s6 +sysvinit sysv-utils unicode"
+
+COMMON_DEPEND="
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? ( sys-libs/pam )
+	audit? ( sys-process/audit )
+	sys-process/psmisc
+	selinux? (
+		sys-apps/policycoreutils
+		>=sys-libs/libselinux-2.6
+	)"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	bash? ( app-shells/bash )
+	sysv-utils? (
+		!sys-apps/systemd[sysv-utils(-)]
+		!sys-apps/sysvinit
+	)
+	!sysv-utils? (
+		sysvinit? ( >=sys-apps/sysvinit-2.86-r6[selinux?] )
+		s6? ( sys-apps/s6-linux-init[sysv-utils(-)] )
+	)
+	virtual/tmpfiles
+	selinux? (
+		>=sec-policy/selinux-base-policy-2.20170204-r4
+		>=sec-policy/selinux-openrc-2.20170204-r4
+	)
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature audit)
+		"-Dbranding=\"Gentoo Linux\""
+		$(meson_use newnet)
+		-Dos=Linux
+		$(meson_use pam)
+		$(meson_feature selinux)
+		-Drootprefix="${EPREFIX}"
+		-Dshell=$(usex bash /bin/bash /bin/sh)
+		$(meson_use sysv-utils sysvinit)
+		-Dtermcap=$(usev ncurses)
+	)
+	# export DEBUG=$(usev debug)
+	meson_src_configure
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	meson_install
+
+	keepdir /lib/rc/tmp
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/etc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	if use pam; then
+		# install gentoo pam.d files
+		newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+		newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
+	fi
+
+	# install documentation
+	dodoc *.md
+}
+
+pkg_preinst() {
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"/etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"/etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
+	return 0
+}
+
+pkg_postinst() {
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRc without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/connman,"
+		ewarn " net-misc/NetworkManager, or net-vpn/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"/etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+
+	# added for 0.45 to handle seedrng/urandom switching (2022-06-07)
+	for v in ${REPLACING_VERSIONS}; do
+		[[ -x $(type rc-update) ]] || continue
+		if ver_test $v -lt 0.45; then
+			if rc-update show boot | grep -q urandom; then
+				rc-update del urandom boot
+				rc-update add seedrng boot
+		fi
+		fi
+	done
+}