gentoo resync : 02.06.2018

4 files changed, 210 insertions, 3 deletions

diff --git a/sys-apps/coreutils/Manifest b/sys-apps/coreutils/Manifest
index cc4aa1f14ad9..5767a505befc 100644
--- a/sys-apps/coreutils/Manifest
+++ b/sys-apps/coreutils/Manifest
@@ -3,6 +3,7 @@ DIST coreutils-8.28-patches-1.1.tar.xz 7336 BLAKE2B 9cd5db3e1d5545da5cb38f919ae5
 DIST coreutils-8.28.tar.xz 5252336 BLAKE2B 30e3c05311834b19a941ddaa6a405cb0033b0e3518211dd0d33e9a1aa91c60f4d597fca9419b467ade2b54e3bf81ba5149cebfc93a02fa1e546c1b0f71ee91c9 SHA512 1e592d0dd03b9227bf92af9a82bed6dc3bcbee46e984c7fb09833dea0962e86b309aa34d5e43823b73d4522c066bfa5cdc8ec694aa190910fb246ff32ceb63a1
 DIST coreutils-8.29-patches-1.0.tar.xz 5772 BLAKE2B 8f05185404d527ad524684231f0b8bef3b65e7752527b6bf55371f474035b8a92cdcaa8349a321784d14c6700a0d49e9d10ee2e3a96b78e8f6423ee8c5b9ec02 SHA512 0f7db6744a6a6bad8d582bb2d32e1a0ad0ab5f48a53b54c371d27494967832ddec2570e45dbf7e66c7091496bcecd66aab21644f603d2c8878a87f51a1a9b1a2
 DIST coreutils-8.29.tar.xz 5286588 BLAKE2B cbb66d9054bdd2db5b9a6010876484b16d178f8f4d935836b1e42830178647fac4e0a75052a6e7e2fbc50e74e4e7ff6f8da43f1137b96d0c2d027c4ebac28a98 SHA512 546bbcd5741beae7a68e7c4ca14d6d634f7c8be87feecdeddd00e226f4865bb89d503437c3a95622ba7bb0cb70addbb5bdf3767fa18d0b7410ab90ee53b29dfd
-EBUILD coreutils-8.28-r1.ebuild 6516 BLAKE2B cce086ffecc713b04301bbd498bca6cce4bb501d2d80ab93fa9dfd86b3e88c62ea79f652385a789b09f4e02f66a6a500637ff9d393f4c3294c1005f018de04be SHA512 8df28ce72003cd7f890f252b1f62addd0c80b2ed3b6599cde3cde7d25478923fb9848783c8ff5e88c91f75ba3c879e89d0e955acaa8467583cddc00630b57ad9
+EBUILD coreutils-8.28-r1.ebuild 6513 BLAKE2B 7202dde224d53d23d69d07b6f0db38eb52c17bc9cdfbe32e6e223bcf2e5823b81e819794f4088bfbb7ba7e060750a68d5c33156ebb4da010ffa947b25cca0528 SHA512 79fc8c2d6fc9e1c97317a8470166ee7fbf3e03a58ffcfbde3b7fdc172c571299bdd484f91039d79c3d1a0a2b1dc4113c8ec6d40c884fa52f469c8b68713f53ed
+EBUILD coreutils-8.29-r1.ebuild 6176 BLAKE2B 7401f3562c128eba7dece52d55464e345b782cbbb5d033a5c1321ba3a2485ab48f01e26a3f5eadf0614607949bf0f1aee34c83303f2ad442a2e4b618569323ac SHA512 d6e571fbf22f285d230c128fcc5d583070d7c9d5464ddf8a1198cbd1bdbd79b8394c229d045ce5a5d0ef042d5e26da0d9f60590df7d7ff6ec86b791268c812d1
 EBUILD coreutils-8.29.ebuild 6063 BLAKE2B 3582ae6e941fa7d6dc47729939ebec016d6d682d616069cac70c58dc34ecf13820820191be18c353f0fc4d86bb6af7becd888024fa5cf21c718c005c26bebd90 SHA512 095b2958618e972ae9f6d04f7868acc97996a3fbd8bede850d6f215d392736cfe046ee5afb99919e10f34b1dfbcbdd501ef37880f9d6ab0a697d68e342231196
-MISC metadata.xml 869 BLAKE2B 397aa866d67eb1d6ff5f604194cf071be0f75606092d78e1cf7f0ced85cf4474d67677307e7e8566ba402c1f94ae2f3e3906ef5006a50e73d6673edb25d517fa SHA512 19e07c93cbe1cfe087eb7fdc8647aa4c264f1e6a193a0ed4e1ceb302bda92565aa76966b6ef2efa15d7535082ef0e6a1454fee20eca4797466f5de5e37ac4957
+MISC metadata.xml 958 BLAKE2B f66e780b413255fcde84ab0114e0be6d285963be305cf67bf170243d491e2677dae0e6d33eee5660dfcd6672b55cae383651f878feceffea5085aab31c83b7b6 SHA512 3e4c60dc34a3b6a74392e45bee5a075126728ccc278d61985124780f24b387ef75934c0c0bb4f647e96916d289a5f0c3eccd5411546758c67d703638af87c044
diff --git a/sys-apps/coreutils/coreutils-8.28-r1.ebuild b/sys-apps/coreutils/coreutils-8.28-r1.ebuild
index 6629afaa9633..bde20a7a599d 100644
--- a/sys-apps/coreutils/coreutils-8.28-r1.ebuild
+++ b/sys-apps/coreutils/coreutils-8.28-r1.ebuild
@@ -24,7 +24,7 @@ SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
 
 LICENSE="GPL-3"
 SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~arm-linux ~x86-linux"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~arm-linux ~x86-linux"
 IUSE="acl caps gmp hostname kill multicall nls selinux static test userland_BSD vanilla xattr"
 
 LIB_DEPEND="acl? ( sys-apps/acl[static-libs] )
diff --git a/sys-apps/coreutils/coreutils-8.29-r1.ebuild b/sys-apps/coreutils/coreutils-8.29-r1.ebuild
new file mode 100644
index 000000000000..36ef844453e9
--- /dev/null
+++ b/sys-apps/coreutils/coreutils-8.29-r1.ebuild
@@ -0,0 +1,205 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit eutils flag-o-matic python-any-r1 toolchain-funcs
+
+PATCH_VER="1.0"
+DESCRIPTION="Standard GNU utilities (chmod, cp, dd, ls, sort, tr, head, wc, who,...)"
+HOMEPAGE="https://www.gnu.org/software/coreutils/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
+	mirror://gentoo/${P}-patches-${PATCH_VER}.tar.xz
+	https://dev.gentoo.org/~whissi/dist/${PN}/${P}-patches-${PATCH_VER}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~arm-linux ~x86-linux"
+IUSE="acl caps gmp hostname kill multicall nls selinux +split-usr static test userland_BSD vanilla xattr"
+
+LIB_DEPEND="acl? ( sys-apps/acl[static-libs] )
+	caps? ( sys-libs/libcap )
+	gmp? ( dev-libs/gmp:=[static-libs] )
+	xattr? ( !userland_BSD? ( sys-apps/attr[static-libs] ) )"
+RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs]} )
+	selinux? ( sys-libs/libselinux )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+	app-arch/xz-utils
+	test? (
+		dev-lang/perl
+		dev-perl/Expect
+		!userland_BSD? (
+			dev-util/strace
+		)
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/pyinotify[${PYTHON_USEDEP}]')
+	)"
+RDEPEND+="
+	hostname? ( !sys-apps/net-tools[hostname] )
+	kill? (
+		!sys-apps/util-linux[kill]
+		!sys-process/procps[kill]
+	)
+	!app-misc/realpath
+	!<sys-apps/util-linux-2.13
+	!<sys-apps/sandbox-2.10-r4
+	!sys-apps/stat
+	!net-mail/base64
+	!sys-apps/mktemp
+	!<app-forensics/tct-1.18-r1
+	!<net-fs/netatalk-2.0.3-r4"
+
+pkg_setup() {
+	if use test ; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	if ! use vanilla ; then
+		eapply "${WORKDIR}"/patch/*.patch
+	fi
+
+	eapply_user
+
+	# Since we've patched many .c files, the make process will try to
+	# re-build the manpages by running `./bin --help`.  When doing a
+	# cross-compile, we can't do that since 'bin' isn't a native bin.
+	# Also, it's not like we changed the usage on any of these things,
+	# so let's just update the timestamps and skip the help2man step.
+	set -- man/*.x
+	touch ${@/%x/1}
+
+	# Avoid perl dep for compiled in dircolors default #348642
+	if ! has_version dev-lang/perl ; then
+		touch src/dircolors.h
+		touch ${@/%x/1}
+	fi
+}
+
+src_configure() {
+	local myconf=(
+		--with-packager="Gentoo"
+		--with-packager-version="${PVR} (p${PATCH_VER:-0})"
+		--with-packager-bug-reports="https://bugs.gentoo.org/"
+		--enable-install-program="arch,$(usev hostname),$(usev kill)"
+		--enable-no-install-program="groups,$(usev !hostname),$(usev !kill),su,uptime"
+		--enable-largefile
+		$(use caps || echo --disable-libcap)
+		$(use_enable nls)
+		$(use_enable acl)
+		$(use_enable multicall single-binary)
+		$(use_enable xattr)
+		$(use_with gmp)
+	)
+	if tc-is-cross-compiler && [[ ${CHOST} == *linux* ]] ; then
+		export fu_cv_sys_stat_statfs2_bsize=yes #311569
+		export gl_cv_func_realpath_works=yes #416629
+	fi
+
+	export gl_cv_func_mknod_works=yes #409919
+	use static && append-ldflags -static && sed -i '/elf_sys=yes/s:yes:no:' configure #321821
+	use selinux || export ac_cv_{header_selinux_{context,flash,selinux}_h,search_setfilecon}=no #301782
+	use userland_BSD && myconf+=( -program-prefix=g --program-transform-name=s/stat/nustat/ )
+	# kill/uptime - procps
+	# groups/su   - shadow
+	# hostname    - net-tools
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	# Known to fail with FEATURES=usersandbox (bug #439574):
+	#   -  tests/du/long-from-unreadable.sh} (bug #413621)
+	#   -  tests/rm/deep-2.sh (bug #413621)
+	#   -  tests/dd/no-allocate.sh (bug #629660)
+	if has usersandbox $FEATURES ; then
+		ewarn "You are emerging ${P} with 'usersandbox' enabled." \
+			"Expect some test failures or emerge with 'FEATURES=-usersandbox'!"
+	fi
+
+	# Non-root tests will fail if the full path isn't
+	# accessible to non-root users
+	chmod -R go-w "${WORKDIR}"
+	chmod a+rx "${WORKDIR}"
+
+	# coreutils tests like to do `mount` and such with temp dirs
+	# so make sure /etc/mtab is writable #265725
+	# make sure /dev/loop* can be mounted #269758
+	mkdir -p "${T}"/mount-wrappers
+	mkwrap() {
+		local w ww
+		for w in "$@" ; do
+			ww="${T}/mount-wrappers/${w}"
+			cat <<-EOF > "${ww}"
+				#!${EPREFIX}/bin/sh
+				exec env SANDBOX_WRITE="\${SANDBOX_WRITE}:/etc/mtab:/dev/loop" $(type -P $w) "\$@"
+			EOF
+			chmod a+rx "${ww}"
+		done
+	}
+	mkwrap mount umount
+
+	addwrite /dev/full
+	#export RUN_EXPENSIVE_TESTS="yes"
+	#export FETISH_GROUPS="portage wheel"
+	env PATH="${T}/mount-wrappers:${PATH}" \
+	emake -j1 -k check
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	newins src/dircolors.hin DIR_COLORS
+
+	if [[ ${USERLAND} == "GNU" ]] ; then
+		cd "${ED%/}"/usr/bin || die
+		dodir /bin
+		# move critical binaries into /bin (required by FHS)
+		local fhs="cat chgrp chmod chown cp date dd df echo false ln ls
+		           mkdir mknod mv pwd rm rmdir stty sync true uname"
+		mv ${fhs} ../../bin/ || die "could not move fhs bins"
+		if use hostname; then
+			mv hostname ../../bin/ || die
+		fi
+		if use kill; then
+			mv kill ../../bin/ || die
+		fi
+		if use split-usr ; then
+			# move critical binaries into /bin (common scripts)
+			local com="basename chroot cut dir dirname du env expr head mkfifo
+			           mktemp readlink seq sleep sort tail touch tr tty vdir wc yes"
+			mv ${com} ../../bin/ || die "could not move common bins"
+			# create a symlink for uname in /usr/bin/ since autotools require it
+			local x
+			for x in ${com} uname ; do
+				dosym ../../bin/${x} /usr/bin/${x}
+			done
+		fi
+	else
+		# For now, drop the man pages, collides with the ones of the system.
+		rm -rf "${ED%/}"/usr/share/man
+	fi
+
+}
+
+pkg_postinst() {
+	ewarn "Make sure you run 'hash -r' in your active shells."
+	ewarn "You should also re-source your shell settings for LS_COLORS"
+	ewarn "  changes, such as: source /etc/profile"
+
+	# Help out users using experimental filesystems
+	if grep -qs btrfs "${EROOT%/}"/etc/fstab /proc/mounts ; then
+		case $(uname -r) in
+		2.6.[12][0-9]|2.6.3[0-7]*)
+			ewarn "You are running a system with a buggy btrfs driver."
+			ewarn "Please upgrade your kernel to avoid silent corruption."
+			ewarn "See: https://bugs.gentoo.org/353907"
+			;;
+		esac
+	fi
+}
diff --git a/sys-apps/coreutils/metadata.xml b/sys-apps/coreutils/metadata.xml
index 9241968a4690..4e46af051b39 100644
--- a/sys-apps/coreutils/metadata.xml
+++ b/sys-apps/coreutils/metadata.xml
@@ -12,6 +12,7 @@
 	<flag name="hostname">Build the hostname program</flag>
 	<flag name="kill">Build the kill program</flag>
 	<flag name="multicall">Build all tools into a single `coreutils` program akin to busybox to save space</flag>
+	<flag name="split-usr">Enable this if /bin and /usr/bin are separate directories</flag>
 </use>
 <upstream>
 	<remote-id type="cpe">cpe:/a:gnu:coreutils</remote-id>