gentoo resync : 28.04.2021

2 files changed, 99 insertions, 0 deletions

diff --git a/sci-libs/dlib/Manifest b/sci-libs/dlib/Manifest
index 0e81c7b2895f..b6c4cf999ac9 100644
--- a/sci-libs/dlib/Manifest
+++ b/sci-libs/dlib/Manifest
@@ -1,3 +1,5 @@
 DIST dlib-19.16.tar.gz 10411975 BLAKE2B 93047590a4d8f4685970d3db6841cbf9cc90ca8a5e50f0929a106d887e5db1b4fd96bbe14380537a3e28369a8db6d9d8c067e7768000ac3c7d0f225b46369326 SHA512 4e040ef88acff05e1a48e499b813c876b22ad3f989d076bdf19969d01036b62e51a0dff30b70046910ba31dfa1b1c2450a7fad41ae3142b7285ed74b8d584887
+DIST dlib-19.22.tar.gz 10796236 BLAKE2B 5ca840536f61b38557d39ff6c24d9727f7c494e032d5abf912ccf83f724ecad61ce241126478eeed8b14e33b994af4065b1cfaf17a3b29cfa0dafc236e4c2a06 SHA512 49af41460de9aa270e47ee1d158231e87ffdbbf56ca29a3382dd896fcf81ef04729e59bd9c26eac63fb088cefce651149e5cdb0ffed73bfd6b05127887114d94
 EBUILD dlib-19.16-r1.ebuild 2841 BLAKE2B 0764d949505216763578cf8eb658f5486051b3206c796d43bcd13c89de303477c66c13f9052dc21d513e0a050f08044faebcfeb30c1a4602bf507722df137f21 SHA512 39a3b0c7c506f9f7eae79f1ef1b6098b1974f907230a623cd4533bdb73440345cb8235f764036daff646e2b9b544ba98978280a362558bd48095c23b96ad1f3e
+EBUILD dlib-19.22.ebuild 2408 BLAKE2B ea18c8f137dc925a5fdffbd728c346906bfccb703d597df09bd08cca29d1c655b3897a71557015336c4edfc2ea4bedc65f8c5134007df0ee7871d7a854eb3a67 SHA512 c7cedc466f3ac4af898c797f328c6c095d548c93f1c45be39c55bf326bb783317bbb3fd83bb57f11caae0ac1c51011fa16f0bb3b04a2ae9fe4b4b82313a2dcf9
 MISC metadata.xml 1002 BLAKE2B 899d622186d6ed4ab0c8c448bdbe312be12f0eeeec5e4d4ae031de4dcb26d73f0489b697375893d4c4bd16651c6b2d40ac156b67be0b376ec270d7d99a6f465a SHA512 1977d192107b78b97d5336d3e5b2e43a7ea12ede631a864ce14aeab2f9d328526f815fab0d62ae1417842cdfe9e1e7c0494fcf79be535dbfc4e3ca9342447b5c
diff --git a/sci-libs/dlib/dlib-19.22.ebuild b/sci-libs/dlib/dlib-19.22.ebuild
new file mode 100644
index 000000000000..04deb083df05
--- /dev/null
+++ b/sci-libs/dlib/dlib-19.22.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_OPTIONAL=1
+inherit cmake cuda distutils-r1
+
+DESCRIPTION="Numerical and networking C++ library"
+HOMEPAGE="http://dlib.net/"
+SRC_URI="https://github.com/davisking/dlib/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Boost-1.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cblas cuda debug examples gif jpeg lapack mkl png python sqlite test X cpu_flags_x86_avx cpu_flags_x86_sse2 cpu_flags_x86_sse4_1"
+REQUIRED_USE="python? ( png ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+# doc needs a bunch of deps not in portage
+RDEPEND="
+	cblas? ( virtual/cblas )
+	cuda? ( dev-libs/cudnn:= )
+	gif? ( media-libs/giflib:= )
+	jpeg? ( virtual/jpeg:0= )
+	lapack? ( virtual/lapack )
+	mkl? ( sci-libs/mkl )
+	png? ( media-libs/libpng:0= )
+	python? ( ${PYTHON_DEPS} )
+	sqlite? ( dev-db/sqlite:3 )
+	X? ( x11-libs/libX11 )"
+DEPEND="${RDEPEND}"
+BDEPEND="python? ( test? ( dev-python/pytest[${PYTHON_USEDEP}] ) )"
+
+DOCS=( docs/README.txt )
+
+src_prepare() {
+	use cuda && cuda_src_prepare
+	cmake_src_prepare
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDLIB_ENABLE_ASSERTS=$(usex debug)
+		-DDLIB_ENABLE_STACK_TRACE=$(usex debug)
+		-DDLIB_GIF_SUPPORT=$(usex gif)
+		-DDLIB_JPEG_SUPPORT=$(usex jpeg)
+		-DDLIB_PNG_SUPPORT=$(usex png)
+		-DDLIB_LINK_WITH_SQLITE3=$(usex sqlite)
+		-DDLIB_NO_GUI_SUPPORT=$(usex X OFF ON)
+		-DDLIB_USE_BLAS=$(usex cblas)
+		-DDLIB_USE_CUDA=$(usex cuda)
+		-DDLIB_USE_LAPACK=$(usex lapack)
+		-DUSE_AVX_INSTRUCTIONS=$(usex cpu_flags_x86_avx)
+		-DUSE_SSE2_INSTRUCTIONS=$(usex cpu_flags_x86_sse2)
+		-DUSE_SSE4_INSTRUCTIONS=$(usex cpu_flags_x86_sse4_1)
+	)
+	cmake_src_configure
+	use python && distutils-r1_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use python && distutils-r1_src_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+src_test() {
+	(
+		local BUILD_DIR="${BUILD_DIR}"/dlib/test
+		mkdir -p "${BUILD_DIR}" || die
+		cd "${BUILD_DIR}" >/dev/null || die
+
+		local CMAKE_USE_DIR="${S}"/dlib/test
+		cmake_src_configure
+		cmake_build
+
+		./dtest --runall || die "Tests failed"
+	)
+
+	use python && distutils-r1_src_test
+}
+
+src_install() {
+	cmake_src_install
+	use python && distutils-r1_src_install
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}
+	fi
+}