gentoo resync : 30.06.2018

2 files changed, 246 insertions, 0 deletions

diff --git a/net-wireless/gnuradio/Manifest b/net-wireless/gnuradio/Manifest
index 8171dcec2070..45a1ec906ac8 100644
--- a/net-wireless/gnuradio/Manifest
+++ b/net-wireless/gnuradio/Manifest
@@ -2,8 +2,11 @@ AUX gnuradio-3.6.1-automagic-audio.patch 2839 BLAKE2B 5b7e2e224ef2dcc9d0645a0faf
 AUX gnuradio-wxpy3.0-compat.patch 2202 BLAKE2B 2efeb291e109c6251356bbe6bae93abaff9766984d141f2d9c0a180af4c0ccbc5de6cc0d07c0c7965ac48967ed7e4a5d576713c77fa98a31a12c0b4404987561 SHA512 6d06c76394954eb63784ef6edca06a8611f59c3bea0355c7a0623a56054d0466d83770ce4afd9d9be484543c3859d20209c858506f3d789a3818d549df95de3f
 DIST gnuradio-3.6.5.1.tar.gz 3150283 BLAKE2B f04121aab9a1b4c5424b5396c96269a53dd6302bf42e5a443b99ea642c8db8ed32df843a89ffe49869212cd2325b209407b5407dbd9b7730510c4ee42bd95836 SHA512 23a22aed482da11005b17e5197ee3ba24d442b30309522b0858e694b58f46b76cc050143d365623c7dd4241cdf8b9f988e1a4dabe2e1f98d0fd4cca71bbb82e8
 DIST gnuradio-3.7.11.tar.gz 4357123 BLAKE2B ae43e9f7e20605de484c4dc31bc33b9b99e5fba269d8d394e9053f4451083b2d6048c1d1fe19a774c0cc686c13e758f0b6e719cf15d05c5867e2ac1c4eecf789 SHA512 a3b44e04e63056ad5238ddbda7967ebaf5802d2ed7e24649190bde67a533b50780ec1260dc7710c5388c966b71e153d3d21468bbfee4529c62ac5b89b589dd14
+DIST gnuradio-3.7.12-qt5.tar.xz 31048 BLAKE2B 5665ecd7f5ab34852a0e2dc975c483331e7b547377adf8a4c38ab68a6e034d6ec9f009210f74bbf9a0fc76e214bd744558b267e853843f33f799bbf0a0f2a7fc SHA512 25da9415d7b7f9984075c2a8fcf092bc0585be550c0b9a7e6910d934fd3aab4be3135d7a2c83b01ce19b2ac8e0065ffb5ad1375fa29cc259d4dc2d1d92003f99
+DIST gnuradio-3.7.13.3.tar.gz 4544605 BLAKE2B f059e8af860b7c18573f0efa909f3bf2b36b4d7208e26dd18a1c9de8cbf40e0d9079336f4a5f48430790e28dc21f5150ad2294fa1d664889c07e849d236160a0 SHA512 e4bf63899678fd792bc08baa2db673b192dc823d6e586124538cbdf12e60a882847e72cfca7f52ef906d52038a9cb48a8b5891593c9db1cb172c4077a54d4056
 EBUILD gnuradio-3.6.5.1-r2.ebuild 5339 BLAKE2B 6e54dbf3381eed4556a52c1536ca36def8f724da6375140b06ddda7549c857d65ad029aa774326ab587edc82a0a804e009a72a6d12214bdfcacd2101608278ca SHA512 e632918a4543ea97158dd205548310bf268b295a69bbc288d1129c076c982b2bb87784ea7b519c0fa6a4fc7852cef2adbc444b68099a98929862105ea2351c7c
 EBUILD gnuradio-3.7.11-r3.ebuild 7029 BLAKE2B 3d38a4b4288ef2d5d12a7433ee2ec2bffbc2a5cfe6cd70eee57c3eaf701122712d618490a2b460d2110a283e81085c1c2a7ddb40fd7ef73f6045b5d7211fe36f SHA512 647158607c8137ffd4a09344da964d22b9b800d5fb10c63451548292f6e3a8d173dee9d140cd2e7405af06819bd9b136e9dfdca33971c16f7a97297391a6b98b
+EBUILD gnuradio-3.7.13.3.ebuild 6785 BLAKE2B 2038f1ce0bcffd0c44e1f2224b618103ea797c6423dcdc23b819da53bc6061673975165713296f4d18650771e9a44fb3b8ce102851d349fbfc75c1a4fe631351 SHA512 4c8317d911c7c0643e7f977f83696e8e3b939d9737cfdde5864779e05248ed58863dd81ba9a6eb80c10db4b023b1118d25705efd4a77d2585d839acfc1a97993
 EBUILD gnuradio-3.7.9999.ebuild 7105 BLAKE2B 665ec0e3792d8543ae75134f8b475f17cbb534658220265248453c9c00351bbbb6029831b530a95fbf10ebe9ef9e3f3bd08c89d50890dfaf0cd5dea62177aecc SHA512 3d950e8f53160c2e33df4c43eeef9f0050cb53448f4dd92d4b0027a4c36d2dc48feee8f602a281e81fc86e5d37e5b0387e70a8cff7b692449422f1992ab51b0c
 EBUILD gnuradio-3.8.9999.ebuild 6654 BLAKE2B 2ecf927d0469ecd721e929ba77db619949cac4e11f2a4ee62e292cbcc6ac5c0969d8eae1d01b52f67756e6cc5165cadde94b7907658c950e181dff0107d893d6 SHA512 3a839947f80f483dc6e78b9b453c1f455c4be58a7a67cbf2b116bba7f2364c53485c6695bb236704ff5286fc28310fa8324b6a428b7d55105b393087069e340e
 EBUILD gnuradio-9999.ebuild 7105 BLAKE2B 665ec0e3792d8543ae75134f8b475f17cbb534658220265248453c9c00351bbbb6029831b530a95fbf10ebe9ef9e3f3bd08c89d50890dfaf0cd5dea62177aecc SHA512 3d950e8f53160c2e33df4c43eeef9f0050cb53448f4dd92d4b0027a4c36d2dc48feee8f602a281e81fc86e5d37e5b0387e70a8cff7b692449422f1992ab51b0c
diff --git a/net-wireless/gnuradio/gnuradio-3.7.13.3.ebuild b/net-wireless/gnuradio/gnuradio-3.7.13.3.ebuild
new file mode 100644
index 000000000000..469c004b33d6
--- /dev/null
+++ b/net-wireless/gnuradio/gnuradio-3.7.13.3.ebuild
@@ -0,0 +1,243 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+CMAKE_BUILD_TYPE="None"
+inherit cmake-utils eutils gnome2-utils python-single-r1 python-utils-r1 xdg-utils
+
+DESCRIPTION="Toolkit that provides signal processing blocks to implement software radios"
+HOMEPAGE="https://www.gnuradio.org/"
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+
+if [[ ${PV} =~ "9999" ]]; then
+	EGIT_REPO_URI="https://www.gnuradio.org/cgit/gnuradio.git"
+	inherit git-r3
+	KEYWORDS=""
+else
+	SRC_URI="https://www.gnuradio.org/releases/gnuradio/${P}.tar.gz
+			https://dev.gentoo.org/~zerochaos/patches/${PN}-3.7.12-qt5.tar.xz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+if [[ ${PV} == "3.7.9999" ]]; then
+	EGIT_BRANCH="maint"
+elif [[ ${PV} == "3.8.9999" ]]; then
+	EGIT_BRANCH="next"
+fi
+
+IUSE="+audio +alsa atsc +analog +digital channels doc dtv examples fcd fec +filter grc jack log noaa oss pager performance-counters portaudio +qt5 sdl test trellis uhd vocoder +utils wavelet wxwidgets zeromq"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+		audio? ( || ( alsa oss jack portaudio ) )
+		alsa? ( audio )
+		oss? ( audio )
+		jack? ( audio )
+		portaudio? ( audio )
+		analog? ( filter )
+		digital? ( filter analog )
+		dtv? ( fec )
+		pager? ( filter analog )
+		qt5? ( filter )
+		uhd? ( filter analog )
+		fcd? ( || ( alsa oss ) )
+		wavelet? ( analog )
+		wxwidgets? ( filter analog )"
+
+# bug #348206
+# comedi? ( >=sci-electronics/comedilib-0.8 )
+# boost-1.52.0 is blacklisted, bug #461578, upstream #513, boost #7669
+RDEPEND="${PYTHON_DEPS}
+	>=dev-lang/orc-0.4.12
+	dev-libs/boost:0=[${PYTHON_USEDEP}]
+	!<=dev-libs/boost-1.52.0-r6:0/1.52
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	sci-libs/fftw:3.0=
+	alsa? (
+		media-libs/alsa-lib:=
+	)
+	fcd? ( virtual/libusb:1 )
+	filter? ( sci-libs/scipy )
+	grc? (
+		dev-python/pygobject:*[cairo(+),${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/mako[${PYTHON_USEDEP}]
+	)
+	jack? (
+		media-sound/jack-audio-connection-kit
+	)
+	log? ( dev-libs/log4cpp )
+	portaudio? (
+		>=media-libs/portaudio-19_pre
+	)
+	qt5? (
+		dev-python/PyQt5[opengl,${PYTHON_USEDEP}]
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		x11-libs/qwt:6[qt5(+)]
+		dev-qt/qtwidgets:5
+	)
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	uhd? ( >=net-wireless/uhd-3.9.6:=[${PYTHON_USEDEP}] )
+	utils? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+	vocoder? ( media-sound/gsm )
+	wavelet? (
+		>=sci-libs/gsl-1.10
+	)
+	zeromq? ( >=net-libs/zeromq-2.1.11 )
+	"
+
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.2
+	>=dev-lang/swig-3.0.5
+	virtual/pkgconfig
+	doc? (
+		>=app-doc/doxygen-1.5.7.1
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	grc? ( x11-misc/xdg-utils )
+	oss? ( virtual/os-headers )
+	test? ( >=dev-util/cppunit-1.9.14 )
+	zeromq? ( net-libs/cppzmq )
+"
+
+src_prepare() {
+	gnome2_environment_reset #534582
+
+	if [[ ${PV} == "3.8.9999" ]]; then
+		true
+	else
+		epatch "${FILESDIR}"/gnuradio-wxpy3.0-compat.patch
+	fi
+	# Useless UI element would require qt3support, bug #365019
+	sed -i '/qPixmapFromMimeSource/d' "${S}"/gr-qtgui/lib/spectrumdisplayform.ui || die
+	epatch "${WORKDIR}"/qt5-maint-00*.patch
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	python_export PYTHON_SITEDIR
+	mycmakeargs=(
+		-DENABLE_DEFAULT=OFF
+		-DENABLE_GNURADIO_RUNTIME=ON
+		-DENABLE_VOLK=ON
+		-DENABLE_PYTHON=ON
+		-DENABLE_GR_BLOCKS=ON
+		-DENABLE_GR_FFT=ON
+		-DENABLE_GR_AUDIO=ON
+		-DENABLE_GR_AUDIO_ALSA="$(usex alsa)"
+		-DENABLE_GR_ANALOG="$(usex analog)"
+		-DENABLE_GR_ATSC="$(usex atsc)"
+		-DENABLE_GR_CHANNELS="$(usex channels)"
+		-DENABLE_GR_DIGITAL="$(usex digital)"
+		-DENABLE_DOXYGEN="$(usex doc)"
+		-DENABLE_SPHINX="$(usex doc)"
+		-DENABLE_GR_DTV="$(usex dtv)"
+		-DENABLE_GR_FCD="$(usex fcd)"
+		-DENABLE_GR_FEC="$(usex fec)"
+		-DENABLE_GR_FILTER="$(usex filter)"
+		-DENABLE_GRC="$(usex grc)"
+		-DENABLE_GR_AUDIO_JACK="$(usex jack)"
+		-DENABLE_GR_LOG="$(usex log)"
+		-DENABLE_GR_NOAA="$(usex noaa)"
+		-DENABLE_GR_AUDIO_OSS="$(usex oss)"
+		-DENABLE_GR_PAGER="$(usex pager)"
+		-DENABLE_ENABLE_PERFORMANCE_COUNTERS="$(usex performance-counters)"
+		-DENABLE_GR_AUDIO_PORTAUDIO="$(usex portaudio)"
+		-DENABLE_TESTING="$(usex test)"
+		-DENABLE_GR_TRELLIS="$(usex trellis)"
+		-DENABLE_GR_UHD="$(usex uhd)"
+		-DENABLE_GR_UTILS="$(usex utils)"
+		-DENABLE_GR_VOCODER="$(usex vocoder)"
+		-DENABLE_GR_WAVELET="$(usex wavelet)"
+		-DENABLE_GR_QTGUI="$(usex qt5)"
+		-DDESIRED_QT_VERSION="$(usex qt5 5)"
+		-DENABLE_GR_VIDEO_SDL="$(usex sdl)"
+		-DENABLE_GR_ZEROMQ="$(usex zeromq)"
+		-DENABLE_GR_CORE=ON
+		-DSYSCONFDIR="${EPREFIX}"/etc
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DGR_PYTHON_DIR="${PYTHON_SITEDIR}"
+		-DGR_PKG_DOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+	)
+	use vocoder && mycmakeargs+=( -DGR_USE_SYSTEM_LIBGSM=TRUE )
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use examples ; then
+		dodir /usr/share/doc/${PF}/
+		mv "${ED}"/usr/share/${PN}/examples "${ED}"/usr/share/doc/${PF}/ || die
+		docompress -x /usr/share/doc/${PF}/examples
+	else
+	# It seems that the examples are always installed
+		rm -rf "${ED}"/usr/share/${PN}/examples || die
+	fi
+
+	if use doc || use examples; then
+		#this doesn't appear useful
+		rm -rf "${ED}"/usr/share/doc/${PF}/xml || die
+	fi
+
+	# We install the mimetypes to the correct locations from the ebuild
+	rm -rf "${ED}"/usr/share/${PN}/grc/freedesktop || die
+	rm -f "${ED}"/usr/libexec/${PN}/grc_setup_freedesktop || die
+
+	# Install icons, menu items and mime-types for GRC
+	if use grc ; then
+		local fd_path="${S}/grc/scripts/freedesktop"
+		insinto /usr/share/mime/packages
+		doins "${fd_path}/${PN}-grc.xml"
+
+		domenu "${fd_path}/"*.desktop
+		doicon "${fd_path}/"*.png
+	fi
+
+	python_fix_shebang "${ED}"
+}
+
+src_test()
+{
+	ctest -E qtgui
+}
+
+pkg_postinst()
+{
+	local GRC_ICON_SIZES="32 48 64 128 256"
+
+	if use grc ; then
+		xdg_desktop_database_update
+		xdg_mime_database_update
+		for size in ${GRC_ICON_SIZES} ; do
+			xdg-icon-resource install --noupdate --context mimetypes --size ${size} \
+				"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" application-gnuradio-grc \
+				|| die "icon resource installation failed"
+			xdg-icon-resource install --noupdate --context apps --size ${size} \
+				"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" gnuradio-grc \
+				|| die "icon resource installation failed"
+		done
+		xdg-icon-resource forceupdate
+	fi
+}
+
+pkg_postrm()
+{
+	local GRC_ICON_SIZES="32 48 64 128 256"
+
+	if use grc ; then
+		xdg_desktop_database_update
+		xdg_mime_database_update
+		for size in ${GRC_ICON_SIZES} ; do
+			xdg-icon-resource uninstall --noupdate --context mimetypes --size ${size} \
+				application-gnuradio-grc || ewarn "icon uninstall failed"
+			xdg-icon-resource uninstall --noupdate --context apps --size ${size} \
+				gnuradio-grc || ewarn "icon uninstall failed"
+
+		done
+		xdg-icon-resource forceupdate
+	fi
+}