reinit the tree, so we can have metadata

1 files changed, 60 insertions, 0 deletions

diff --git a/sci-mathematics/calc/calc-2.12.5.4.ebuild b/sci-mathematics/calc/calc-2.12.5.4.ebuild
new file mode 100644
index 000000000000..c8ebd6a8570c
--- /dev/null
+++ b/sci-mathematics/calc/calc-2.12.5.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Arbitrary precision C-like arithmetic system"
+HOMEPAGE="http://www.isthe.com/chongo/tech/comp/calc/"
+SRC_URI="http://www.isthe.com/chongo/src/calc/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="LGPL-2"
+KEYWORDS="~alpha amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE=""
+
+RDEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/readline:0="
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-as-needed.patch"
+)
+
+src_prepare() {
+	default
+	ln -sf libcustcalc.so.${PV} custom/libcustcalc.so || die
+	sed -i -e "/DIR/s:/usr:${EPREFIX}/usr:g" Makefile || die
+}
+
+src_compile() {
+	# parallel compilation hard to fix. better to leave upstream.
+	emake -j1 \
+		CC="$(tc-getCC)" \
+		DEBUG="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		CALCPAGER="${PAGER}" \
+		USE_READLINE="-DUSE_READLINE" \
+		READLINE_LIB="-lreadline -lhistory $(pkg-config --libs ncurses) -L\"${S}\"/custom -lcustcalc" \
+		all
+}
+
+src_test() {
+	if echo "${LD_PRELOAD}" | grep -q "sandbox"; then
+		ewarn "Can't run check when running in sandbox - see bug #59676"
+	else
+		emake chk
+	fi
+}
+
+src_install() {
+	emake \
+		T="${D}" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		install
+	dodoc BUGS CHANGES LIBRARY README
+}