gentoo resync : 12.05.2022

3 files changed, 141 insertions, 4 deletions

diff --git a/net-wireless/uhd/Manifest b/net-wireless/uhd/Manifest
index a4606de7ccb7..fe15032683c7 100644
--- a/net-wireless/uhd/Manifest
+++ b/net-wireless/uhd/Manifest
@@ -1,5 +1,8 @@
 AUX uhd-4.1.0.5-hidden-visibility-tests.patch 870 BLAKE2B 97c7e1c477d57f32cd1ed8a4c96de5761f422719783c1da247c3d00a1ddf51087484b95daa57fd3a4a417c6227a5fe2de2d7d3637575a7a5cab83a243ae270bf SHA512 017ce990463d332a5a67853dcf6362063935b10af67083c88385ef5659694e3af765349b89663b9e0f95ccd11da43f690feddbf71faa7ddcc109344c41c9dd6c
 DIST EttusResearch-UHD-4.1.0.5.tar.gz 37975618 BLAKE2B ff5b38be7ef7088168f2bf8908e59e74d2f492a860dac6b7fef48abd5d25840435a57b3ef980ceb7416efd1d3520a3f83bace3bc5bca5caaecc14088e9609fcd SHA512 4929ebc8a12bcc0acfe4a64ceafe17387420e2f056e7bb7284a8d7b60d14aba05484b3c033ce63b00c6d9115f570b056df4e2b36e11a2b25079a8c34b1d084af
+DIST EttusResearch-UHD-4.2.0.0.tar.gz 38124395 BLAKE2B cbb149e6f6aaff628e40463b37b3e52ee758acaaf8e86f85586a70fb4d9744408fb2c807a491b91de64a8cb23adb566722eece99eb8bd844e704d5412372b2ec SHA512 a5f105a8765a06e53bed17dee760dfa985d40a97c61ca243127c8a912378d6f5ae81170a48e8e5f92a238bcfd66742798043b3fb0119e574dbac74291f15ec9c
 DIST uhd-images_4.1.0.5.tar.xz 118480128 BLAKE2B 90803ca0a7452e601481837d006dbaf0eab57070d4fccfd0576a7a7736c11fa62caf9ea141be807a5c4d65ba2bb0f7a5361833ff2afb9f732f231b2bb659f08e SHA512 fa9ca49bc917e55a1505acce090dc6b06cac6c59fbe7a78c2c47f79783fab52baf9563903715da205762962485c8b4a83292a171a33e7c247b0eeb35819aff5c
-EBUILD uhd-4.1.0.5.ebuild 3582 BLAKE2B 2ba95c7c53ecedd0d02be1b0d848b18c51f436de93133c43cbb4338f1f37e6b638843649ca1e4eb33a8715716aed8c7ec4689403c457b980b5119010a176d944 SHA512 5fcedf9d592b63a87df4244abb28f8cb5e6f5da1fbf8e1fa85a2e737fa4263840687636f702df97efd13899a93d779d5fded916a45cb9e6398db93b6ee36e358
+DIST uhd-images_4.2.0.0.tar.xz 127034940 BLAKE2B ab186ad83fe607c745a56862363a8cc0566450bffc90f070714b07124f1172d09a823fa7b74c7b7cd0fe42cd00d1f0178ed63b07a7959fd59ea5cde071c639fd SHA512 b3cee57b63137e074d370eed3d1c1533627a85cd3937103721d2f4ee322c6725a38be62cd737891193fa2b4c32f32cff372fadf4f75cb3cec3f9085cdc889c8f
+EBUILD uhd-4.1.0.5.ebuild 3566 BLAKE2B 45dc4989480875a6ebdc3afd3fdc955af2cb48cf44f80dfd45289d2404a1bea6b3d7993e4976809e0a0306080acccdb79b730fffe05fd77af94b479e970a38c7 SHA512 ff76a249133c92c8365ad9ea299c2a7fa935519cd0125b4389549eff522face5aaee660d59f127e4c11586d6f80231236f96921d1e091e96dbcc57b18165f019
+EBUILD uhd-4.2.0.0.ebuild 3435 BLAKE2B e69ade2b09003b2c446b455764d72689992e21f2d44cfb59f6ab527dd25b6f2f00c9f94548d5246f705a0a06133fa42b33ecff90942f53e999a00815b52a8b39 SHA512 9d0df399c441a769ba14deaf7295456405742f141f248221835f6a2bdf0d10787dc2c3c5d49b28c87d78e5f080615a3c67cd07b7cea7f62851d2855d3f88df16
 MISC metadata.xml 1160 BLAKE2B 0bcd5e0ea7008a4847cd0ec47e900eaad894c1b37f9917197ed408edb6525f3526fce2086fa318d66f9fe3a355a8a3d5b92dcdffd2518439fb4813f9cdec5b8a SHA512 b53864ec397c266c6c914c9d7bf44eb30187585fac7d5c871b54e91e7909186c756bcd49850343a28093e77148b506bbab5583834a0a125cefe9280c2e324c4d
diff --git a/net-wireless/uhd/uhd-4.1.0.5.ebuild b/net-wireless/uhd/uhd-4.1.0.5.ebuild
index 6d285be59c72..f77c3fbc8a83 100644
--- a/net-wireless/uhd/uhd-4.1.0.5.ebuild
+++ b/net-wireless/uhd/uhd-4.1.0.5.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 PYTHON_COMPAT=( python3_{8,9,10} )
 
-inherit cmake gnome2-utils python-single-r1
+inherit cmake gnome2-utils python-single-r1 udev
 
 DESCRIPTION="Universal Software Radio Peripheral (USRP) Hardware Driver"
 HOMEPAGE="https://kb.ettus.com"
@@ -103,8 +103,7 @@ src_install() {
 		rm -r "${ED}/usr/share/man/man1/uhd_images_downloader.1" || die
 	fi
 
-	insinto /lib/udev/rules.d/
-	doins "${S}/utils/uhd-usrp.rules"
+	udev_dorules "${S}/utils/uhd-usrp.rules"
 
 	rm -r "${WORKDIR}/images/winusb_driver" || die
 	if ! use b100; then
diff --git a/net-wireless/uhd/uhd-4.2.0.0.ebuild b/net-wireless/uhd/uhd-4.2.0.0.ebuild
new file mode 100644
index 000000000000..cc43f7cef743
--- /dev/null
+++ b/net-wireless/uhd/uhd-4.2.0.0.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit cmake gnome2-utils python-single-r1 udev
+
+DESCRIPTION="Universal Software Radio Peripheral (USRP) Hardware Driver"
+HOMEPAGE="https://kb.ettus.com"
+
+SRC_URI="https://github.com/EttusResearch/uhd/archive/v${PV}.tar.gz -> EttusResearch-UHD-${PV}.tar.gz \
+	https://github.com/EttusResearch/uhd/releases/download/v${PV}/uhd-images_${PV}.tar.xz"
+#https://github.com/EttusResearch/UHD-Mirror/tags
+#http://files.ettus.com/binaries/images/
+
+LICENSE="GPL-3"
+SLOT="0/$(ver_cut 1-3)"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+IUSE="+b100 +b200 doc e300 examples +mpmd octoclock +n230 test +usb +usrp1 +usrp2 +utils +x300"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+			b100? ( usb )
+			b200? ( usb )
+			usrp1? ( usb )
+			usrp2? ( usb )
+			|| ( b100 b200 e300 mpmd n230 usrp1 usrp2 x300 )"
+
+RDEPEND="${PYTHON_DEPS}
+	e300? ( virtual/udev )
+	usb? ( virtual/libusb:1 )
+	dev-libs/boost:=
+	sys-libs/ncurses:0=
+	$(python_gen_cond_dep '
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+#zip an gzip are directly used by the build system
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	$(python_gen_cond_dep '
+	dev-python/mako[${PYTHON_USEDEP}]
+	')
+	app-arch/unzip
+	app-arch/gzip
+"
+
+S="${WORKDIR}/${P}/host"
+
+src_unpack() {
+	default
+	mv "uhd-images_${PV}" images || die
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	gnome2_environment_reset #534582
+}
+
+src_configure() {
+	#https://gitlab.kitware.com/cmake/cmake/-/issues/23236
+	#https://github.com/EttusResearch/uhd/pull/560
+	local mycmakeargs=(
+		-DCURSES_NEED_NCURSES=ON
+		-DENABLE_LIBUHD=ON
+		-DENABLE_C_API=ON
+		-DENABLE_MAN_PAGES=ON
+		-DENABLE_MAN_PAGE_COMPRESSION=OFF
+		-DENABLE_EXAMPLES="$(usex examples)"
+		-DENABLE_TESTS="$(usex test)"
+		-DENABLE_USB="$(usex usb)"
+		-DENABLE_UTILS="$(usex utils)"
+		-DENABLE_MANUAL="$(usex doc)"
+		-DENABLE_DOXYGEN="$(usex doc)"
+		-DENABLE_B100="$(usex b100)"
+		-DENABLE_B200="$(usex b200)"
+		-DENABLE_E300="$(usex e300)"
+		-DENABLE_USRP1="$(usex usrp1)"
+		-DENABLE_USRP2="$(usex usrp2)"
+		-DENABLE_X300="$(usex x300)"
+		-DENABLE_MPMD="$(usex mpmd)"
+		-DENABLE_OCTOCLOCK="$(usex octoclock)"
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DPKG_DOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_optimize
+	use utils && python_fix_shebang "${ED}"/usr/$(get_libdir)/${PN}/utils/
+	if [[ "${PV}" != "9999" ]]; then
+		rm -r "${ED}/usr/bin/uhd_images_downloader" || die
+	fi
+
+	udev_dorules "${S}/utils/uhd-usrp.rules"
+
+	rm -r "${WORKDIR}/images/winusb_driver" || die
+	if ! use b100; then
+		rm "${WORKDIR}"/images/usrp_b100* || die
+	fi
+	if ! use b200; then
+		rm "${WORKDIR}"/images/usrp_b2[01]* || die
+	fi
+	if ! use e300; then
+		rm "${WORKDIR}"/images/usrp_e3* || die
+	fi
+	if ! use mpmd; then
+		rm "${WORKDIR}"/images/usrp_n310* || die
+	fi
+	if ! use n230; then
+		rm "${WORKDIR}"/images/usrp_n230* || die
+	fi
+	if ! use octoclock; then
+		rm "${WORKDIR}"/images/octoclock* || die
+	fi
+	if ! use usrp1; then
+		rm "${WORKDIR}"/images/usrp1* || die
+	fi
+	if ! use usrp2; then
+		rm "${WORKDIR}"/images/usrp2* || die
+		rm "${WORKDIR}"/images/usrp_n2[01]* || die
+		rm -r "${WORKDIR}"/images/bit || die
+	fi
+	if ! use x300; then
+		rm "${WORKDIR}/"images/usrp_x3* || die
+	fi
+	insinto /usr/share/${PN}
+	doins -r "${WORKDIR}/images"
+}