gentoo resync : 28.04.2021

1 files changed, 54 insertions, 0 deletions

diff --git a/sci-libs/kissfft/kissfft-9999.ebuild b/sci-libs/kissfft/kissfft-9999.ebuild
new file mode 100644
index 000000000000..ad2bc1ff31a9
--- /dev/null
+++ b/sci-libs/kissfft/kissfft-9999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit cmake python-any-r1 toolchain-funcs
+
+DESCRIPTION="A Fast Fourier Transform (FFT) library that tries to Keep it Simple, Stupid"
+HOMEPAGE="https://github.com/mborgerding/kissfft"
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/mborgerding/kissfft"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/mborgerding/kissfft/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="alloca cpu_flags_x86_sse openmp test tools"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		sci-libs/fftw:3.0
+		$(python_gen_any_dep '
+			dev-python/numpy[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	has_version -d "dev-python/numpy[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DKISSFFT_OPENMP=$(usex openmp)
+		-DKISSFFT_TEST=$(usex test)
+		-DKISSFFT_TOOLS=$(usex tools)
+		-DKISSFFT_USE_ALLOCA=$(usex alloca)
+		-DKISSFFT_DATATYPE=$(usex cpu_flags_x86_sse simd float)
+	)
+
+	cmake_src_configure
+}