gentoo Easter resync : 12.04.2020

3 files changed, 125 insertions, 14 deletions

diff --git a/sci-astronomy/celestia/Manifest b/sci-astronomy/celestia/Manifest
index f0cbd70b3b67..f2ee61a13140 100644
--- a/sci-astronomy/celestia/Manifest
+++ b/sci-astronomy/celestia/Manifest
@@ -1,4 +1,6 @@
 AUX celestia-1.5.0-desktop.patch 1371 BLAKE2B f4964ea5794b6fa7eff49cb4d9879226e83739dfe877f055f1cbff25562f324e30af3ef4ee68897324504b06a6a6c84c2cee4caf78914792a4c89e54ed580b14 SHA512 937d3a733ec679ed4fb7644b2ae0bf780972dce7ac7d6e30dfbd7cad3e90354460a3e1c3df268514048e53979d22b1bdee70dd340f8c9977e7a0749c65a24bf7
 AUX celestia-1.6.99-cfg.patch 781 BLAKE2B 04ff4f7c5159eee81479ed588d302fa6a97475955af733e013fcafb2b37975fb1f2215afe61a715b5ec7716dbd75b5915dd4a5031255adb8fde5f6e64d9b71a5 SHA512 50cce63a701da85b52bee5db5b34eed77118c7c847612b4bc7ae82c80b198c718b4adbf0f21cc82e4afbafe20f53dda191285095d6ee5e796ce7f6c94388b832
-EBUILD celestia-9999.ebuild 2317 BLAKE2B 096a8110ee248bf732b7862a17f2f2ac30f780e295f67f6e30d2a4c5fc7d36196b53172a567c8860efa1d5d9241366eed07dda5e9b2b6316fbbcf25225cfde10 SHA512 933533e727691fe7c5fb6b969bd940babb206780b9c4675297f44d4d38c2313628e66a170b8af28785c7e8620b16ac67727e156ac7b3de4093df0ba2b4238e4e
+DIST celestia-1.7.0_pre20200316.tar.gz 69459012 BLAKE2B 8e718e8a4aa064b9be0bd5f0f1c034f3ffec42671c6eae503216f5ea2787e8c5da3315e3cb39e94e2a0eab5f067e189fe70dc9d04bff4127e9e39fba3a7117ae SHA512 db4213e1d76699ff01390f12e3763596dfd2641389743c27221b4e7934be9daca7a884dd389135894d225e8613830468ebede5664543e27e44e21e19d22d1e7f
+EBUILD celestia-1.7.0_pre20200316.ebuild 2484 BLAKE2B 2936f3c633deb89924193671236c2315e25f2323173604260f576c9955c753e804be913e3840c488178a0f0d1455b516dfe7610a8ea55a9f2114e812d2651ca8 SHA512 195b84de386a480d9513d5fc8d7657606dd499597caa85ab71ee894449a188eea8bdb653549c4c26ea47dd9924e3d0df8cbfc7663c3ebffb3e09775a1d64f368
+EBUILD celestia-9999.ebuild 2484 BLAKE2B 2936f3c633deb89924193671236c2315e25f2323173604260f576c9955c753e804be913e3840c488178a0f0d1455b516dfe7610a8ea55a9f2114e812d2651ca8 SHA512 195b84de386a480d9513d5fc8d7657606dd499597caa85ab71ee894449a188eea8bdb653549c4c26ea47dd9924e3d0df8cbfc7663c3ebffb3e09775a1d64f368
 MISC metadata.xml 892 BLAKE2B e5bc4a09a9e495bcecf9bc2f5e0c60e7aee0b7c65071ac1636416368a1fc9c49057a23127a964c0cbb9a42c6a679cfed5c8d0511c88c67808f5078cfb3ad04c0 SHA512 f222c4e816f2684d8d8de5d456e81b6f6a9b92f3d3996137ddd371a9934793beeda6d1611e8f510f35eafdbe83837007fbae897efcebd47a6bf00e8b3ae159f9
diff --git a/sci-astronomy/celestia/celestia-1.7.0_pre20200316.ebuild b/sci-astronomy/celestia/celestia-1.7.0_pre20200316.ebuild
new file mode 100644
index 000000000000..4ea492d2df57
--- /dev/null
+++ b/sci-astronomy/celestia/celestia-1.7.0_pre20200316.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop flag-o-matic xdg cmake
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/CelestiaProject/Celestia.git"
+	inherit git-r3
+else
+	if [[ ${PV} == *_p* ]] ; then
+		COMMIT_ID="df508a0c597a3d96c1c039fa4a973e294021cfba"
+		SRC_URI="https://github.com/${PN^}Project/${PN^}/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${PN^}-${COMMIT_ID}"
+		KEYWORDS="~amd64 ~x86"
+	else
+		SRC_URI="https://github.com/${PN^}Project/${PN^}/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+		KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+	fi
+fi
+
+DESCRIPTION="OpenGL 3D space simulator"
+HOMEPAGE="https://celestia.space"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="glut lua nls +qt5 theora"
+REQUIRED_USE="|| ( glut qt5 )"
+
+BDEPEND="
+	dev-cpp/eigen
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+DEPEND="
+	dev-libs/libfmt:=
+	media-libs/glew:0
+	media-libs/libpng:0=
+	sys-libs/zlib:=
+	virtual/glu
+	virtual/jpeg:0
+	virtual/opengl
+	glut? ( media-libs/freeglut )
+	lua? ( dev-lang/lua:* )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	# make better desktop files
+	"${FILESDIR}"/${PN}-1.5.0-desktop.patch
+	# add a ~/.celestia for extra directories
+	"${FILESDIR}"/${PN}-1.6.99-cfg.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	### This version of Celestia has a bug in the font rendering and
+	### requires -fsigned-char. We should be able to force this flag
+	### on all architectures. See bug #316573.
+	append-flags "-fsigned-char"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CELX="$(usex lua)"
+		-DENABLE_NLS="$(usex nls)"
+		-DENABLE_GLUT="$(usex glut)"
+		-DENABLE_GTK=OFF
+		-DENABLE_QT="$(usex qt5)"
+		-DENABLE_WIN=OFF
+		-DENABLE_THEORA="$(usex theora)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	local size
+	for size in 16 22 32 48 ; do
+		newicon -s ${size} "${S}"/src/celestia/kde/data/hi${size}-app-${PN}.png ${PN}.png
+	done
+	newicon -s 128 "${S}"/src/celestia/gtk/data/${PN}-logo.png ${PN}.png
+	doicon -s scalable "${S}"/src/celestia/gtk/data/${PN}.svg
+
+	use glut && domenu ${PN}.desktop
+	if use qt5 ; then
+		sed \
+			-e "/^Name/s@\$@ (qt5 interface)@" \
+			-e "/^Exec/s@${PN}@${PN}-qt@" \
+			${PN}.desktop > "${T}"/${PN}-qt5.desktop || die
+		domenu "${T}"/${PN}-qt5.desktop
+	fi
+	dodoc AUTHORS README TRANSLATORS *.txt
+}
diff --git a/sci-astronomy/celestia/celestia-9999.ebuild b/sci-astronomy/celestia/celestia-9999.ebuild
index fda29bea8547..4ea492d2df57 100644
--- a/sci-astronomy/celestia/celestia-9999.ebuild
+++ b/sci-astronomy/celestia/celestia-9999.ebuild
@@ -5,21 +5,27 @@ EAPI=7
 
 inherit desktop flag-o-matic xdg cmake
 
-if [[ "${PV}" = 9999 ]] ; then
-	inherit git-r3
+if [[ ${PV} == *9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/CelestiaProject/Celestia.git"
+	inherit git-r3
 else
-	SRC_URI="https://github.com/${PN^}Project/${PN^}/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+	if [[ ${PV} == *_p* ]] ; then
+		COMMIT_ID="df508a0c597a3d96c1c039fa4a973e294021cfba"
+		SRC_URI="https://github.com/${PN^}Project/${PN^}/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${PN^}-${COMMIT_ID}"
+		KEYWORDS="~amd64 ~x86"
+	else
+		SRC_URI="https://github.com/${PN^}Project/${PN^}/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+		KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+	fi
 fi
 
 DESCRIPTION="OpenGL 3D space simulator"
 HOMEPAGE="https://celestia.space"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
-IUSE="glut nls +qt5 theora"
-
+IUSE="glut lua nls +qt5 theora"
 REQUIRED_USE="|| ( glut qt5 )"
 
 BDEPEND="
@@ -28,14 +34,15 @@ BDEPEND="
 	nls? ( sys-devel/gettext )
 "
 DEPEND="
-	>=dev-lang/lua-5.1:*
 	dev-libs/libfmt:=
 	media-libs/glew:0
 	media-libs/libpng:0=
+	sys-libs/zlib:=
 	virtual/glu
 	virtual/jpeg:0
 	virtual/opengl
 	glut? ( media-libs/freeglut )
+	lua? ( dev-lang/lua:* )
 	qt5? (
 		dev-qt/qtcore:5
 		dev-qt/qtgui:5
@@ -58,8 +65,6 @@ PATCHES=(
 src_prepare() {
 	cmake_src_prepare
 
-	filter-flags "-funroll-loops -frerun-loop-opt"
-
 	### This version of Celestia has a bug in the font rendering and
 	### requires -fsigned-char. We should be able to force this flag
 	### on all architectures. See bug #316573.
@@ -67,10 +72,8 @@ src_prepare() {
 }
 
 src_configure() {
-	# force lua. Seems still to be inevitable
 	local mycmakeargs=(
-		#-DENABLE_CELX="$(usex lua)"
-		-DENABLE_CELX=ON
+		-DENABLE_CELX="$(usex lua)"
 		-DENABLE_NLS="$(usex nls)"
 		-DENABLE_GLUT="$(usex glut)"
 		-DENABLE_GTK=OFF