gentoo resync : 20.03.2022

1 files changed, 56 insertions, 0 deletions

diff --git a/net-misc/bridge-utils/bridge-utils-1.7.1-r1.ebuild b/net-misc/bridge-utils/bridge-utils-1.7.1-r1.ebuild
new file mode 100644
index 000000000000..85a58f61fc89
--- /dev/null
+++ b/net-misc/bridge-utils/bridge-utils-1.7.1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools linux-info toolchain-funcs
+
+DESCRIPTION="Tools for configuring the Linux kernel 802.1d Ethernet Bridge"
+HOMEPAGE="http://bridge.sourceforge.net/"
+SRC_URI="https://www.kernel.org/pub/linux/utils/net/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="selinux"
+
+DEPEND="virtual/os-headers"
+RDEPEND="selinux? ( sec-policy/selinux-brctl )"
+
+CONFIG_CHECK="~BRIDGE"
+WARNING_BRIDGE="CONFIG_BRIDGE is required to get bridge devices in the kernel"
+
+get_headers() {
+	CTARGET=${CTARGET:-${CHOST}}
+	dir=/usr/include
+	tc-is-cross-compiler && dir=/usr/${CTARGET}/usr/include
+	echo "${dir}"
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}"/libbridge-substitute-AR-variable-from-configure.patch
+		"${FILESDIR}"/${P}-musl.patch  #828902
+	)
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# use santitized headers and not headers from /usr/src
+	local myeconfargs=(
+		--prefix=/
+		--libdir=/usr/$(get_libdir)
+		--includedir=/usr/include
+		--with-linux-headers="$(get_headers)"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	dodoc AUTHORS ChangeLog README THANKS \
+		doc/{FAQ,FIREWALL,HOWTO,PROJECTS,RPM-GPG-KEY,SMPNOTES,WISHLIST}
+
+	[ -f "${ED}"/sbin/brctl ] || die "upstream makefile failed to install binary"
+}