gentoo auto-resync : 18:06:2023 - 01:46:36

3 files changed, 284 insertions, 2 deletions

diff --git a/sys-apps/coreutils/Manifest b/sys-apps/coreutils/Manifest
index 4dce13778b95..b354d9258131 100644
--- a/sys-apps/coreutils/Manifest
+++ b/sys-apps/coreutils/Manifest
@@ -19,6 +19,7 @@ EBUILD coreutils-9.1-r2.ebuild 7114 BLAKE2B 6f52424f7e9f065d56dacc6fbbee0ac27928
 EBUILD coreutils-9.2-r2.ebuild 7602 BLAKE2B 858fd03a8ff42630b11bdd4a3c26d195d40ec93073fed28ee309475731c2ff054e54f3580ca17a536b88751293e26cd95cb82130431b963cd2d0abf5e6167faf SHA512 2934bf8602114f68e10f5f72c24b4e0cb07e95ab1d24f738b208754d3d58df21f0d72b1d01ba29897827bf9f961bd6536e1f3190a5a79d91839909e955812a53
 EBUILD coreutils-9.3-r1.ebuild 7604 BLAKE2B 2dfda62928900111a402e353402ac7e7f545ab72d37a626202933806a8591095b35c8e86b149f0aa784e7d5ac9b6325f72d5c8c7b49f2d6adb049fb42b9379dd SHA512 76430d1fa83857e9392a2973d797479ee130256c232f911157ae4056493b826ec436fdeb7e0ed93a01cf9de925f29cb0f7b5f29c1eb3059bf3a7031a9f97a5d6
 EBUILD coreutils-9.3-r2.ebuild 7794 BLAKE2B 5b043bc597928643cd313d14941c32d8a9fe495090c4577eee02115775fe5605ca1f2c1c704e71f24ad5353520e36ba34b05fe814be072f38e486f750fde28fd SHA512 b4d7c5bbba946f60af46e4a2f1dec9f449d48c71dc18d592a2f30ac0c44c8ea5a75aedb86f0d15398c931cde2c7a73f3209ad2c6a22a8e4c6d122454be09fd15
+EBUILD coreutils-9.3-r3.ebuild 7935 BLAKE2B b70917cdf13265e12c70d38b5f305ec5a824407802a4111c30a5107ff13c4f6a30fb13f3ce88a3bff886b9de15edfe3b03519593ca3219a32f889af965b6104f SHA512 366d6aa630fbbed5484aa6d2f517512a74c25cd9fde1f0a660cfcd852c1fc1de22e4f495baccc7a959d298bf987a9904c9d71efa381adedf33ac22d28efac432
 EBUILD coreutils-9.3.ebuild 7478 BLAKE2B 8e857aeeb4a557ade9a6a85eb88814a414ba9f1a5c99efafd859c87cf644d21eac3592c033b505564ac54c0b827184faa295a2a7632fa2270a9c6225b790ce1f SHA512 7ec70783e2c978f6591ac16d1b137677e2927b961053a3e3e66a40dc5f9e576d9fbfae27f07f79110d3a2c4d93017ce92e3b32358e94cf5fe0509258ca2e4112
-EBUILD coreutils-9999.ebuild 7550 BLAKE2B a169a42a5e795e8cfb568d05c9744a46e687627bcc905178f5d0f5ee977f4a5c661a6cfe6f46c7dbaa04ab941f49de950af4546d22daf8ccd66e83a0df667c88 SHA512 cfb15372aa67eff7c67fee803b9d53500205e9d2e093cc9495e09fc48b453894ff183536d984b3ffc0fef25244f5285ebbf598ebeb3c74fe8bf35de0a99c0a7e
+EBUILD coreutils-9999.ebuild 7686 BLAKE2B a03e0d4c230f28daa688b2ee60f5f740bdb1a2040634dc86d4355647b96ea9666be13c589d62d773bc65a3f57d183354389c0f2e09bd73cd6775bd7c11aa9d1f SHA512 79b3b4263909522367ddb022247266535a21f0c950c9c0d8df2d78c68242a2730371e37e7528f53a39e1f72f0ffdd629e89c57cd546c9167985146c2215039d7
 MISC metadata.xml 1093 BLAKE2B 68a653fe54fc668c7f2c7c01904cfca5a071192de4370dcbba427e673f8e9ec33b5104a868a5493117ef24e277446181383140c621b105689797aec4e077b86e SHA512 bf8f2653a1a81edb6e4090b127c5660e0c5ab41a33c985dea1b5cb05c6656b04f42084ce4e561f4550c3e54630893314d3084011c673e7d5aded022be1c065d1
diff --git a/sys-apps/coreutils/coreutils-9.3-r3.ebuild b/sys-apps/coreutils/coreutils-9.3-r3.ebuild
new file mode 100644
index 000000000000..ab1c0e9a1cbd
--- /dev/null
+++ b/sys-apps/coreutils/coreutils-9.3-r3.ebuild
@@ -0,0 +1,277 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Try to keep an eye on Fedora's packaging: https://src.fedoraproject.org/rpms/coreutils
+# The upstream coreutils maintainers also maintain the package in Fedora and may
+# backport fixes which we want to pick up.
+#
+# Also recommend subscribing to the coreutils and bug-coreutils MLs.
+
+PYTHON_COMPAT=( python3_{9..11} )
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/coreutils.asc
+inherit flag-o-matic python-any-r1 toolchain-funcs verify-sig
+
+MY_PATCH="${PN}-9.0_p20220409-patches-01"
+DESCRIPTION="Standard GNU utilities (chmod, cp, dd, ls, sort, tr, head, wc, who,...)"
+HOMEPAGE="https://www.gnu.org/software/coreutils/"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/coreutils.git"
+	inherit git-r3
+elif [[ ${PV} == *_p* ]] ; then
+	# Note: could put this in devspace, but if it's gone, we don't want
+	# it in tree anyway. It's just for testing.
+	MY_SNAPSHOT="$(ver_cut 1-2).18-ffd62"
+	SRC_URI="https://www.pixelbeat.org/cu/coreutils-${MY_SNAPSHOT}.tar.xz -> ${P}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://www.pixelbeat.org/cu/coreutils-${MY_SNAPSHOT}.tar.xz.sig -> ${P}.tar.xz.sig )"
+	S="${WORKDIR}"/${PN}-${MY_SNAPSHOT}
+else
+	SRC_URI="
+		mirror://gnu/${PN}/${P}.tar.xz
+		verify-sig? ( mirror://gnu/${PN}/${P}.tar.xz.sig )
+	"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x86-linux"
+fi
+
+SRC_URI+=" !vanilla? ( https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${MY_PATCH}.tar.xz )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="acl caps gmp hostname kill multicall nls +openssl selinux +split-usr static test vanilla xattr"
+RESTRICT="!test? ( test )"
+
+LIB_DEPEND="
+	acl? ( sys-apps/acl[static-libs] )
+	caps? ( sys-libs/libcap )
+	gmp? ( dev-libs/gmp:=[static-libs] )
+	openssl? ( dev-libs/openssl:=[static-libs] )
+	xattr? ( sys-apps/attr[static-libs] )
+"
+RDEPEND="
+	!static? ( ${LIB_DEPEND//\[static-libs]} )
+	selinux? ( sys-libs/libselinux )
+	nls? ( virtual/libintl )
+"
+DEPEND="
+	${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+"
+BDEPEND="
+	app-arch/xz-utils
+	dev-lang/perl
+	test? (
+		dev-lang/perl
+		dev-perl/Expect
+		dev-util/strace
+		${PYTHON_DEPS}
+	)
+	verify-sig? ( sec-keys/openpgp-keys-coreutils )
+"
+RDEPEND+="
+	hostname? ( !sys-apps/net-tools[hostname] )
+	kill? (
+		!sys-apps/util-linux[kill]
+		!sys-process/procps[kill]
+	)
+	!app-misc/realpath
+	!<sys-apps/util-linux-2.13
+	!<sys-apps/sandbox-2.10-r4
+	!sys-apps/stat
+	!net-mail/base64
+	!sys-apps/mktemp
+	!<app-forensics/tct-1.18-r1
+	!<net-fs/netatalk-2.0.3-r4"
+
+pkg_setup() {
+	if use test ; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]] ; then
+		git-r3_src_unpack
+
+		cd "${S}" || die
+		./bootstrap || die
+
+		sed -i -e "s:submodule-checks ?= no-submodule-changes public-submodule-commit:submodule-checks ?= no-submodule-changes:" gnulib/top/maint.mk || die
+	elif use verify-sig ; then
+		# Needed for downloaded patch (which is unsigned, which is fine)
+		verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
+	fi
+
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		# Upstream patches
+		"${FILESDIR}"/${P}-cp-parents-preserve-permissions.patch
+		"${FILESDIR}"/${P}-old-kernel-copy_file_range.patch
+	)
+
+	if ! use vanilla && [[ -d "${WORKDIR}"/patch ]] ; then
+		PATCHES+=( "${WORKDIR}"/patch )
+	fi
+
+	default
+
+	# Just for ${P}-old-kernel-copy_file_range.patch
+	touch aclocal.m4 configure.ac Makefile.in gnulib-tests/Makefile.in configure || die
+
+	# Since we've patched many .c files, the make process will try to
+	# re-build the manpages by running `./bin --help`.  When doing a
+	# cross-compile, we can't do that since 'bin' isn't a native bin.
+	#
+	# Also, it's not like we changed the usage on any of these things,
+	# so let's just update the timestamps and skip the help2man step.
+	set -- man/*.x
+	touch ${@/%x/1} || die
+
+	# Avoid perl dep for compiled in dircolors default (bug #348642)
+	if ! has_version dev-lang/perl ; then
+		touch src/dircolors.h || die
+		touch ${@/%x/1} || die
+	fi
+}
+
+src_configure() {
+	# On alpha at least, gnulib (as of 9.3) can't seem to figure out we need
+	# _F_O_B=64: https://debbugs.gnu.org/64123
+	append-lfs-flags
+
+	local myconf=(
+		--with-packager="Gentoo"
+		--with-packager-version="${PVR} (p${PATCH_VER:-0})"
+		--with-packager-bug-reports="https://bugs.gentoo.org/"
+		# kill/uptime - procps
+		# groups/su   - shadow
+		# hostname    - net-tools
+		--enable-install-program="arch,$(usev hostname),$(usev kill)"
+		--enable-no-install-program="groups,$(usev !hostname),$(usev !kill),su,uptime"
+		$(usex caps '' --disable-libcap)
+		$(use_enable nls)
+		$(use_enable acl)
+		$(use_enable multicall single-binary)
+		$(use_enable xattr)
+		$(use_with gmp libgmp)
+		$(use_with openssl)
+	)
+
+	if use gmp ; then
+		myconf+=( --with-libgmp-prefix="${ESYSROOT}"/usr )
+	fi
+
+	if tc-is-cross-compiler && [[ ${CHOST} == *linux* ]] ; then
+		# bug #311569
+		export fu_cv_sys_stat_statfs2_bsize=yes
+		# bug #416629
+		export gl_cv_func_realpath_works=yes
+	fi
+
+	# bug #409919
+	export gl_cv_func_mknod_works=yes
+
+	if use static ; then
+		append-ldflags -static
+		# bug #321821
+		sed -i '/elf_sys=yes/s:yes:no:' configure || die
+	fi
+
+	if ! use selinux ; then
+		# bug #301782
+		export ac_cv_{header_selinux_{context,flash,selinux}_h,search_setfilecon}=no
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	# Known to fail with FEATURES=usersandbox (bug #439574):
+	#   -  tests/du/long-from-unreadable.sh} (bug #413621)
+	#   -  tests/rm/deep-2.sh (bug #413621)
+	#   -  tests/dd/no-allocate.sh (bug #629660)
+	if has usersandbox ${FEATURES} ; then
+		ewarn "You are emerging ${P} with 'usersandbox' enabled." \
+			"Expect some test failures or emerge with 'FEATURES=-usersandbox'!"
+	fi
+
+	# Non-root tests will fail if the full path isn't
+	# accessible to non-root users
+	chmod -R go-w "${WORKDIR}" || die
+	chmod a+rx "${WORKDIR}" || die
+
+	# coreutils tests like to do `mount` and such with temp dirs,
+	# so make sure:
+	# - /etc/mtab is writable (bug #265725)
+	# - /dev/loop* can be mounted (bug #269758)
+	mkdir -p "${T}"/mount-wrappers || die
+	mkwrap() {
+		local w ww
+		for w in "${@}" ; do
+			ww="${T}/mount-wrappers/${w}"
+			cat <<-EOF > "${ww}"
+				#!${EPREFIX}/bin/sh
+				exec env SANDBOX_WRITE="\${SANDBOX_WRITE}:/etc/mtab:/dev/loop" $(type -P ${w}) "\$@"
+			EOF
+			chmod a+rx "${ww}" || die
+		done
+	}
+	mkwrap mount umount
+
+	addwrite /dev/full
+	#export RUN_EXPENSIVE_TESTS="yes"
+	#export FETISH_GROUPS="portage wheel"
+	env PATH="${T}/mount-wrappers:${PATH}" gl_public_submodule_commit= \
+		emake -k check VERBOSE=yes
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	newins src/dircolors.hin DIR_COLORS
+
+	if use split-usr ; then
+		cd "${ED}"/usr/bin || die
+		dodir /bin
+
+		# Move critical binaries into /bin (required by FHS)
+		local fhs="cat chgrp chmod chown cp date dd df echo false ln ls
+		           mkdir mknod mv pwd rm rmdir stty sync true uname"
+		mv ${fhs} ../../bin/ || die "Could not move FHS bins!"
+
+		if use hostname ; then
+			mv hostname ../../bin/ || die
+		fi
+
+		if use kill ; then
+			mv kill ../../bin/ || die
+		fi
+
+		# Move critical binaries into /bin (common scripts)
+		# (Why are these required for booting?)
+		local com="basename chroot cut dir dirname du env expr head mkfifo
+		           mktemp readlink seq sleep sort tail touch tr tty vdir wc yes"
+		mv ${com} ../../bin/ || die "Could not move common bins!"
+
+		# Create a symlink for uname in /usr/bin/ since autotools require it.
+		# (Other than uname, we need to figure out why we are
+		# creating symlinks for these in /usr/bin instead of leaving
+		# the files there in the first place...)
+		local x
+		for x in ${com} uname ; do
+			dosym ../../bin/${x} /usr/bin/${x}
+		done
+	fi
+}
+
+pkg_postinst() {
+	ewarn "Make sure you run 'hash -r' in your active shells."
+	ewarn "You should also re-source your shell settings for LS_COLORS"
+	ewarn "  changes, such as: source /etc/profile"
+}
diff --git a/sys-apps/coreutils/coreutils-9999.ebuild b/sys-apps/coreutils/coreutils-9999.ebuild
index 6e3d435cba1d..3e4dc9a20eb0 100644
--- a/sys-apps/coreutils/coreutils-9999.ebuild
+++ b/sys-apps/coreutils/coreutils-9999.ebuild
@@ -23,7 +23,7 @@ if [[ ${PV} == 9999 ]] ; then
 elif [[ ${PV} == *_p* ]] ; then
 	# Note: could put this in devspace, but if it's gone, we don't want
 	# it in tree anyway. It's just for testing.
-	MY_SNAPSHOT="$(ver_cut 1-2).198-e68b1"
+	MY_SNAPSHOT="$(ver_cut 1-2).18-ffd62"
 	SRC_URI="https://www.pixelbeat.org/cu/coreutils-${MY_SNAPSHOT}.tar.xz -> ${P}.tar.xz"
 	SRC_URI+=" verify-sig? ( https://www.pixelbeat.org/cu/coreutils-${MY_SNAPSHOT}.tar.xz.sig -> ${P}.tar.xz.sig )"
 	S="${WORKDIR}"/${PN}-${MY_SNAPSHOT}
@@ -135,6 +135,10 @@ src_prepare() {
 }
 
 src_configure() {
+	# On alpha at least, gnulib (as of 9.3) can't seem to figure out we need
+	# _F_O_B=64: https://debbugs.gnu.org/64123
+	append-lfs-flags
+
 	local myconf=(
 		--with-packager="Gentoo"
 		--with-packager-version="${PVR} (p${PATCH_VER:-0})"