gentoo resync : 16.06.2019

2 files changed, 148 insertions, 0 deletions

diff --git a/net-misc/mico/Manifest b/net-misc/mico/Manifest
index 9690a2607e59..1d202ed322f6 100644
--- a/net-misc/mico/Manifest
+++ b/net-misc/mico/Manifest
@@ -1,5 +1,7 @@
 DIST mico-2.3.13-gentoo-r13.patch 133254 BLAKE2B 71e22f8bd7491b6aa594a32d7d2a5677b3fc1376bb8ff11eae20e6749ec9c582b99704030c2178f81f1b1fd4ac8f4c2b14e3c80cdf9769ed49004c5a4bab761d SHA512 4e4c60c8e3f6e303b136d17cc83cd5bb92a2b23c0a843721ba74e62d6c69224719bf254a5d8c028df0166c36a07ef349e98f4244b4d208e689c3b6c382c1b906
+DIST mico-2.3.13-gentoo-r14.patch 136291 BLAKE2B 3416fe0fc2e0b9243d22c9cf6a0dffbf14c99846d1b064b3df6496c2d1b9021de0268d0543f566d13425d4fef29626829359deb133ce678d299627f93b0461de SHA512 3ec284442ac00bf429f633dddcaae46a83b720045bc93a177a609255957956aaccb188b0e858ac88b3d8b0c9be081501dcffabd86965b1a4b30a07d45aab0850
 DIST mico-2.3.13.tar.gz 3269814 BLAKE2B cddf6a3d3192625af492b1fa3cf91d4d19d3c8b410de9889cc2e68b6a0db28aef228c1c4e11dc04d4de629d58181dc9e9fd93ddd74537e3362ad5bcd4881750b SHA512 b4c09b5a41e480b8211529776b83e84669e1e91ccba7a0d2d940834f217bc7f3d9ef74101dadc43778c6813b733ccfdae2b00eab2f0993b58193bb9f270e3895
 EBUILD mico-2.3.13-r13.ebuild 4328 BLAKE2B e569938f537160595c3a546a4da8a3f2a43283c580e11ee0975d0620e1c02720522251f302c4953ed2420fd75086cb24e6c8a7aab2ad13f0e85a33ac924283af SHA512 7ed391ebfd57867eee96ef417a7356721d7cd0fdd72c372844f1ea730dce327e66efdde00864bf894bd319abf044823d9752b5414069b2804cff0b6e0bb24319
+EBUILD mico-2.3.13-r14.ebuild 4328 BLAKE2B e569938f537160595c3a546a4da8a3f2a43283c580e11ee0975d0620e1c02720522251f302c4953ed2420fd75086cb24e6c8a7aab2ad13f0e85a33ac924283af SHA512 7ed391ebfd57867eee96ef417a7356721d7cd0fdd72c372844f1ea730dce327e66efdde00864bf894bd319abf044823d9752b5414069b2804cff0b6e0bb24319
 EBUILD mico-9999.ebuild 4328 BLAKE2B e569938f537160595c3a546a4da8a3f2a43283c580e11ee0975d0620e1c02720522251f302c4953ed2420fd75086cb24e6c8a7aab2ad13f0e85a33ac924283af SHA512 7ed391ebfd57867eee96ef417a7356721d7cd0fdd72c372844f1ea730dce327e66efdde00864bf894bd319abf044823d9752b5414069b2804cff0b6e0bb24319
 MISC metadata.xml 631 BLAKE2B bb0a1ee82b5b74160096ad9652a933f25c51f192ff30b3ae18d477aacff13a1021aa959e238b9103957ddff622b40f4ec8269b35b114d2325e3f75f90891c580 SHA512 111d8d30478b2647475b075f3c16f49b14be2bbde9e55b0b9efde42c0eaa8da128dd6801a914a898a8500d705d034d50ad05f7b41da5ec644f3c1bad12f21840
diff --git a/net-misc/mico/mico-2.3.13-r14.ebuild b/net-misc/mico/mico-2.3.13-r14.ebuild
new file mode 100644
index 000000000000..4b4032d1f826
--- /dev/null
+++ b/net-misc/mico/mico-2.3.13-r14.ebuild
@@ -0,0 +1,146 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic toolchain-funcs autotools
+
+if [[ ${PV} == 9999 ]]; then
+	EDARCS_REPOSITORY="http://www.mico.org/mico-darcs-repository"
+	inherit darcs
+	SRC_URI=""
+	PATCHES="${WORKDIR}/${P}-gentoo.patch"
+else
+	SRC_URI="
+		http://www.mico.org/${P}.tar.gz
+		https://github.com/haubi/mico/compare/${PV}-raw...${PV}-gentoo-${PR}.patch -> ${P}-gentoo-${PR}.patch
+	"
+	PATCHES="${DISTDIR}/${P}-gentoo-${PR}.patch"
+	KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~sparc-solaris ~x86-winnt"
+fi
+
+DESCRIPTION="A freely available and fully compliant implementation of the CORBA standard"
+HOMEPAGE="http://www.mico.org/"
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+IUSE="gtk postgres ssl tcl threads X"
+RESTRICT="test" #298101
+
+# doesn't compile:
+#   bluetooth? ( net-wireless/bluez )
+
+RDEPEND="
+	gtk?       ( x11-libs/gtk+:2 )
+	postgres?  ( dev-db/postgresql:* )
+	ssl?       ( dev-libs/openssl:0= )
+	tcl?       ( dev-lang/tcl:0 )
+	X?         ( x11-libs/libXt )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/flex-2.5.2
+	>=sys-devel/bison-1.22
+"
+
+if [[ ${PV} == 9999 ]]; then
+	src_unpack() {
+		wget -O ${P}-gentoo.patch "https://github.com/haubi/mico/compare/gentoo.patch" || die
+		darcs_src_unpack
+		default
+	}
+else
+	S=${WORKDIR}/${PN}
+fi
+
+src_prepare() {
+	default
+
+	mv configure.in configure.ac || die #426262
+	eautoreconf
+
+	# cannot use big TOC (AIX only), gdb doesn't like it.
+	# This assumes that the compiler (or -wrapper) uses
+	# gcc flag '-mminimal-toc' for compilation.
+	sed -i -e 's/,-bbigtoc//' "${S}"/configure || die
+}
+
+src_configure() {
+	tc-export CC CXX
+	append-cxxflags -fno-strict-aliasing
+
+	# Don't know which version of JavaCUP would suffice, but there is no
+	# configure argument to disable checking for JavaCUP.
+	# So we override the configure check to not find 'javac'.
+	export ac_cv_path_JAVAC=no
+
+	# '--without-ssl' just does not add another search path - the only way
+	# to disable openssl utilization seems to override the configure check.
+	use ssl || export ac_cv_lib_ssl_open=no
+
+	local myconf=
+	myconf() {
+		myconf="${myconf} $*"
+	}
+
+	myconf --disable-mini-stl
+	myconf $(use_enable threads)
+
+	# '--without-*' or '--with-*=no' does not disable some features,
+	# the value needs to be empty instead.
+	# This applies to: pgsql, qt, tcl, bluetooth.
+	myconf --with-pgsql=$(use postgres && echo "${EPREFIX}"/usr)
+	myconf --with-tcl=$(  use tcl      && echo "${EPREFIX}"/usr)
+	# bluetooth and wireless both don't compile cleanly
+	myconf --with-bluetooth=''
+	myconf --disable-wireless
+	# But --without-x works.
+	myconf $(use_with X x "${EPREFIX}"/usr)
+	# Same for gtk after patch 013, searches for gtk release.
+	myconf $(use_with gtk gtk 2)
+
+	# http://www.mico.org/pipermail/mico-devel/2009-April/010285.html
+	[[ ${CHOST} == *-hpux* ]] && append-cppflags -D_XOPEN_SOURCE_EXTENDED
+
+	if [[ ${CHOST} == *-winnt* ]]; then
+		# disabling static libs, since ar on interix takes nearly
+		# one hour per library, thanks to mico's monster objects.
+		use threads &&
+		ewarn "disabling USE='threads', does not work on ${CHOST}"
+		myconf --disable-threads --disable-static --enable-final
+		append-flags -D__STDC__
+	fi
+
+	econf ${myconf}
+}
+
+src_install() {
+	emake INSTDIR="${ED}"/usr SHARED_INSTDIR="${ED}"/usr install LDCONFIG=:
+	if [[ $(get_libdir) != lib ]]; then #500744
+		mv "${ED}"/usr/lib "${ED}"/usr/$(get_libdir) || die
+	fi
+
+	# avoid conflict with net-dns/nsd, bug#544488
+	mv "${ED}"/usr/bin/{,mico-}nsd || die
+	mv "${ED}"/usr/man/man8/{,mico-}nsd.8 || die
+
+	# avoid conflict with net-misc/eventd, bug#632170
+	mv "${ED}"/usr/bin/{,mico-}eventd || die
+
+	dodir /usr/share
+	mv "${ED}"/usr/man "${ED}"/usr/share || die
+	dodir /usr/share/doc/${PF}
+	mv "${ED}"/usr/doc "${ED}"/usr/share/doc/${PF} || die
+
+	dodoc BUGS CHANGES* CONVERT README* ROADMAP TODO VERSION WTODO
+	[[ ${PV} == 9999 ]] || dodoc FAQ
+}
+
+pkg_postinst() {
+	einfo "The MICO Name Service daemon 'nsd' is named 'mico-nsd'"
+	einfo "due to a name conflict with net-dns/nsd. For details"
+	einfo "please refer to https://bugs.gentoo.org/544488."
+	einfo
+	einfo "The MICO Event daemon 'eventd' is named 'mico-eventd'"
+	einfo "due to a name conflict with net-misc/eventd. For details"
+	einfo "please refer to https://bugs.gentoo.org/632170."
+}