gentoo resync : 12.05.2022

3 files changed, 75 insertions, 0 deletions

diff --git a/net-misc/gnome-connections/Manifest b/net-misc/gnome-connections/Manifest
new file mode 100644
index 000000000000..7cd3e5073ea0
--- /dev/null
+++ b/net-misc/gnome-connections/Manifest
@@ -0,0 +1,3 @@
+DIST gnome-connections-42.1.2.tar.xz 3987992 BLAKE2B 2cad2376c238884b069767efbcd8afae5270f576e499fa59defe2d8ec10188cfd9b263a63cd44fcbe9ceed315267807f6b106f93d1fc73092e6c5366d9daac62 SHA512 34bc8e167ccd828c1aa52728017a52282d96b607751d566e3f8a5169d6fd5ccd7c6ae04abb073946f5cf6038c7b23b3eb897e2922b6d5b914d89ac0afbbbc7ed
+EBUILD gnome-connections-42.1.2.ebuild 1142 BLAKE2B 55e93469531e95fd8e6a756e557420374229ef20286b140be660f193d62da3d645ba4b0ba27fac814f388858c4e89493a9482e63879d11880342407fcfb44d85 SHA512 c65dcf3e54070ea3168b8af9121ef33ba02b238643b8d08f7b0103e0c59179f2e82064e0e06029107ba9cd639c65bd3824963014136e33316ddc2b64e4ab9740
+MISC metadata.xml 254 BLAKE2B de7a97001e5947704f42973c8a0c3a23c2d80afb976254f5fd21e9d372a946e055d4cdc3c0eaed010505f87929b56e8b1e650c945e2a302644adbc9440833be8 SHA512 c81da4f9b80e5691a167f4590906952e25356604ec17689c005be14efb394c0634776bbe84df936edde239480bdf46db41216b00da4a3a45f670e9ca18ab0132
diff --git a/net-misc/gnome-connections/gnome-connections-42.1.2.ebuild b/net-misc/gnome-connections/gnome-connections-42.1.2.ebuild
new file mode 100644
index 000000000000..8fb4b3b9b9da
--- /dev/null
+++ b/net-misc/gnome-connections/gnome-connections-42.1.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="A remote desktop client for the GNOME desktop environment"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/connections"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/gobject-introspection
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3[introspection]
+	>=net-libs/gtk-vnc-0.4.4[vala]
+	>=gui-libs/libhandy-1.2.0:1[vala]
+	>=dev-libs/libxml2-2.7.8
+	app-crypt/libsecret[vala]
+
+	>=net-misc/freerdp-2.0.0:0=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-libs/glib
+	dev-util/glib-utils
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	test? (
+		dev-libs/appstream-glib
+		dev-util/desktop-file-utils
+	)
+"
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofile=default
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/net-misc/gnome-connections/metadata.xml b/net-misc/gnome-connections/metadata.xml
new file mode 100644
index 000000000000..f453528b934f
--- /dev/null
+++ b/net-misc/gnome-connections/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>gnome@gentoo.org</email>
+		<name>Gentoo GNOME Desktop</name>
+	</maintainer>
+</pkgmetadata>