gentoo auto-resync : 20:07:2023 - 07:07:07

1 files changed, 51 insertions, 0 deletions

diff --git a/sys-apps/debianutils/debianutils-5.8.ebuild b/sys-apps/debianutils/debianutils-5.8.ebuild
new file mode 100644
index 000000000000..8187ac45152d
--- /dev/null
+++ b/sys-apps/debianutils/debianutils-5.8.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="A selection of tools from Debian"
+HOMEPAGE="https://packages.qa.debian.org/d/debianutils.html"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="BSD GPL-2 SMAIL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x86-linux"
+IUSE="+installkernel static"
+
+PDEPEND="
+	installkernel? (
+		|| (
+			sys-kernel/installkernel-gentoo
+			sys-kernel/installkernel-systemd-boot
+		)
+	)"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.4.2-no-bs-namespace.patch )
+
+src_prepare() {
+	# Avoid adding po4a dependency, upstream refreshes manpages.
+	sed -i -e '/SUBDIRS/s|po4a||' Makefile.am || die
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	default
+}
+
+src_install() {
+	into /
+	dobin run-parts
+
+	into /usr
+	dobin ischroot
+	dosbin savelog
+
+	doman ischroot.1 run-parts.8 savelog.8
+
+	dodoc CHANGELOG
+}