gentoo auto-resync : 23:10:2024 - 04:04:36

3 files changed, 240 insertions, 0 deletions

diff --git a/sci-visualization/Manifest.gz b/sci-visualization/Manifest.gz
index 513305e2947b..d0c455555181 100644
--- a/sci-visualization/Manifest.gz
+++ b/sci-visualization/Manifest.gz
diff --git a/sci-visualization/paraview/Manifest b/sci-visualization/paraview/Manifest
index 1c11c3b721ea..b7993fe24443 100644
--- a/sci-visualization/paraview/Manifest
+++ b/sci-visualization/paraview/Manifest
@@ -3,7 +3,9 @@ AUX paraview-5.5.0-allow_custom_build_type.patch 1036 BLAKE2B ff00093034196935e9
 DIST ParaView-v5.11.1.tar.xz 79847556 BLAKE2B efef5e519a82ef1c0a7d532578778f6a95f07ebd72ebefd0cbdcff0bfc3af1773601cd102ff81f45f302fcaa4bb6ec7ee68f7dec77f5d4e137c2842fbbb54e11 SHA512 d0e666b49f49e41dba23e23d454a9462f018bd6d832628b0029e8d54760f0439ca97841a26da3126c5144780fc01dc25234a6624fb35346a98d35cbe0e0c98ca
 DIST ParaView-v5.12.0-RC1.tar.xz 128908020 BLAKE2B 3222ac21f733559b9f5c7e8c1009a19c0e462e2622805db7d61b683f25d70fc40cf096d699afde6dab9e23c102e3df9251a718d3ecbaac7a56db01c898270cd9 SHA512 1c6a052081e274a120563c5ffc73dadf4e02be237cc0c213a22d0b93a9865713c83992a3fc0cc1c52742b0753546b5b983a3f650989e8a472ac2f7e90383de92
 DIST ParaView-v5.12.0.tar.xz 129439820 BLAKE2B b9a59c22d15ee1582704c7e6c70a259d8b8df5d0f59fb87902ade07bce3ef7b52b055d75bb0876b7a0a9b493a7ef8df377f0ac281c370c72d9b89418efec9657 SHA512 d7ad95105f43672c5f0001f673977b7742cca113b78b0d953f4c55f60a6cf72b8a216515136251f63b8294becb0ea717b5118bf48b78ca8db85949a1b59892c1
+DIST ParaView-v5.13.0.tar.xz 133195632 BLAKE2B f4e639d01667dfb7ad02fa51133b1e2d29429aefa89e7f77772d0080aa537d910f9b6f7868e4a31d52b392762c38d94ec228b2a754936409077eb2f8ffcf7f1c SHA512 ba0051902efb2a9c599e500f85f9b20bc46eead1e1f68daa0fea0295ee606844fb72fb8eee04f67f7cced3a35be2b2b442c6f1160fc4f2c2eedfbe9c440b5b1f
 EBUILD paraview-5.11.1-r1.ebuild 6251 BLAKE2B 4452567cb75694727d5456beb8dddbab0276098563be8a1b965e0fbdbc13609879872f9dfdc61307944c7417fa344f719334d02ea8ccda10e047c1518b287472 SHA512 dbe57b15c77fd073cc03ca0ec07c4edb2c5ee4f3f12c5bd112345d70efd55de92a94c967a7a556d79b42ca72e45d344ef32d92bf719a72b71f1b0a139f555356
 EBUILD paraview-5.12.0.ebuild 6260 BLAKE2B 66604c9c100146d68b7805333867b738a79b2b428807d7e5c8314256f9dce6fb616c9d5e6f7e508f48c859e7f939f4eb4c993e2b12c3ec264f734a107baddbd4 SHA512 0bc757085502574c37d97b64c38644c0d655e80ea38937fa086d656e1a005748776a28e3445e56e5b8001b91a71c865a4c26761f5ec823bda62bc8c2ad1de4df
 EBUILD paraview-5.12.0_rc1-r1.ebuild 6260 BLAKE2B 4d24c2c876ccc685ff46b5d4d2a8eba2fd95f6205b90e1b8a60f15bdfb62923bd437a8ae109cb6ec155c1f12eebba700befd500b777744c2342ff086028a198c SHA512 268ea39ad59659ba289743681b29636db53c9634cc53002c6d04ecc0b91d88f217d8673c2e76360063ea7d23e7bb110ef5295eccb25fc70d3fd3d7e962acafb8
+EBUILD paraview-5.13.0.ebuild 6068 BLAKE2B cbca83b87c4b0592ae7bfa6d1f419a3bae084f5a143fd2cd5df9539b96048704b15f5400c3462cfdc6f70f82132de176fea9d210fec5aa852fd8521e76500c75 SHA512 deaf109ec2f2210b996279fa9b607ef8d3485c891e2ff88af5c1ce5e42cf76cd3705d9f5db2bc4047d474e81aee8db5cffccd7c646768c16ec3f7a4114657120
 MISC metadata.xml 683 BLAKE2B 28b4017609ac733ac1c1ff4cb4ac3b5341f72180f487542b9db3b8bee59357ac9fed25bc0287a2f8c93f7429d098d1b26c74741b86b943564a4caafd7ee8450e SHA512 0bd4a1c8331532529d405f36c4556f57caecc299ceddd4ca8ff23138d96bd450c1d4fade7f02edddd8f9b3062d6b31bcb9a7696b2b628494c1d1b60d0312bc91
diff --git a/sci-visualization/paraview/paraview-5.13.0.ebuild b/sci-visualization/paraview/paraview-5.13.0.ebuild
new file mode 100644
index 000000000000..783e7e442b77
--- /dev/null
+++ b/sci-visualization/paraview/paraview-5.13.0.ebuild
@@ -0,0 +1,238 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+DOCS_BUILDER="doxygen"
+inherit cmake flag-o-matic desktop docs python-single-r1 qmake-utils toolchain-funcs xdg
+
+MAJOR_PV="$(ver_cut 1-2)"
+MINOR_PV="$(ver_cut 3)"
+RC_PV="$(ver_cut 4-5)"
+RC_PV="${RC_PV:+-${RC_PV^^}}"
+MY_P="ParaView-v${MAJOR_PV}.${MINOR_PV}${RC_PV}"
+
+DESCRIPTION="Powerful scientific data visualization application"
+HOMEPAGE="https://www.paraview.org"
+SRC_URI="https://www.paraview.org/files/v${MAJOR_PV}/${MY_P}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+# TODO: check licenses of plugins (USE=plugins)
+LICENSE="BSD MIT PSF-2 VTK"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boost cg examples ffmpeg mpi nvcontrol openmp offscreen plugins python +qt6 +sqlite test tk +webengine"
+
+RESTRICT="mirror test"
+
+REQUIRED_USE="
+	python? ( mpi ${PYTHON_REQUIRED_USE} )
+	webengine? ( qt6 )
+	qt6? ( sqlite )
+	?? ( offscreen qt6 )"
+
+RDEPEND="
+	app-arch/lz4
+	dev-libs/expat
+	dev-libs/jsoncpp:=
+	dev-libs/libxml2:2
+	dev-libs/protobuf:=
+	dev-libs/pugixml
+	media-libs/freetype
+	media-libs/glew:0
+	media-libs/libpng:0
+	media-libs/libtheora
+	media-libs/tiff:=
+	sci-libs/cgnslib
+	sci-libs/hdf5:=[mpi=]
+	>=sci-libs/netcdf-4.2[hdf5]
+	>=sci-libs/netcdf-cxx-4.2:3
+	sys-libs/zlib
+	virtual/glu
+	media-libs/libjpeg-turbo:=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXmu
+	x11-libs/libXt
+	ffmpeg? ( media-video/ffmpeg )
+	mpi? ( virtual/mpi[cxx,romio] )
+	offscreen? ( >=media-libs/mesa-18.3.6[osmesa] )
+	!offscreen? ( virtual/opengl )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/constantly[${PYTHON_USEDEP}]
+			dev-python/incremental[${PYTHON_USEDEP}]
+			dev-python/matplotlib[${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+			dev-python/pygments[${PYTHON_USEDEP}]
+			dev-python/sip:5[${PYTHON_USEDEP}]
+			dev-python/six[${PYTHON_USEDEP}]
+			dev-python/twisted[${PYTHON_USEDEP}]
+			dev-python/zope-interface[${PYTHON_USEDEP}]
+			mpi? ( dev-python/mpi4py )
+			qt6? ( dev-python/PyQt6[opengl,${PYTHON_USEDEP}] )
+		')
+	)
+	qt6? (
+		dev-qt/qt5compat:6
+		dev-qt/qtbase:6[gui,opengl,sql]
+		dev-qt/qtdeclarative:6
+		dev-qt/qtsvg:6
+		dev-qt/qttools:6[assistant,designer,widgets]
+	)
+	sqlite? ( dev-db/sqlite:3 )
+	tk? ( dev-lang/tk:0= )
+	webengine? ( dev-qt/qtwebengine:6[widgets] )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	boost? (
+		$(python_gen_cond_dep '
+			dev-libs/boost[mpi?,python,${PYTHON_USEDEP}]
+		')
+	)
+"
+
+BDEPEND="
+	openmp? ( virtual/fortran )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.5.0-allow_custom_build_type.patch
+)
+
+# false positive when checking for available HDF5 interface, bug #904731
+QA_CONFIG_IMPL_DECL_SKIP=(
+	H5Pset_coll_metadata_write
+	H5Pset_all_coll_metadata_ops
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	use python && python-single-r1_pkg_setup
+	PVLIBDIR=$(get_libdir)/${PN}-${MAJOR_PV}
+}
+
+src_prepare() {
+	# Bug #661812
+	mkdir -p Plugins/StreamLinesRepresentation/doc || die
+
+	cmake_src_prepare
+
+	# lib64 fixes
+	sed -i \
+		-e "s:/lib/python:/$(get_libdir)/python:g" \
+		VTK/ThirdParty/xdmf3/vtkxdmf3/CMakeLists.txt || die
+	sed -i \
+		-e "s:lib/paraview-:$(get_libdir)/paraview-:g" \
+		Remoting/Application/vtkInitializationHelper.cxx || die
+}
+
+src_configure() {
+	# Needed to compile bundled VTK in ParaView 5.11.1 with gcc 12
+	# see also, bug #863299
+	filter-lto
+	append-cflags $(test-flags-CC -fno-strict-aliasing \
+		-Wno-error=incompatible-function-pointer-types -Wno-error=int-conversion)
+	append-cxxflags $(test-flags-CXX -fno-strict-aliasing \
+		-Wno-error=incompatible-function-pointer-types -Wno-error=int-conversion)
+
+	# Make sure qmlplugindump is in path:
+	export PATH="$(qt6_get_bindir):${PATH}"
+
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_LIBDIR="${PVLIBDIR}"
+		-UBUILD_SHARED_LIBS
+		-DPARAVIEW_BUILD_SHARED_LIBS=ON
+		-DCMAKE_VERBOSE_MAKEFILE=ON
+
+		# boost
+		-DVTK_MODULE_ENABLE_VTK_IOInfovis="$(usex boost YES NO)"
+
+		# doc
+		-DPARAVIEW_BUILD_DEVELOPER_DOCUMENTATION="$(usex doc)"
+
+		# examples
+		-DBUILD_EXAMPLES="$(usex examples)"
+
+		# ffmpeg
+		-DPARAVIEW_ENABLE_FFMPEG="$(usex ffmpeg)"
+
+		# mpi
+		-DPARAVIEW_USE_MPI="$(usex mpi)"
+		-DXDMF_BUILD_MPI="$(usex mpi)"
+		-DVTK_GROUP_ENABLE_MPI="$(usex mpi YES NO)"
+
+		# offscreen
+		-DVTK_OPENGL_HAS_OSMESA="$(usex offscreen)"
+		-DVTK_OPENGL_HAS_OSMESA="$(usex offscreen)"
+
+		# plugins
+		-DPARAVIEW_PLUGINS_DEFAULT="$(usex plugins)"
+
+		# python
+		-DModule_pqPython="$(usex python)"
+		-DPARAVIEW_USE_PYTHON="$(usex python)"
+
+		# qt6
+		-DPARAVIEW_USE_QT="$(usex qt6)"
+		-DPARAVIEW_QT_VERSION="6"
+		-DVTK_QT_VERSION="6"
+		-DModule_pqPython="$(usex qt6 "$(usex python)" "off")"
+		-DVTK_USE_NVCONTROL="$(usex nvcontrol)"
+		-DVTK_GROUP_ENABLE_Qt="$(usex qt6 YES NO)"
+		-DCMAKE_INSTALL_QMLDIR="${EPREFIX}/usr/$(get_libdir)/qt6/qml"
+
+		# sqlite
+		-DVTK_MODULE_ENABLE_VTK_sqlite="$(usex sqlite YES NO)"
+
+		# test
+		-DBUILD_TESTING="$(usex test)"
+
+		# tk
+		-DVTK_USE_TK="$(usex tk)"
+		-DVTK_GROUP_ENABLE_Tk="$(usex tk YES NO)"
+
+		# webengine
+		-DPARAVIEW_USE_QTWEBENGINE="$(usex webengine)"
+		-DVTK_GROUP_ENABLE_Web="$(usex webengine YES NO)"
+	)
+
+	if use openmp; then
+		mycmakeargs+=( -DVTK_SMP_IMPLEMENTATION_TYPE=OpenMP )
+	fi
+
+	if use qt6; then
+		mycmakeargs+=(
+			-DOPENGL_gl_LIBRARY="${EPREFIX}"/usr/$(get_libdir)/libGL.so
+			-DOPENGL_glu_LIBRARY="${EPREFIX}"/usr/$(get_libdir)/libGLU.so
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# remove wrapper binaries and put the actual executable in place
+	for i in {paraview-config,pvserver,pvdataserver,pvrenderserver,pvbatch,pvpython,paraview}; do
+		if [ -f "${ED}"/usr/lib/"$i" ]; then
+			mv "${ED}"/usr/lib/"$i" "${ED}"/usr/bin/"$i" || die
+		fi
+	done
+
+	# set up the environment
+	echo "LDPATH=${EPREFIX}/usr/${PVLIBDIR}" > "${T}"/40${PN} || die
+	doenvd "${T}"/40${PN}
+
+	newicon "${S}"/Clients/ParaView/pvIcon-96x96.png paraview.png
+	make_desktop_entry paraview "Paraview" paraview
+
+	use python && python_optimize "${ED}/usr/$(get_libdir)/${PN}-${MAJOR_PV}"
+}