gentoo resync : 29.12.2022

3 files changed, 187 insertions, 24 deletions

diff --git a/net-misc/spice-gtk/Manifest b/net-misc/spice-gtk/Manifest
index 786d850bb4c0..e227d6b331e1 100644
--- a/net-misc/spice-gtk/Manifest
+++ b/net-misc/spice-gtk/Manifest
@@ -1,6 +1,8 @@
 AUX README.gentoo 527 BLAKE2B 5f02dbe14485894513b67bfb8b6f6159321e081f82f24c76a4b05f1463f8a6e332fffb2510b791a04fb9ad99ce7caba761b313fe2252c8d44893faa6ccef0d29 SHA512 2f8a79f6eea330ac9a6927c6cce29f9232c3c0650436f3f4c459d324bd5054a4ad82786d926e5e4c7384e74cb84d1fbb387c25b0b4c27fdb9514d526cbe02f9b
 AUX spice-gtk-0.39-fix-finding-pyparsing.patch 634 BLAKE2B 232f39c0762c23553952e3f84018622b01f51ea2e1967b83f1016cf9e096e798d914e044598dcf6c41359dc95116152409918d7be800fe686dbdaa2d711ce30b SHA512 54140731f5005d2ccbd41358f499be6dfcdf909606c894c3707f686ba80898595484f2509857608c54d60908dbbb1ef4309ae0673f47d1594eb7b543db39fb45
 DIST spice-gtk-0.39.tar.xz 845528 BLAKE2B c886c4c9f0e51d7f2bf6dbfe574f1a2bcab249f863cb7da1f009410572cdaa7a35ef98fc370a7e74f7e490ad3bfe8ffa832601f8bb0b0894b90ec1de76495ce9 SHA512 ff0f3ca6b10a2c415f2fa8d61464c5710aaa2a46c2c83909f146fa45f01151e756d9c3d79cb162dd3d0c1279b6ef55a67fc5c1266af2cb5b46ac1eaa0254c8d2
+DIST spice-gtk-0.40.tar.xz 848688 BLAKE2B 1046361ca40037bca826759bd7dc86f522640d39c08b1579f8e25bc2a2510665034445f7421d4de0485df9ef868e19779000c643035842f18e16555e3a1936b3 SHA512 b6db8b56c5c36158d97b3f7690d18883c4d6076e4ed1de1763fc704f9a2397b60d6170b70882d7d0a977b32be334756b7a27d66849f53e4d3b82abb8a54a0892
 EBUILD spice-gtk-0.39-r2.ebuild 3205 BLAKE2B 70c637fc3edd032462b4a5eef134d03e7f8b5805a96d0b3fa72fb1bae49aa2e49cd7db7b3c1f7399051a3a754aa96402cea83a5618313ca3e3fbefd8ee8a0e65 SHA512 6bc020c385e9ac49cb8f23d259c69d4c578377d9baa068885ac268ae4acb5c60dc4624bb1606aca0d14c8e31e49e3ff3a940716c2912eb867a0062630b1e0e4e
-EBUILD spice-gtk-9999.ebuild 3158 BLAKE2B c5a87f0de68702ad2ed030b4fd82fe7d945d9f468acf890744ed441ec3d5695ddfb80c01d0e8b26d12c5a723371b06e7f8c9440881989bc1c8c0271356917f5a SHA512 6bcd6a0cdceb6af987d9044b155236b46bb99fb2a7d0b2c5e607267004a41b092613bcf0a3177048d956c58f9a6ec11f7b92e81b5716923c910907729465c079
+EBUILD spice-gtk-0.40.ebuild 3668 BLAKE2B 7363180cd7de7fe721a557043a7858268abdbfea8e89e9c4528bcbac5820ee492cb43b198f771aaa9d410051bc3ae3a4f30e9b114f6a1bfd1d25f53b7c0db8eb SHA512 37501a0ac3359e2df1c815b2d58b88b9472e8ed5f0b9126bf5bd6f3e2f7f42f5cbe4bac5539cbe0c87aad43a12aebca54eac27f14775971e52ace1e0e69b4de1
+EBUILD spice-gtk-9999.ebuild 3668 BLAKE2B 7363180cd7de7fe721a557043a7858268abdbfea8e89e9c4528bcbac5820ee492cb43b198f771aaa9d410051bc3ae3a4f30e9b114f6a1bfd1d25f53b7c0db8eb SHA512 37501a0ac3359e2df1c815b2d58b88b9472e8ed5f0b9126bf5bd6f3e2f7f42f5cbe4bac5539cbe0c87aad43a12aebca54eac27f14775971e52ace1e0e69b4de1
 MISC metadata.xml 786 BLAKE2B 92848ffe7209398af8bb17b6ec7017474aac7abfd9b2d1babdf9724c909ab364c53d23115d46c7cfc316ac2014c56d89a80590924e5fa31302b9a9016783e30d SHA512 1de921c89ecdeeaf601d8a362f025ed636a4125152a5042e51ca7c54c1b0dbe479566ad9528913c24209ac4c22c94c7b8a927bf6e352ea8223c65408af3a7dfa
diff --git a/net-misc/spice-gtk/spice-gtk-0.40.ebuild b/net-misc/spice-gtk/spice-gtk-0.40.ebuild
new file mode 100644
index 000000000000..357e2deefa6d
--- /dev/null
+++ b/net-misc/spice-gtk/spice-gtk-0.40.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VALA_MIN_API_VERSION="0.14"
+VALA_USE_DEPEND="vapigen"
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit desktop meson optfeature python-any-r1 readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Set of GObject and Gtk objects for connecting to Spice servers and a client GUI"
+HOMEPAGE="https://www.spice-space.org https://cgit.freedesktop.org/spice/spice-gtk/"
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/spice/spice-gtk.git"
+	inherit git-r3
+
+	SPICE_PROTOCOL_VER=9999
+else
+	SRC_URI="https://www.spice-space.org/download/gtk/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+	SPICE_PROTOCOL_VER=0.14.3
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="+gtk3 +introspection lz4 mjpeg policykit sasl smartcard usbredir vala wayland webdav"
+
+# TODO:
+# * check if sys-freebsd/freebsd-lib (from virtual/acl) provides acl/libacl.h
+# * use external pnp.ids as soon as that means not pulling in gnome-desktop
+RDEPEND="
+	>=dev-libs/glib-2.46:2
+	dev-libs/json-glib:0=
+	media-libs/gst-plugins-base:1.0
+	media-libs/gst-plugins-good:1.0
+	media-libs/gstreamer:1.0[introspection?]
+	media-libs/opus
+	media-libs/libjpeg-turbo:=
+	sys-libs/zlib
+	>=x11-libs/cairo-1.2
+	>=x11-libs/pixman-0.17.7
+	x11-libs/libX11
+	gtk3? ( x11-libs/gtk+:3[introspection?] )
+	introspection? ( dev-libs/gobject-introspection )
+	dev-libs/openssl:=
+	lz4? ( app-arch/lz4 )
+	sasl? ( dev-libs/cyrus-sasl )
+	smartcard? ( app-emulation/qemu[smartcard] )
+	usbredir? (
+		sys-apps/hwdata
+		>=sys-apps/usbredir-0.4.2
+		virtual/libusb:1
+		policykit? (
+			sys-apps/acl
+			>=sys-auth/polkit-0.110-r1
+		)
+	)
+	webdav? (
+		net-libs/phodav:2.0
+		>=net-libs/libsoup-2.49.91:2.4
+	)
+"
+# TODO: spice-gtk has an automagic dependency on x11-libs/libva without a
+# configure knob. The package is relatively lightweight so we just depend
+# on it unconditionally for now. It would be cleaner to transform this into
+# a USE="vaapi" conditional and patch the buildsystem...
+RDEPEND="${RDEPEND}
+	amd64? ( x11-libs/libva:= )
+	arm64? ( x11-libs/libva:= )
+	x86? ( x11-libs/libva:= )
+"
+DEPEND="${RDEPEND}
+	>=app-emulation/spice-protocol-${SPICE_PROTOCOL_VER}"
+BDEPEND="
+	dev-perl/Text-CSV
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	$(python_gen_any_dep '
+		dev-python/six[${PYTHON_USEDEP}]
+		dev-python/pyparsing[${PYTHON_USEDEP}]
+	')
+"
+
+python_check_deps() {
+	python_has_version "dev-python/six[${PYTHON_USEDEP}]" &&
+	python_has_version "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gtk3 gtk)
+		$(meson_feature introspection)
+		$(meson_use mjpeg builtin-mjpeg)
+		$(meson_feature policykit polkit)
+		$(meson_feature lz4)
+		$(meson_feature sasl)
+		$(meson_feature smartcard)
+		$(meson_feature usbredir)
+		$(meson_feature vala vapi)
+		$(meson_feature webdav)
+		$(meson_feature wayland wayland-protocols)
+	)
+
+	if use usbredir; then
+		emesonargs+=(
+			-Dusb-acl-helper-dir=/usr/libexec
+			-Dusb-ids-path="${EPREFIX}"/usr/share/hwdata/usb.ids
+		)
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use usbredir && use policykit; then
+		# bug #775554 (and bug #851657)
+		fowners root:root /usr/libexec/spice-client-glib-usb-acl-helper
+		fperms 4755 /usr/libexec/spice-client-glib-usb-acl-helper
+	fi
+
+	make_desktop_entry spicy Spicy "utilities-terminal" "Network;RemoteAccess;"
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "Sound support (via pulseaudio)" media-plugins/gst-plugins-pulse
+}
diff --git a/net-misc/spice-gtk/spice-gtk-9999.ebuild b/net-misc/spice-gtk/spice-gtk-9999.ebuild
index 5d2a172d0ec3..357e2deefa6d 100644
--- a/net-misc/spice-gtk/spice-gtk-9999.ebuild
+++ b/net-misc/spice-gtk/spice-gtk-9999.ebuild
@@ -1,23 +1,32 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 VALA_MIN_API_VERSION="0.14"
 VALA_USE_DEPEND="vapigen"
 
-PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_COMPAT=( python3_{8..10} )
 
-inherit desktop git-r3 meson python-any-r1 readme.gentoo-r1 vala xdg-utils
+inherit desktop meson optfeature python-any-r1 readme.gentoo-r1 vala xdg
 
 DESCRIPTION="Set of GObject and Gtk objects for connecting to Spice servers and a client GUI"
 HOMEPAGE="https://www.spice-space.org https://cgit.freedesktop.org/spice/spice-gtk/"
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/spice/spice-gtk.git"
+	inherit git-r3
+
+	SPICE_PROTOCOL_VER=9999
+else
+	SRC_URI="https://www.spice-space.org/download/gtk/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+	SPICE_PROTOCOL_VER=0.14.3
+fi
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-EGIT_REPO_URI="https://anongit.freedesktop.org/git/spice/spice-gtk.git"
-KEYWORDS=""
-IUSE="+gtk3 +introspection lz4 mjpeg policykit pulseaudio sasl smartcard usbredir vala webdav"
+IUSE="+gtk3 +introspection lz4 mjpeg policykit sasl smartcard usbredir vala wayland webdav"
 
 # TODO:
 # * check if sys-freebsd/freebsd-lib (from virtual/acl) provides acl/libacl.h
@@ -29,17 +38,15 @@ RDEPEND="
 	media-libs/gst-plugins-good:1.0
 	media-libs/gstreamer:1.0[introspection?]
 	media-libs/opus
+	media-libs/libjpeg-turbo:=
 	sys-libs/zlib
-	virtual/jpeg:0=
 	>=x11-libs/cairo-1.2
 	>=x11-libs/pixman-0.17.7
+	x11-libs/libX11
 	gtk3? ( x11-libs/gtk+:3[introspection?] )
 	introspection? ( dev-libs/gobject-introspection )
-	dev-libs/openssl:0=
+	dev-libs/openssl:=
 	lz4? ( app-arch/lz4 )
-	pulseaudio? (
-		media-plugins/gst-plugins-pulse:1.0
-	)
 	sasl? ( dev-libs/cyrus-sasl )
 	smartcard? ( app-emulation/qemu[smartcard] )
 	usbredir? (
@@ -53,7 +60,8 @@ RDEPEND="
 	)
 	webdav? (
 		net-libs/phodav:2.0
-		>=net-libs/libsoup-2.49.91:2.4 )
+		>=net-libs/libsoup-2.49.91:2.4
+	)
 "
 # TODO: spice-gtk has an automagic dependency on x11-libs/libva without a
 # configure knob. The package is relatively lightweight so we just depend
@@ -65,16 +73,13 @@ RDEPEND="${RDEPEND}
 	x86? ( x11-libs/libva:= )
 "
 DEPEND="${RDEPEND}
-	~app-emulation/spice-protocol-9999
+	>=app-emulation/spice-protocol-${SPICE_PROTOCOL_VER}"
+BDEPEND="
 	dev-perl/Text-CSV
 	dev-util/glib-utils
-	>=dev-util/gtk-doc-am-1.14
 	>=sys-devel/gettext-0.17
 	virtual/pkgconfig
 	vala? ( $(vala_depend) )
-"
-
-BDEPEND="
 	$(python_gen_any_dep '
 		dev-python/six[${PYTHON_USEDEP}]
 		dev-python/pyparsing[${PYTHON_USEDEP}]
@@ -82,14 +87,14 @@ BDEPEND="
 "
 
 python_check_deps() {
-	has_version "dev-python/six[${PYTHON_USEDEP}]" &&
-	has_version "dev-python/pyparsing[${PYTHON_USEDEP}]"
+	python_has_version "dev-python/six[${PYTHON_USEDEP}]" &&
+	python_has_version "dev-python/pyparsing[${PYTHON_USEDEP}]"
 }
 
 src_prepare() {
 	default
 
-	use vala && vala_src_prepare
+	use vala && vala_setup
 }
 
 src_configure() {
@@ -98,18 +103,20 @@ src_configure() {
 		$(meson_feature introspection)
 		$(meson_use mjpeg builtin-mjpeg)
 		$(meson_feature policykit polkit)
-		$(meson_feature pulseaudio pulse)
 		$(meson_feature lz4)
 		$(meson_feature sasl)
 		$(meson_feature smartcard)
 		$(meson_feature usbredir)
 		$(meson_feature vala vapi)
 		$(meson_feature webdav)
+		$(meson_feature wayland wayland-protocols)
 	)
 
 	if use usbredir; then
-		emesonargs+=( -D "usb-acl-helper-dir=/usr/libexec" )
-		emesonargs+=( -D "usb-ids-path=${EPREFIX}/usr/share/hwdata/usb.ids" )
+		emesonargs+=(
+			-Dusb-acl-helper-dir=/usr/libexec
+			-Dusb-ids-path="${EPREFIX}"/usr/share/hwdata/usb.ids
+		)
 	fi
 
 	meson_src_configure
@@ -118,6 +125,18 @@ src_configure() {
 src_install() {
 	meson_src_install
 
+	if use usbredir && use policykit; then
+		# bug #775554 (and bug #851657)
+		fowners root:root /usr/libexec/spice-client-glib-usb-acl-helper
+		fperms 4755 /usr/libexec/spice-client-glib-usb-acl-helper
+	fi
+
 	make_desktop_entry spicy Spicy "utilities-terminal" "Network;RemoteAccess;"
 	readme.gentoo_create_doc
 }
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "Sound support (via pulseaudio)" media-plugins/gst-plugins-pulse
+}