Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.

1 files changed, 43 insertions, 0 deletions

diff --git a/net-misc/seafile/seafile-6.2.4.ebuild b/net-misc/seafile/seafile-6.2.4.ebuild
new file mode 100644
index 000000000000..2d7f5c030463
--- /dev/null
+++ b/net-misc/seafile/seafile-6.2.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 )
+inherit autotools python-single-r1 vala
+
+DESCRIPTION="File syncing and sharing software with file encryption and group sharing"
+HOMEPAGE="https://github.com/haiwen/seafile/ http://www.seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	net-libs/libsearpc[${PYTHON_USEDEP}]
+	~net-libs/ccnet-6.1.7[${PYTHON_USEDEP}]
+	dev-libs/glib:2
+	dev-libs/libevent:0
+	dev-libs/jansson
+	sys-libs/zlib:0
+	net-misc/curl
+	dev-libs/openssl:0
+	dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	$(vala_depend)"
+
+src_prepare() {
+	default
+	sed -i -e 's/valac /${VALAC} /' lib/Makefile.am || die
+	eautoreconf
+	vala_src_prepare
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files, as recommended by ltprune.eclass
+	find "${ED}" -name '*.la' -delete || die
+	python_fix_shebang "${ED}"/usr/bin
+}