gentoo auto-resync : 25:10:2024 - 04:04:26

3 files changed, 199 insertions, 0 deletions

diff --git a/net-vpn/Manifest.gz b/net-vpn/Manifest.gz
index a3b95fae7158..526bdfd83416 100644
--- a/net-vpn/Manifest.gz
+++ b/net-vpn/Manifest.gz
diff --git a/net-vpn/tor/Manifest b/net-vpn/tor/Manifest
index 1ab08c40d3cd..e4267cd86ce2 100644
--- a/net-vpn/tor/Manifest
+++ b/net-vpn/tor/Manifest
@@ -10,7 +10,11 @@ DIST tor-0.4.8.11.tar.gz.sha256sum.asc 1321 BLAKE2B fbb12fbef8ef2c33a0a1c40eefb7
 DIST tor-0.4.8.12.tar.gz 9687430 BLAKE2B adaf1f90c698ee373d7ef93c77e883b76a2d75932a50b2bf7a4f5a2d387f3f8cc00d83860ed61e1e2c1d224680d07828137cf4805adb9975d9cc7218c493d19d SHA512 54b3b5d68d54a6143fa48339057d6d07bf93505a124fcdef3c374d1dc2d34055a1ebb3b1a97c814089d5671d1533a0e5941251604f3122032a0decad2ecec965
 DIST tor-0.4.8.12.tar.gz.sha256sum 86 BLAKE2B 9c813a64ebadcba84e8578f037795ba025cc2bd5c9c4fb8ad5478035c4d70fde8d8052417f60fc065a35334683daa5a868929ac15657874126873be20fd82a2f SHA512 975605066114a71120f9c79a62db9078247ea93d42629a048d7575d1d7088d91ef032309bfb9654b28b36f9197107e1cf0acd8f245a67534c7de825217616de5
 DIST tor-0.4.8.12.tar.gz.sha256sum.asc 716 BLAKE2B 8c92a7de4e0e4cab15df534c34d36b03efa052af844bc956f946a45e5ad9ed0260a6e1f1dfc6b8a2be858d7c1e31fffccc404716e52b763663fbc3fb2266966b SHA512 ba13f5cce4844bdb14860cf689f5281a7d3c8fa968fdf1f2c6161797716f0736a5ab6472e9363438233f212120a60a2a7293fcdffe307d057089526132a1204f
+DIST tor-0.4.8.13.tar.gz 9912610 BLAKE2B b55b29b5b2d4aa391f8d9d22657833647064af354ac8b6751ddc096fa30d0b43399851d11b0e8a41c7537aa134b61aa65c9b94f2a1854eea7c01a2bfa63f1110 SHA512 7a095931ed709333a512535212048360d9d90907c3c71a8c6dc55fd52ccf515aa42c7ec6e18c7fb5fde7f5e1b1da1753f1380a274743b6420ac49ed1a3bb1a0c
+DIST tor-0.4.8.13.tar.gz.sha256sum 86 BLAKE2B 8e2fce0973e9798c3396fc4c070afe5d4ecf42368aa35e7ee13737c7a0b1c6a45c628605ec1879c9c923380bfb1b9d401b2527cf5bb3768630ac526b22d0be18 SHA512 b059030226b70224c10dabb3517c1d33419d138505b2f339f3a921844e921bed0056a4836559789d74b10fe552897c12716d956dae46474634bb814ab19211f0
+DIST tor-0.4.8.13.tar.gz.sha256sum.asc 716 BLAKE2B 8f708838cc4b642168b689e9ce9bd8daca513db308d86a4d0193edaee8ad47cb52bb0b5af9236da302b9cce542f2dd52a5c86130cd30b5320560e58b7f71fb9c SHA512 879ee66396cd1a751980686c79b03cf85ae19828255b0e0058540d72d0d365aa82778f009824cab310403bda98c968fac956905a9cb8f6877b960897e0476dd0
 EBUILD tor-0.4.8.11.ebuild 4557 BLAKE2B 3ed5bdb4eb425f1061da8f4cacdfe5cbc4ffc3a2631196cafa55ae6056cb59616336dd828aae1bbf64c8375cf96bdc14a17f77ce7fe7afb20451bf0cc116e86d SHA512 5818afd4c2ba7a39be1615bfd5feefc62e43770bb81f86652aa9f471d7732225523e5bb56c9ed1bb3410bf34eeedba3faa5ac65773e28ec49aa90acc85fb3746
 EBUILD tor-0.4.8.12-r1.ebuild 4713 BLAKE2B 1320cc00cab15b86d63645ca2ef80d224346e02eae654cc84a1ab3d939f06ea4a603a06a8f9f1217be81908cc52d3951c8378f7b724ae1535aff3a2fbdf369ec SHA512 96ca832249cadf1af659237b73cc714c989189fe337189632e970f57fbe0cb520a163881cd74eba17bd3a07e138dea94fe8cea70ae4c181cce4f26a883f1e028
+EBUILD tor-0.4.8.13.ebuild 4719 BLAKE2B 71096a316d1c79d193ab7af927996c2007009eb6d035a43751eaec1c8a35ca9bce7cea0880d61d840c4528ef95ab3e5db8acb1735f8de33114c14d6d2268d432 SHA512 e1f59d2889fe7f8db9495a5c3debe1fe48281336a474e757391a56ddffc530ee2a30672b3cfe0f7aaceb8477cc8b3e6e311327ec14d7620bf94c6cc19b2e85b3
 EBUILD tor-9999.ebuild 4719 BLAKE2B 71096a316d1c79d193ab7af927996c2007009eb6d035a43751eaec1c8a35ca9bce7cea0880d61d840c4528ef95ab3e5db8acb1735f8de33114c14d6d2268d432 SHA512 e1f59d2889fe7f8db9495a5c3debe1fe48281336a474e757391a56ddffc530ee2a30672b3cfe0f7aaceb8477cc8b3e6e311327ec14d7620bf94c6cc19b2e85b3
 MISC metadata.xml 645 BLAKE2B a7f450c6cfb9a605f7021cbe533ec64ff0926c9877bef7aace8ce1770a8ec552255b5c54ac80035646c3515d7d0b778100573897068d0905a56f7b860c8de21b SHA512 e5724033912b73ab8abe1b47e74578c8fe4bf6e341b8e7d7434d69071508cd1f35d97f4c7ade9787ae0ded6660cf0a5477d3c7462ed13832693bfd6205f0f0f1
diff --git a/net-vpn/tor/tor-0.4.8.13.ebuild b/net-vpn/tor/tor-0.4.8.13.ebuild
new file mode 100644
index 000000000000..22759b502bcd
--- /dev/null
+++ b/net-vpn/tor/tor-0.4.8.13.ebuild
@@ -0,0 +1,195 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/torproject.org.asc
+inherit edo python-any-r1 readme.gentoo-r1 systemd verify-sig
+
+MY_PV="$(ver_rs 4 -)"
+MY_PF="${PN}-${MY_PV}"
+DESCRIPTION="Anonymizing overlay network for TCP"
+HOMEPAGE="https://www.torproject.org/ https://gitlab.torproject.org/tpo/core/tor/"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://gitlab.torproject.org/tpo/core/tor"
+	inherit autotools git-r3
+else
+	SRC_URI="
+		https://www.torproject.org/dist/${MY_PF}.tar.gz
+		https://archive.torproject.org/tor-package-archive/${MY_PF}.tar.gz
+		verify-sig? (
+			https://dist.torproject.org/${MY_PF}.tar.gz.sha256sum
+			https://dist.torproject.org/${MY_PF}.tar.gz.sha256sum.asc
+		)
+	"
+
+	S="${WORKDIR}/${MY_PF}"
+
+	if [[ ${PV} != *_alpha* && ${PV} != *_beta* && ${PV} != *_rc* ]]; then
+		KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~ppc-macos"
+	fi
+
+	BDEPEND="verify-sig? ( >=sec-keys/openpgp-keys-tor-20230727 )"
+fi
+
+# BSD in general, but for PoW, needs --enable-gpl (GPL-3 per --version)
+# We also already had GPL-2 listed here for the init script, but obviously
+# that's different from the actual binary.
+LICENSE="BSD GPL-2 GPL-3"
+SLOT="0"
+IUSE="caps doc lzma +man scrypt seccomp selinux +server systemd tor-hardening test zstd"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-user/tor
+	acct-group/tor
+	>=dev-libs/libevent-2.1.12-r1:=[ssl]
+	dev-libs/openssl:=[-bindist(-)]
+	sys-libs/zlib
+	caps? ( sys-libs/libcap )
+	man? ( app-text/asciidoc )
+	lzma? ( app-arch/xz-utils )
+	scrypt? ( app-crypt/libscrypt )
+	seccomp? ( >=sys-libs/libseccomp-2.4.1 )
+	systemd? ( sys-apps/systemd:= )
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="
+	${DEPEND}
+	selinux? ( sec-policy/selinux-tor )
+"
+DEPEND+="
+	test? (
+		${DEPEND}
+		${PYTHON_DEPS}
+	)
+"
+
+DOCS=()
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.2.7.4-torrc.sample.patch
+)
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	# test correctly fails because -lnacl fails if not available
+	# https://bugs.gentoo.org/900092
+	crypto_scalarmult_curve25519
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]] ; then
+		git-r3_src_unpack
+	else
+		if use verify-sig; then
+			cd "${DISTDIR}" || die
+			verify-sig_verify_detached ${MY_PF}.tar.gz.sha256sum{,.asc}
+			verify-sig_verify_unsigned_checksums \
+				${MY_PF}.tar.gz.sha256sum sha256 ${MY_PF}.tar.gz
+			cd "${WORKDIR}" || die
+		fi
+
+		default
+	fi
+}
+
+src_prepare() {
+	default
+
+	# Running shellcheck automagically isn't useful for ebuild testing.
+	echo "exit 0" > scripts/maint/checkShellScripts.sh || die
+
+	if [[ ${PV} == 9999 ]] ; then
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	use doc && DOCS+=( README.md ChangeLog ReleaseNotes doc/HACKING )
+
+	export ac_cv_lib_cap_cap_init=$(usex caps)
+	export tor_cv_PYTHON="${EPYTHON}"
+
+	local myeconfargs=(
+		--localstatedir="${EPREFIX}/var"
+		--disable-all-bugs-are-fatal
+		--enable-system-torrc
+		--disable-android
+		--disable-coverage
+		--disable-html-manual
+		--disable-libfuzzer
+		--enable-missing-doc-warnings
+		--disable-module-dirauth
+		--enable-pic
+		--disable-restart-debugging
+
+		# Unless someone asks & has a compelling reason, just always
+		# build in GPL mode for pow, given we don't want yet another USE
+		# flag combination to have to test just for the sake of it.
+		# (PoW requires GPL.)
+		--enable-gpl
+		--enable-module-pow
+
+		$(use_enable man asciidoc)
+		$(use_enable man manpage)
+		$(use_enable lzma)
+		$(use_enable scrypt libscrypt)
+		$(use_enable seccomp)
+		$(use_enable server module-relay)
+		$(use_enable systemd)
+		$(use_enable tor-hardening gcc-hardening)
+		$(use_enable tor-hardening linker-hardening)
+		$(use_enable test unittests)
+		$(use_enable zstd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	local skip_tests=(
+		# Fails in sandbox
+		:sandbox/open_filename
+		:sandbox/openat_filename
+	)
+
+	if use arm ; then
+		skip_tests+=(
+			# bug #920905
+			# https://gitlab.torproject.org/tpo/core/tor/-/issues/40912
+			:sandbox/opendir_dirname
+			:sandbox/openat_filename
+			:sandbox/chmod_filename
+			:sandbox/chown_filename
+			:sandbox/rename_filename
+		)
+	fi
+
+	# The makefile runs these by parallel by chunking them with a script
+	# but that means we lose verbosity and can't skip individual tests easily
+	# either.
+	edo ./src/test/test --verbose "${skip_tests[@]}"
+}
+
+src_install() {
+	default
+	readme.gentoo_create_doc
+
+	newconfd "${FILESDIR}"/tor.confd tor
+	newinitd "${FILESDIR}"/tor.initd-r9 tor
+	systemd_dounit "${FILESDIR}"/tor.service
+
+	keepdir /var/lib/tor
+
+	fperms 750 /var/lib/tor
+	fowners tor:tor /var/lib/tor
+
+	insinto /etc/tor/
+	newins "${FILESDIR}"/torrc-r2 torrc
+}