gentoo auto-resync : 09:06:2024 - 00:08:13

7 files changed, 345 insertions, 24 deletions

diff --git a/net-voip/Manifest.gz b/net-voip/Manifest.gz
index 9bce77c3d5c0..303652c5f0f6 100644
--- a/net-voip/Manifest.gz
+++ b/net-voip/Manifest.gz
diff --git a/net-voip/mumble/Manifest b/net-voip/mumble/Manifest
index 1e4c32407d41..8761fd1441e2 100644
--- a/net-voip/mumble/Manifest
+++ b/net-voip/mumble/Manifest
@@ -3,6 +3,8 @@ DIST mumble-1.4-crypto-threads.patch.xz 1472 BLAKE2B 18f64d7b63a5ac253792e31fe27
 DIST mumble-1.4-odr.patch.xz 1088 BLAKE2B 48a7b04ef31f7d0f4cc7e5632ba8f328e5a7fa6961cd971b66a761366351a9a99e3cecce911c90701688083e03f2b63e6838083a8ab669f86fe0fecf23a8596d SHA512 600807cbd893f585c621e7267ee16e2828428fff17aa7eb36b8595164356ef73be2765a41ff9cd7c549c11a63abbf593b0172e56e07571e1c0a3c86fd14e5f15
 DIST mumble-1.4-openssl3.patch.xz 4172 BLAKE2B 5b68f023e218628a4d73b0991dcc7790ce5f92ce6a27c372c5e80b1f3a8beafa3ddd6416b884705b321aee31ea4f5e09dda6ceb240272dde64f420fbeb06845a SHA512 3a4e504f3365e93418cb85d0da4e6f2f54ab904283743907604bb39276560a4215d9bea1b225601789d1c3d84d270c04840ec57cd04e3df1204cc586ea42562a
 DIST mumble-1.4.287.tar.gz 9457292 BLAKE2B 5fc89c184aa54ab8269870fd87b6c9ce271d77c05a6ecb2aa78eccf297ffb842a50a18a142ac628c1b287a2b5e6c0ae0dced3237242303840a4de05b7f3e7040 SHA512 34ed30c18257ba8deae6938009a90147c8bc3a0aca28e69bea7ec0262e8d2cdacb9a840fac7d3dd623a52ef8d5903ed5424b62b483af21d6df6aa9632eae9d82
+DIST mumble-1.5.634.tar.gz 26001230 BLAKE2B ebd1e3569dd7311d704dbb83ff0ef15875dfaba7a7ba357e3be88800544d4d2217e19a15c0df778deec5a701ddc3692ca3f053651dec1eb1525b7963107ae76e SHA512 5fa9479dd836b87cb84fb6c067019f75aac335aa201baa34939f1c73dd7c67279aed6079aecdab74a14cb6c285b69cb82798de8801b2140ccf99c764b3a84b59
 EBUILD mumble-1.4.287-r1.ebuild 4138 BLAKE2B 3761785af0e3becaff28fd4c1d31bcc0bede8ae136fbd397db1527af6beeace2325ebfe2569d150be164fcfa6bdedac13f8ae9910ad9c4d433f41a7b05505628 SHA512 7c93d2540a6aaeb46da43ced787e2ce87319f9aacc3567538af880bd6cee8001d5f4f72cbe77a5c517c3e6fad925f0bdb8b39236d8155f0ddb3c450c7c387444
-EBUILD mumble-9999.ebuild 3871 BLAKE2B 78c85aebd45cf8a7d2260af7042bdf38c9bb6729d52b29ca5d58b587caaad4df9e604bc3360b2e0f3a0d1ab4ae1aef4fc158bedb45f914b143fb8fd03054ec54 SHA512 ebcc666175f3b17aa7753734dbdbbd3ea6e51ee502015f56fcbae667d52c8a3d06379f33bde09ca5ee2ea23190ca05a402abb55b135bc5e932d0147303cdd43c
+EBUILD mumble-1.5.634.ebuild 3847 BLAKE2B e9a1d2844b79701234871375da0d2fbef356085b17978af817f3388bc8f9e96049089dcd13e1634b54e3422ba3c6a972b956035dc67386ec711e812641d47840 SHA512 f03de8c2b2b82ad5991a58fa489d32c85b09aadcb9349035c2b81caec6b4e8c0204bc5871d0d23bd99a27f4040ea7d4db5c7cdcc556d8c3cad7920734dd30632
+EBUILD mumble-9999.ebuild 3847 BLAKE2B e9a1d2844b79701234871375da0d2fbef356085b17978af817f3388bc8f9e96049089dcd13e1634b54e3422ba3c6a972b956035dc67386ec711e812641d47840 SHA512 f03de8c2b2b82ad5991a58fa489d32c85b09aadcb9349035c2b81caec6b4e8c0204bc5871d0d23bd99a27f4040ea7d4db5c7cdcc556d8c3cad7920734dd30632
 MISC metadata.xml 659 BLAKE2B 29aa7577035302a7cdcd6c433bcdfa6754b13b6b4c41add1779c176e9ab58a2b7a5b74a71269c0ab5e2a2cf6442218e1a9529c26175286431c121ea398e02276 SHA512 82d88c9d5d4fcbe79cbed7de582ad13dcdcbd81165cb808373b2917d59d56bd7b724ed5c1710c17552e8efde39d0f7cc058d3b30355379ea5f1ee3a4d1995227
diff --git a/net-voip/mumble/mumble-1.5.634.ebuild b/net-voip/mumble/mumble-1.5.634.ebuild
new file mode 100644
index 000000000000..4ba02c3ee8b2
--- /dev/null
+++ b/net-voip/mumble/mumble-1.5.634.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake flag-o-matic multilib python-any-r1 xdg
+
+DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software"
+HOMEPAGE="https://wiki.mumble.info"
+if [[ "${PV}" == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mumble-voip/mumble.git"
+
+	# needed for the included 3rdparty license script,
+	# even if these components may not be compiled in
+	EGIT_SUBMODULES=(
+		'-*'
+		3rdparty/cmake-compiler-flags
+		3rdparty/FindPythonInterpreter
+		3rdparty/flag-icons
+		3rdparty/minhook
+		3rdparty/renamenoise
+		3rdparty/speexdsp
+		3rdparty/tracy
+	)
+else
+	if [[ "${PV}" == *_pre* ]] ; then
+		SRC_URI="https://dev.gentoo.org/~concord/distfiles/${P}.tar.xz"
+	else
+		MY_PV="${PV/_/-}"
+		MY_P="${PN}-${MY_PV}"
+		SRC_URI="https://github.com/mumble-voip/mumble/releases/download/v${MY_PV}/${MY_P}.tar.gz"
+		S="${WORKDIR}/${P/_*}"
+	fi
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="+alsa debug g15 jack pipewire portaudio pulseaudio multilib nls +rnnoise speech test zeroconf"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/ms-gsl
+	>=dev-libs/openssl-1.0.0b:0=
+	dev-libs/poco[util,xml,zip]
+	>=dev-libs/protobuf-2.2.0:=
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	>=media-libs/libsndfile-1.0.20[-minimal]
+	>=media-libs/opus-1.3.1
+	>=media-libs/speex-1.2.0
+	media-libs/speexdsp
+	sys-apps/lsb-release
+	x11-libs/libX11
+	x11-libs/libXi
+	alsa? ( media-libs/alsa-lib )
+	g15? ( app-misc/g15daemon:= )
+	jack? ( virtual/jack )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	pipewire? ( media-video/pipewire )
+	speech? ( >=app-accessibility/speech-dispatcher-0.8.0 )
+	zeroconf? ( net-dns/avahi[mdnsresponder-compat] )
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-cpp/nlohmann_json
+	dev-qt/qtconcurrent:5
+	dev-qt/qttest:5
+	dev-libs/boost
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	sed '/TRACY_ON_DEMAND/s@ ON @ OFF @' -i src/CMakeLists.txt || die
+
+	# required because of xdg.eclass also providing src_prepare
+	cmake_src_prepare
+}
+
+src_configure() {
+
+	local mycmakeargs=(
+		-Dalsa="$(usex alsa)"
+		-Dbundled-gsl="OFF"
+		-Dbundled-json="OFF"
+		-Dbundled-speex="OFF"
+		-Dg15="$(usex g15)"
+		-Djackaudio="$(usex jack)"
+		-Doverlay="ON"
+		-Dportaudio="$(usex portaudio)"
+		-Doverlay-xcompile="$(usex multilib)"
+		-Dpipewire="$(usex pipewire)"
+		-Dpulseaudio="$(usex pulseaudio)"
+		-Drenamenoise="$(usex rnnoise)"
+		-Dserver="OFF"
+		-Dspeechd="$(usex speech)"
+		-Dtests="$(usex test)"
+		-Dtracy="OFF"
+		-Dtranslations="$(usex nls)"
+		-Dupdate="OFF"
+		-Dwarnings-as-errors="OFF"
+		-Dzeroconf="$(usex zeroconf)"
+	)
+
+	if [[ "${PV}" != 9999 ]] ; then
+		mycmakeargs+=( -DBUILD_NUMBER="$(ver_cut 3)" )
+	fi
+
+	# https://bugs.gentoo.org/832978
+	# fix tests (and possibly runtime issues) on arches with unsigned chars
+	append-cxxflags -fsigned-char
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use amd64 && use multilib ; then
+		# The 32bit overlay library gets built when multilib is enabled.
+		# Install it into the correct 32bit lib dir.
+		local libdir_64="/usr/$(get_libdir)/mumble"
+		local libdir_32="/usr/$(get_abi_var LIBDIR x86)/mumble"
+		dodir ${libdir_32}
+		mv "${ED}"/${libdir_64}/libmumbleoverlay.x86.so* \
+			"${ED}"/${libdir_32}/ || die
+	fi
+
+	insinto /usr/share/mumble
+	doins -r samples
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	echo
+	elog "Visit https://wiki.mumble.info/ for futher configuration instructions."
+	elog "Run 'mumble-overlay <program>' to start the OpenGL overlay (after starting mumble)."
+	echo
+}
diff --git a/net-voip/mumble/mumble-9999.ebuild b/net-voip/mumble/mumble-9999.ebuild
index 79e98b80ec73..4ba02c3ee8b2 100644
--- a/net-voip/mumble/mumble-9999.ebuild
+++ b/net-voip/mumble/mumble-9999.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
-inherit cmake flag-o-matic python-any-r1 xdg
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake flag-o-matic multilib python-any-r1 xdg
 
 DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software"
 HOMEPAGE="https://wiki.mumble.info"
@@ -18,10 +18,9 @@ if [[ "${PV}" == 9999 ]] ; then
 		'-*'
 		3rdparty/cmake-compiler-flags
 		3rdparty/FindPythonInterpreter
-		3rdparty/gsl
+		3rdparty/flag-icons
 		3rdparty/minhook
-		3rdparty/opus
-		3rdparty/rnnoise-src
+		3rdparty/renamenoise
 		3rdparty/speexdsp
 		3rdparty/tracy
 	)
@@ -32,21 +31,23 @@ else
 		MY_PV="${PV/_/-}"
 		MY_P="${PN}-${MY_PV}"
 		SRC_URI="https://github.com/mumble-voip/mumble/releases/download/v${MY_PV}/${MY_P}.tar.gz"
-		S="${WORKDIR}/${P/_*}.src"
+		S="${WORKDIR}/${P/_*}"
 	fi
 	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
 fi
 
 LICENSE="BSD MIT"
 SLOT="0"
-IUSE="+alsa +dbus debug g15 jack pipewire portaudio pulseaudio multilib nls +rnnoise speech test zeroconf"
+IUSE="+alsa debug g15 jack pipewire portaudio pulseaudio multilib nls +rnnoise speech test zeroconf"
 RESTRICT="!test? ( test )"
 
 RDEPEND="
+	dev-cpp/ms-gsl
 	>=dev-libs/openssl-1.0.0b:0=
 	dev-libs/poco[util,xml,zip]
 	>=dev-libs/protobuf-2.2.0:=
 	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
 	dev-qt/qtgui:5
 	dev-qt/qtnetwork:5[ssl]
 	dev-qt/qtsql:5[sqlite]
@@ -61,7 +62,6 @@ RDEPEND="
 	x11-libs/libX11
 	x11-libs/libXi
 	alsa? ( media-libs/alsa-lib )
-	dbus? ( dev-qt/qtdbus:5 )
 	g15? ( app-misc/g15daemon:= )
 	jack? ( virtual/jack )
 	portaudio? ( media-libs/portaudio )
@@ -98,10 +98,9 @@ src_configure() {
 
 	local mycmakeargs=(
 		-Dalsa="$(usex alsa)"
+		-Dbundled-gsl="OFF"
 		-Dbundled-json="OFF"
-		-Dbundled-opus="OFF"
 		-Dbundled-speex="OFF"
-		-Ddbus="$(usex dbus)"
 		-Dg15="$(usex g15)"
 		-Djackaudio="$(usex jack)"
 		-Doverlay="ON"
@@ -109,7 +108,7 @@ src_configure() {
 		-Doverlay-xcompile="$(usex multilib)"
 		-Dpipewire="$(usex pipewire)"
 		-Dpulseaudio="$(usex pulseaudio)"
-		-Drnnoise="$(usex rnnoise)"
+		-Drenamenoise="$(usex rnnoise)"
 		-Dserver="OFF"
 		-Dspeechd="$(usex speech)"
 		-Dtests="$(usex test)"
diff --git a/net-voip/murmur/Manifest b/net-voip/murmur/Manifest
index 54d6d1716637..5a9d7a02952d 100644
--- a/net-voip/murmur/Manifest
+++ b/net-voip/murmur/Manifest
@@ -7,6 +7,8 @@ DIST mumble-1.4-crypto-threads.patch.xz 1472 BLAKE2B 18f64d7b63a5ac253792e31fe27
 DIST mumble-1.4-odr.patch.xz 1088 BLAKE2B 48a7b04ef31f7d0f4cc7e5632ba8f328e5a7fa6961cd971b66a761366351a9a99e3cecce911c90701688083e03f2b63e6838083a8ab669f86fe0fecf23a8596d SHA512 600807cbd893f585c621e7267ee16e2828428fff17aa7eb36b8595164356ef73be2765a41ff9cd7c549c11a63abbf593b0172e56e07571e1c0a3c86fd14e5f15
 DIST mumble-1.4-openssl3.patch.xz 4172 BLAKE2B 5b68f023e218628a4d73b0991dcc7790ce5f92ce6a27c372c5e80b1f3a8beafa3ddd6416b884705b321aee31ea4f5e09dda6ceb240272dde64f420fbeb06845a SHA512 3a4e504f3365e93418cb85d0da4e6f2f54ab904283743907604bb39276560a4215d9bea1b225601789d1c3d84d270c04840ec57cd04e3df1204cc586ea42562a
 DIST mumble-1.4.287.tar.gz 9457292 BLAKE2B 5fc89c184aa54ab8269870fd87b6c9ce271d77c05a6ecb2aa78eccf297ffb842a50a18a142ac628c1b287a2b5e6c0ae0dced3237242303840a4de05b7f3e7040 SHA512 34ed30c18257ba8deae6938009a90147c8bc3a0aca28e69bea7ec0262e8d2cdacb9a840fac7d3dd623a52ef8d5903ed5424b62b483af21d6df6aa9632eae9d82
+DIST mumble-1.5.634.tar.gz 26001230 BLAKE2B ebd1e3569dd7311d704dbb83ff0ef15875dfaba7a7ba357e3be88800544d4d2217e19a15c0df778deec5a701ddc3692ca3f053651dec1eb1525b7963107ae76e SHA512 5fa9479dd836b87cb84fb6c067019f75aac335aa201baa34939f1c73dd7c67279aed6079aecdab74a14cb6c285b69cb82798de8801b2140ccf99c764b3a84b59
 EBUILD murmur-1.4.287-r2.ebuild 5076 BLAKE2B 81ff6d63cd6d3a34b86242523dd92ec9a0cde341259f91640f0f281a17adb53b91924eadefe48be384697360f5caab761ca5a0f793dc0469a2e933e81b9bfc3f SHA512 0ea39a18c3cadba14fac0405a6b4ba4f1f4b77ed1c361e8a4a7c02c509c8fa6942f6462d60582458651230aa698487ac5ded57eee4da887e8091bf73c8c28bbe
-EBUILD murmur-9999.ebuild 4145 BLAKE2B cb92119abf53bc148042fd6ad24147b48f05eef5f7eb04fdbc176daaf7f168f94c8b7511290ea6a9c64ac68780f63f34a9008b4536e4497e3b324718526f5a47 SHA512 0f1f3e60849a463e536db6fc4939af9264be38a8dd9f73409a7c589fba6f95006b9bdc2681a3e8d571c0dfce226184768341a6dd8aad04b5561fe98b2290794b
+EBUILD murmur-1.5.634.ebuild 4373 BLAKE2B edb477684442513e1ade80915162f07fb384387378dbf3d8c15a22144c973f941b129670e5aa5235783fce022180694995debaab5b4ec8f9fe3dd02906711877 SHA512 a1339a40f3c83feb416bd1d24e60a5b682695c3712f34bf4ce6d15150c20712e0815284506720bcdfbebff9e0629c0a0b06bdda74517b9dadbefc462f178b81b
+EBUILD murmur-9999.ebuild 4373 BLAKE2B edb477684442513e1ade80915162f07fb384387378dbf3d8c15a22144c973f941b129670e5aa5235783fce022180694995debaab5b4ec8f9fe3dd02906711877 SHA512 a1339a40f3c83feb416bd1d24e60a5b682695c3712f34bf4ce6d15150c20712e0815284506720bcdfbebff9e0629c0a0b06bdda74517b9dadbefc462f178b81b
 MISC metadata.xml 590 BLAKE2B c8b9be5ba465c5a9a1d2b4ed33e5d1e86a148c6052eee9d39bd70c2073ec0578c3aad1ca14ddf2396611b43eb4c88d1dcae018d7c50530b64a1d8eecf807e3f0 SHA512 fef0cb21cb11c762b5ed70c89bd07dd30c3a0672b56cfdc09940b336cb7e13b2059fbde8eb738e355d7eb1a9e94d40e88f10073ed14f42f9edaf079d51f490d1
diff --git a/net-voip/murmur/murmur-1.5.634.ebuild b/net-voip/murmur/murmur-1.5.634.ebuild
new file mode 100644
index 000000000000..93abe94c1455
--- /dev/null
+++ b/net-voip/murmur/murmur-1.5.634.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic systemd readme.gentoo-r1 tmpfiles
+
+DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software"
+HOMEPAGE="https://wiki.mumble.info"
+if [[ "${PV}" == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mumble-voip/mumble.git"
+
+	# needed for the included 3rdparty license script,
+	# even if these components may not be compiled in
+	EGIT_SUBMODULES=(
+		'-*'
+		3rdparty/cmake-compiler-flags
+		3rdparty/FindPythonInterpreter
+		3rdparty/flag-icons
+		3rdparty/minhook
+		3rdparty/speexdsp
+		3rdparty/tracy
+	)
+else
+	MY_PN="mumble"
+	if [[ "${PV}" == *_pre* ]] ; then
+		MY_P="${MY_PN}-${PV}"
+		SRC_URI="https://dev.gentoo.org/~concord/distfiles/${MY_P}.tar.xz"
+		S="${WORKDIR}/${MY_P}"
+	else
+		MY_PV="${PV/_/-}"
+		MY_P="${MY_PN}-${MY_PV}"
+		SRC_URI="https://github.com/mumble-voip/mumble/releases/download/v${MY_PV}/${MY_P}.tar.gz"
+		S="${WORKDIR}/${MY_PN}-${PV/_*}"
+	fi
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="+ice test zeroconf"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/murmur
+	acct-user/murmur
+	dev-cpp/ms-gsl
+	>=dev-libs/openssl-1.0.0b:0=
+	>=dev-libs/protobuf-2.2.0:=
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtnetwork:5[ssl]
+	|| (
+		dev-qt/qtsql:5[sqlite]
+		dev-qt/qtsql:5[mysql]
+	)
+	dev-qt/qtxml:5
+	sys-apps/lsb-release
+	>=sys-libs/libcap-2.15
+	ice? ( dev-libs/Ice:= )
+	zeroconf? ( net-dns/avahi[mdnsresponder-compat] )
+"
+
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-qt/qttest:5
+"
+BDEPEND="
+	acct-group/murmur
+	acct-user/murmur
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="
+The default 'SuperUser' password will be written into the log file
+when starting murmur for the first time.
+
+If you want to manually set a password yourself, please execute:
+su murmur -s /bin/bash -c 'mumble-server -ini /etc/murmur/mumble-server.ini -supw <pw>'
+
+This will set the built-in 'SuperUser' password to '<pw>' when starting murmur.
+"
+
+src_prepare() {
+	# Adjust default server settings to be correct for our default setup
+	sed \
+		-e 's:database=:database=/var/lib/murmur/database.sqlite:' \
+		-e 's:;logfile=mumble-server.log:logfile=/var/log/murmur/murmur.log:' \
+		-e 's:;pidfile=:pidfile=/run/murmur/murmur.pid:' \
+		-i auxiliary_files/mumble-server.ini || die
+
+	# Replace the default group and user _mumble-server with murmur
+	grep -r -l _mumble-server auxiliary_files/ | xargs sed -i 's/_mumble-server/murmur/g' || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING="$(usex test)"
+		-Dbundled-gsl="OFF"
+		-Dclient="OFF"
+		-Dice="$(usex ice)"
+		-DMUMBLE_INSTALL_SYSCONFDIR="/etc/murmur"
+		-Dserver="ON"
+		-DMUMBLE_INSTALL_SERVICEFILEDIR=$(systemd_get_systemunitdir)
+		-DMUMBLE_INSTALL_SYSUSERSDIR=$(systemd_get_userunitdir)
+		-DMUMBLE_INSTALL_TMPFILESDIR="/usr/lib/tmpfiles.d"
+		-Dzeroconf="$(usex zeroconf)"
+	)
+	if [[ "${PV}" != 9999 ]] ; then
+		mycmakeargs+=( -DBUILD_NUMBER="$(ver_cut 3)" )
+	fi
+
+	# https://bugs.gentoo.org/832978
+	# fix tests (and possibly runtime issues) on arches with unsigned chars
+	append-cxxflags -fsigned-char
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	dodoc README.md
+
+	insinto /etc/logrotate.d/
+	newins "${FILESDIR}"/murmur.logrotate murmur
+
+	# Copy over the initd file so we can modify it incase zeroconf support is on.
+	cp "${FILESDIR}"/murmur.initd-r2 "${T}"/murmur.initd || die
+
+	if use zeroconf; then
+		sed -e 's:need:need avahi-daemon:' -i "${T}"/murmur.initd || die
+	fi
+
+	newinitd "${T}"/murmur.initd murmur
+	newconfd "${FILESDIR}"/murmur.confd-r2 murmur
+
+	keepdir /var/lib/murmur /var/log/murmur
+	fowners -R murmur /var/lib/murmur /var/log/murmur
+	fperms 750 /var/lib/murmur /var/log/murmur
+
+	mv "${ED}"/etc/murmur/mumble-server.ini "${ED}"/etc/murmur/murmur.ini || die
+	mv "${ED}"/usr/lib/systemd/system/mumble-server.service "${ED}"/usr/lib/systemd/system/murmur.service || die
+	sed -ie 's|mumble-server\.ini|murmur.ini|' "${ED}"/usr/lib/systemd/system/murmur.service || die
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	tmpfiles_process mumble-server.conf
+	readme.gentoo_print_elog
+
+	if use zeroconf; then
+		elog "To turn on the zeroconf functionality, you need to uncomment and"
+		elog "change the 'bonjour=false' setting in mumble-server.ini to 'true'"
+	fi
+}
diff --git a/net-voip/murmur/murmur-9999.ebuild b/net-voip/murmur/murmur-9999.ebuild
index b5d57c5bea38..93abe94c1455 100644
--- a/net-voip/murmur/murmur-9999.ebuild
+++ b/net-voip/murmur/murmur-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit cmake flag-o-matic systemd readme.gentoo-r1 tmpfiles
 
@@ -17,10 +17,8 @@ if [[ "${PV}" == 9999 ]] ; then
 		'-*'
 		3rdparty/cmake-compiler-flags
 		3rdparty/FindPythonInterpreter
-		3rdparty/gsl
+		3rdparty/flag-icons
 		3rdparty/minhook
-		3rdparty/opus
-		3rdparty/rnnoise-src
 		3rdparty/speexdsp
 		3rdparty/tracy
 	)
@@ -33,11 +31,10 @@ else
 	else
 		MY_PV="${PV/_/-}"
 		MY_P="${MY_PN}-${MY_PV}"
-		SRC_URI="https://github.com/mumble-voip/mumble/releases/download/${MY_PV}/${MY_P}.tar.gz
-			https://dl.mumble.info/${MY_P}.tar.gz"
-		S="${WORKDIR}/${MY_PN}-${PV/_*}.src"
+		SRC_URI="https://github.com/mumble-voip/mumble/releases/download/v${MY_PV}/${MY_P}.tar.gz"
+		S="${WORKDIR}/${MY_PN}-${PV/_*}"
 	fi
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 fi
 
 LICENSE="BSD"
@@ -48,6 +45,7 @@ RESTRICT="!test? ( test )"
 RDEPEND="
 	acct-group/murmur
 	acct-user/murmur
+	dev-cpp/ms-gsl
 	>=dev-libs/openssl-1.0.0b:0=
 	>=dev-libs/protobuf-2.2.0:=
 	dev-qt/qtcore:5
@@ -102,11 +100,10 @@ src_prepare() {
 src_configure() {
 	local mycmakeargs=(
 		-DBUILD_TESTING="$(usex test)"
+		-Dbundled-gsl="OFF"
 		-Dclient="OFF"
-		-Dg15="OFF"
 		-Dice="$(usex ice)"
 		-DMUMBLE_INSTALL_SYSCONFDIR="/etc/murmur"
-		-Doverlay="OFF"
 		-Dserver="ON"
 		-DMUMBLE_INSTALL_SERVICEFILEDIR=$(systemd_get_systemunitdir)
 		-DMUMBLE_INSTALL_SYSUSERSDIR=$(systemd_get_userunitdir)
@@ -146,6 +143,10 @@ src_install() {
 	fowners -R murmur /var/lib/murmur /var/log/murmur
 	fperms 750 /var/lib/murmur /var/log/murmur
 
+	mv "${ED}"/etc/murmur/mumble-server.ini "${ED}"/etc/murmur/murmur.ini || die
+	mv "${ED}"/usr/lib/systemd/system/mumble-server.service "${ED}"/usr/lib/systemd/system/murmur.service || die
+	sed -ie 's|mumble-server\.ini|murmur.ini|' "${ED}"/usr/lib/systemd/system/murmur.service || die
+
 	readme.gentoo_create_doc
 }