reinit the tree, so we can have metadata

1 files changed, 52 insertions, 0 deletions

diff --git a/sci-mathematics/glpk/glpk-4.48.ebuild b/sci-mathematics/glpk/glpk-4.48.ebuild
new file mode 100644
index 000000000000..f8ce132717c0
--- /dev/null
+++ b/sci-mathematics/glpk/glpk-4.48.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils flag-o-matic toolchain-funcs autotools-utils
+
+DESCRIPTION="GNU Linear Programming Kit"
+LICENSE="GPL-3"
+HOMEPAGE="https://www.gnu.org/software/glpk/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+SLOT="0"
+IUSE="doc examples gmp odbc mysql static-libs"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+
+RDEPEND="
+	gmp? ( dev-libs/gmp:0 )
+	mysql? ( virtual/mysql )
+	odbc? ( || ( dev-db/libiodbc dev-db/unixODBC ) )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.52.1-mariadb-5.5.patch
+)
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable mysql)
+		$(use_enable odbc)
+		$(use_with gmp)
+	)
+	if use mysql || use odbc; then
+		myeconfargs+=( --enable-dl )
+	else
+		myeconfargs+=( --disable-dl )
+	fi
+	[[ -z $(type -P odbc-config) ]] && \
+		append-cppflags $($(tc-getPKG_CONFIG) --cflags libiodbc)
+
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+	use doc && dodoc doc/*.pdf doc/notes/*.pdf doc/*.txt
+}