gentoo auto-resync : 14:03:2023 - 00:16:42

2 files changed, 67 insertions, 0 deletions

diff --git a/sys-apps/gnome-disk-utility/Manifest b/sys-apps/gnome-disk-utility/Manifest
index bb19689bbd49..7d1d95a60f75 100644
--- a/sys-apps/gnome-disk-utility/Manifest
+++ b/sys-apps/gnome-disk-utility/Manifest
@@ -1,3 +1,5 @@
 DIST gnome-disk-utility-43.0.tar.xz 1752240 BLAKE2B 906183e7f61c4e9d2206fe2c99034f06a0aa3869d253587325ae18b336dffc6d8523a2f4d89c4338ed64947e73c5a24de15dfdb15a9d42d77fe51fd2321bf159 SHA512 8cb1b10fba21c90bceec9521103defe092dea9a4c89a39ae44e4d5981dd0d1958649e7a2743535f0135a3c9179cad0e0aced98dfc805e19bdec81651abcecf48
+DIST gnome-disk-utility-44.rc.tar.xz 1768008 BLAKE2B abdff1507373daa887097780a77761c207d9ab44932bec028d4b22bd9378db6cd47774482bada7ebd9ca734b6cf7b73f9a4fefff5e486ee3b672f62ef57b2769 SHA512 1f462de2830396e6129187e6302ebe509edee532a85b9e7b29528929f4a776b90ec14193a00631d0ae322e6eed7f3cbaff7a06b6006b6489bdb65ce281870f30
 EBUILD gnome-disk-utility-43.0.ebuild 1404 BLAKE2B 38e0f76004764c61e637287671297c19061e231291b992ff1f95963c933cd0f85697e816cb59b28d8f0754533b0b6183e7e75984a0bb29bcc4fbff691ece2ede SHA512 eae8e7135443d55e1015010a3784daecade77b0cb2009a90d5d492f65d39583460d47f7bde7b7a1ac22dce22f4b77438f2ab3b350f8415e7b35f21c14de0136d
+EBUILD gnome-disk-utility-44_rc.ebuild 1507 BLAKE2B 7e1f0c6f153b0d527d40aeab2a189df1e79da229c46acd34970a85d4dc526f778bf8c4757c904917b9b1687ed7a24af2d48b57cf99ab8c9de55f020be02c080a SHA512 6b2b1924ea47a61724f5c42a15896f86a83628b968310a4fc43daf26a04ce5462b6fc7658135169abe75a226972dbfca197919b83b4499116cdb9562afbd79b2
 MISC metadata.xml 725 BLAKE2B 173521fe25d9d15cc28c6c4abb434b246222a2c6e15392fdf655e4be1006f83026e9fabf7d29f9d41421c5f13f114c6649971defe18bde1ae1c40f7355859902 SHA512 88e461ac9ac3c8d2a321ef3a1ad44d17b8b3e4355f92320857c77b1a5c6d707d3b3613518dda5cfec9fe4e44067f97a9bac9b1b56ac037b7f0d86da82ecc93b3
diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-44_rc.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-44_rc.ebuild
new file mode 100644
index 000000000000..fdc7d024be2d
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-44_rc.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
+SRC_URI="https://download.gnome.org/sources/${PN}/44/${PN}-44.rc.tar.xz"
+S="${WORKDIR}/${PN}-44.rc"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat elogind gnome systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="
+	>=media-libs/libdvdread-4.2.0:0=
+	>=dev-libs/glib-2.31:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=gui-libs/libhandy-1.5.0:1
+	>=app-arch/xz-utils-5.0.5
+	>=x11-libs/libnotify-0.7
+	>=app-crypt/libsecret-0.7
+	>=dev-libs/libpwquality-1.0.0
+	>=sys-fs/udisks-2.7.6:2
+	elogind? ( >=sys-auth/elogind-209 )
+	systemd? ( >=sys-apps/systemd-209:0= )
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+# libxml2 for xml-stripblanks in gresource
+BDEPEND="
+	dev-libs/libxml2:2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dlogind=$(usex systemd libsystemd $(usex elogind libelogind none))
+		$(meson_use gnome gsd_plugin)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}