gentoo resync : 14.12.2020

3 files changed, 162 insertions, 4 deletions

diff --git a/sci-libs/mathgl/Manifest b/sci-libs/mathgl/Manifest
index 52a021e67f81..12047b54dbad 100644
--- a/sci-libs/mathgl/Manifest
+++ b/sci-libs/mathgl/Manifest
@@ -1,5 +1,7 @@
 AUX mathgl-2.4.1-mutex.patch 424 BLAKE2B 2077654d0b17d2a1ba63bfcc17bcc82dac7dcc274253357a70cd0b2d49f9c99b73b380c1d09ad70e302fd04449b9adb6392c12cbd03fcefae4a36a50491cf012 SHA512 d0a0101041c91ba4d295484b8b06825d66787600b98acc2ee6e3cb8ec54e86939deadc40924bce42b6eb782bf5c03c6a7687ac853d7bc393e75bcf9a809d7849
 DIST STIX_font.tgz 2450541 BLAKE2B f725eb0264d9c3cb7c32a935e8857c4a21cb905a1dc6c9cc8a16408afdc7dd9b6fcd312a8c2f77aff5484605a39a9ee36e86ad0234adb5d6bcc5c8839101194c SHA512 c9124ec552074c98f15d6d3572a063598ca6bc598e3e78dcb5a5d57ae3928b5327a1374635f428ea1cefc9e51ee1d1aa9bd6ba9a306429fc6965140251d368b5
 DIST mathgl-2.4.1.tar.gz 22665490 BLAKE2B a9c9e0ec7d145262994a754dfbcf1f789d2777f9334c8b4e73696265adba4d2fd7283621857318264c2162841e81427df21f7bc7b951d83876fbc066d3b9068f SHA512 10fd016662ca60b9507942691f85b4d9151104319627732f4add0175475f7e8dff16e3645bb858c283b747f34e58f410d0532e94dc64cf8cf472938d3966402d
-EBUILD mathgl-2.4.1-r2.ebuild 3798 BLAKE2B f2e48362be5f684a2d14413fee9781a51f55ff60ceb1ae1c72cd62f6804484e230974b63c92c4bb1849d5915bf48e3867a6394880b8983fa0f0f14b7a34314ab SHA512 561fc047d3b50617ebad6d1ff1f85113eb33f21052cf123f04ec864fe854f1a93513909a2d8b6bcd175538fd870b24fad3d839ac288ab4e1474a23538c7310f0
+DIST mathgl-2.4.4.tar.gz 23917716 BLAKE2B 11d36195c65b11f0eedbc1c946f600fd33bdc6ab8d3ff95c65634300527b2e06ffbb6615e4425896b87435fdb45bfad806f00e79edd26af4ab67bf223695d5cf SHA512 6955cb3630b4c17ab7eeb7542569a7fba653f592640f30700988abe340ecb17f09f1cbcd3903232797e9debc9f74ba2ea1f76f51935749bc8dec5e05951bb573
+EBUILD mathgl-2.4.1-r2.ebuild 3736 BLAKE2B 4a47173d6c953a295ea1612eb765799de684c9e9b763b41f67da35f04709961c45084e62a7706c29cbddd6a15ab5e57d69ac395832cbfb52eab9862c0608ebb8 SHA512 dcebfaaadd30c48b7103ed9f8d5cf2e363940fb1e42382580452e5f48aa636e6074410ae7bc455a333271cd8a0ec68d4977483e3424b8b3d8815d1d1988e8b7e
+EBUILD mathgl-2.4.4.ebuild 3668 BLAKE2B dd56806436422a28f89a859f3f029c8b3f55888643d38ad54472cc425cab1d40bc7de1f487b0ca8aee0f06e73bbedfda1678b5eb1ffb33ffc763e478706b68e0 SHA512 4593b632c4b15dae0c74f3a736df64cee7fa93dfa22b37cf4607b0068b00775fd4ce61d6b8bce05964411974fc79d88a43e16bae7eb7dfd973e2518d829bd875
 MISC metadata.xml 800 BLAKE2B baa75251910016e5d059cebeebd85632d290ab0c3c50089de0485ffbcd08ee8ac59cbfe33824347a5a5c339c74ea7a56c516d4d38661e56f7498d628d748f64a SHA512 8b75db0a01ce59f22543701447630c56a82f9091b5901f85ae102de7deca281e09dbcb443b8ff2930cf18145d63504646a289fd5e77defccc4d38480596d1968
diff --git a/sci-libs/mathgl/mathgl-2.4.1-r2.ebuild b/sci-libs/mathgl/mathgl-2.4.1-r2.ebuild
index 871e6edae562..b9f2abff3f8e 100644
--- a/sci-libs/mathgl/mathgl-2.4.1-r2.ebuild
+++ b/sci-libs/mathgl/mathgl-2.4.1-r2.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz mirror://sourceforge/${PN}/STIX_
 LICENSE="LGPL-3"
 SLOT="0/7.5.0"
 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc fltk gif glut gsl hdf hdf5 jpeg lua mpi octave opengl openmp pdf
+IUSE="doc fltk gif glut gsl hdf hdf5 jpeg mpi octave opengl openmp pdf
 	png qt5 static-libs threads wxwidgets zlib"
 
 LANGS="ru"
@@ -32,7 +32,6 @@ RDEPEND="
 	hdf? ( sci-libs/hdf )
 	hdf5? ( >=sci-libs/hdf5-1.8[mpi=] )
 	jpeg? ( virtual/jpeg:0 )
-	lua? ( >=dev-lang/lua-5.1:0 )
 	octave? ( >=sci-mathematics/octave-3.4.0 )
 	openmp? ( sys-cluster/openmpi )
 	pdf? ( media-libs/libharu )
@@ -110,7 +109,6 @@ src_configure() {
 		-Denable-hdf4=$(usex hdf)
 		-Denable-hdf5=$(usex hdf5)
 		-Denable-jpeg=$(usex jpeg)
-		-Denable-lua=$(usex lua)
 		-Denable-mpi=$(usex mpi)
 		-Denable-octave=$(usex octave)
 		-Denable-opengl=$(usex opengl)
diff --git a/sci-libs/mathgl/mathgl-2.4.4.ebuild b/sci-libs/mathgl/mathgl-2.4.4.ebuild
new file mode 100644
index 000000000000..4485d272e448
--- /dev/null
+++ b/sci-libs/mathgl/mathgl-2.4.4.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+WX_GTK_VER=3.0
+
+inherit cmake wxwidgets multilib flag-o-matic
+
+DESCRIPTION="Math Graphics Library"
+HOMEPAGE="http://mathgl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz mirror://sourceforge/${PN}/STIX_font.tgz"
+
+LICENSE="LGPL-3"
+SLOT="0/7.5.0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc fltk gif glut gsl hdf hdf5 jpeg mpi octave opengl openmp pdf
+	png qt5 static-libs threads wxwidgets zlib"
+
+LANGS="ru"
+for l in ${LANGS}; do
+	IUSE+=" l10n_${l}"
+done
+unset l
+
+RDEPEND="
+	virtual/opengl
+	fltk? ( x11-libs/fltk:1 )
+	gif? ( media-libs/giflib )
+	glut? ( media-libs/freeglut )
+	gsl? ( >=sci-libs/gsl-2 )
+	hdf? ( sci-libs/hdf )
+	hdf5? ( >=sci-libs/hdf5-1.8[mpi=] )
+	jpeg? ( virtual/jpeg:0 )
+	octave? ( >=sci-mathematics/octave-3.4.0 )
+	openmp? ( sys-cluster/openmpi )
+	pdf? ( media-libs/libharu )
+	png? ( media-libs/libpng:0 )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+	)
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-text/texi2html virtual/texi2dvi )
+	octave? ( dev-lang/swig )"
+
+REQUIRED_USE="
+	mpi? ( hdf5 )
+	openmp? ( !threads )
+	png? ( zlib )
+	pdf? ( png )"
+
+pkg_setup() {
+	use mpi && export CC=mpicc CXX=mpicxx
+}
+
+src_unpack() {
+	default
+	if ! [[ -d "${S}"/fonts ]]; then
+		mkdir "${S}"/fonts || die
+	fi
+	cd "${S}"/fonts || die
+	unpack STIX_font.tgz
+}
+
+src_prepare() {
+	# fix for location of hdf headers
+	sed -i -e 's:hdf/::g' src/data_io.cpp || die
+	# bored of reporting bad libdir upstream
+	sed -i \
+		-e '/DESTINATION/s:lib$:lib${LIB_SUFFIX}:g' \
+		{src,widgets}/CMakeLists.txt || die
+	echo "" > lang/install.m || die
+	# fix desktop file
+	sed -i -e 's/.png//' udav/udav.desktop || die
+	# prevent sandbox violation
+	sed -i -e 's/update-mime-database/true/' udav/CMakeLists.txt || die
+	sed -i -e 's/update-desktop-database/true/' udav/CMakeLists.txt || die
+
+	use wxwidgets && need-wxwidgets unicode
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=()
+	if use hdf; then
+		mycmakeargs+=(
+			-DHDF4_INCLUDE_DIR="${EPREFIX}/usr/include"
+		)
+	fi
+	mycmakeargs+=(
+		# No clue about this option:
+		# option(enable-mgl2 "Use names 'libmgl2-*' instead of 'libmgl-*'")
+		-DMathGL_INSTALL_LIB_DIR="${EPREFIX}/usr/$(get_libdir)"
+		-Denable-all-docs=$(usex doc)
+		-Denable-fltk=$(usex fltk)
+		-Denable-gif=$(usex gif)
+		-Denable-glut=$(usex glut)
+		-Denable-gsl=$(usex gsl)
+		-Denable-hdf4=$(usex hdf)
+		-Denable-hdf5=$(usex hdf5)
+		-Denable-jpeg=$(usex jpeg)
+		-Denable-mpi=$(usex mpi)
+		-Denable-octave=$(usex octave)
+		-Denable-opengl=$(usex opengl)
+		-Denable-openmp=$(usex openmp)
+		-Denable-pdf=$(usex pdf)
+		-Denable-png=$(usex png)
+		-Denable-qt4=OFF
+		-Denable-qt5=$(usex qt5)
+		-Denable-qt5asqt=$(usex qt5)
+		-Denable-pthread=$(usex threads)
+		-Denable-pthr-widget=$(usex threads)
+		-Denable-python=OFF
+		-Denable-wx=$(usex wxwidgets)
+		-Denable-zlib=$(usex zlib)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	dodoc README* *.txt AUTHORS
+	if ! use static-libs; then
+		rm "${ED}"/usr/$(get_libdir)/*.a || die
+	fi
+	if use qt5 ; then
+		local lang
+		insinto /usr/share/udav
+		for lang in ${LANGS} ; do
+			use l10n_${lang} && doins udav/udav_${lang}.qm
+		done
+	fi
+	if use octave ; then
+		insinto /usr/share/${PN}/octave
+		doins "${CMAKE_BUILD_DIR}"/lang/${PN}.tar.gz
+	fi
+}
+
+pkg_postinst() {
+	if use octave; then
+		octave <<-EOF
+		pkg install ${EROOT}/usr/share/${PN}/octave/${PN}.tar.gz
+		EOF
+	fi
+}
+
+pkg_prerm() {
+	if use octave; then
+		octave <<-EOF
+		pkg uninstall ${PN}
+		EOF
+	fi
+}