gentoo resync : 18.05.2019

2 files changed, 233 insertions, 0 deletions

diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index a1156675bc43..c7f31c71f900 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -9,6 +9,7 @@ DIST notmuch-0.26.1.tar.gz 906523 BLAKE2B da0b06361d586d84bea5c6e28adf7850dcb119
 DIST notmuch-0.26.2.tar.gz 907187 BLAKE2B 81212555d729bd05be2edfb0f3dfd604de9d5f3e99e79ebd24a195441bd3778c7c72abe0b6b569dc1cf2ad9d94af1cbe3ca3aff77f521888b7be2eb08444dde1 SHA512 ebd8460c5f08cb8c79dabc1bc1bc32e1f2e1f123d304bb20205d4dedb982186336fd43d0e39acf020ea2563278bee0a063ceb3bf276f1251c099d8fcdd5098e7
 DIST notmuch-0.27.tar.gz 912583 BLAKE2B 75bb13e9666bd2898f58e5ecdd6a180d0da21188665f107857e6729f057525bb7c94832d140de8ff7b3fd31b51e33bcbe5b59d3fc09ba9a854c1c05499df762e SHA512 7c58c6fe5c3b43a979c3a439a24106417120726fd688b456d9084388ddd7c88ab1b6d99cd4676101f085d60bb37099631caa286b76588fcb041bb004ff325515
 DIST notmuch-0.28.3.tar.gz 921920 BLAKE2B 9b96a0cac8188bcaf9efab532721449c655fec4dac77c3eb327e576184cb430aa0fffc9ac74af82ad3ad80097afdda5c8accddbee7e5720d180c071d9dd2ef85 SHA512 dd3931b78cc27540e962f1fca5f4ebb1c04b2637a5761cda023f307fd9be4b5ddc2af26010330868c55200fa96b60b2a11b3b22d4c20d2a4a2d3787421ed85cf
+DIST notmuch-0.28.4.tar.gz 922364 BLAKE2B f22d52ecc982b086b5d2a67d3b9ae4a379bdcb9e9acf3e77060fd7d97439347e3b4cd767f2c9c3c48657b80f63316f6abc09a653d6791e27b4a8996adccf42a9 SHA512 77d7ad81e1f7dc93ae6392346da434f6dc74c21d19be728c2a6ca283c429f36e7081387d223af58eb5f63f5d2a8ad8367f0103f0bb9d052890c07fe419abbee7
 EBUILD notmuch-0.23.7.ebuild 4573 BLAKE2B 10251e488d1b9bbf03798726d168cb746178d6eb43ab8280dd8280d962300a32505e8e0a79aaeefc3b6a255830bcea1ab1a26e95a8d031b10a9379a0333e72f8 SHA512 437dfdebdb2f4105e1378c3202b77dee7c2443d59988c7dc8eee45a905012fecdfbcd90ada3a2fcb1099a7b8bd5febcc1b266f81b2fd5fe4658e5b4382144b5e
 EBUILD notmuch-0.24.2.ebuild 4763 BLAKE2B d6b6a5f62f624986286d504aed9e47b1c0380ca4d8d1de874be36d03aef542b45fd889a2cd97d264cf0defa22e9cbee676d9b4b6f6e2192c6a8dbc76287a9d86 SHA512 8e006a9da05e7556d505af790072fd96aff2f76d88866d9ad3dec66c13a1edf8e95f6522daef65bd4f15a16997c551892ac17e550a1faf2d176e721be7e2ed3a
 EBUILD notmuch-0.25.3.ebuild 4842 BLAKE2B b757474009732309b6f4301bd720766057ba10867616a44bbaa61f28179b02f3a04443ce5b5814f8d68df27d50b16e94d292ae1699a9bf7d0f327fc3103618ca SHA512 9b3f1df762c681c110da3f9aa62145a70abd07901a65a4fa70b4f229a2b1c788840585dcad532da5b998b52632fd5fd02c259c86127ed9931390d5c3c8d39e1b
@@ -16,4 +17,5 @@ EBUILD notmuch-0.26.1.ebuild 4836 BLAKE2B 15cbffd571f2366e66a943929a378dda070724
 EBUILD notmuch-0.26.2.ebuild 4836 BLAKE2B 15cbffd571f2366e66a943929a378dda07072433794c7ed31596ac8a63c63752ed9e28a37f6892e47a9a8aa45c4651f43e4398e401bd49e3e3b8e46ea4dbec6d SHA512 5a670bdad5b8c72cd355a46543f10a68b9ff15f65cc698393f90bc484f1c8f5c746b4f52ee8906a96f7ddefb432b268d2da7d6d2735ebe7e06236a324fa5395d
 EBUILD notmuch-0.27.ebuild 4943 BLAKE2B 7c8ba36bc9f95c439eee7a08b25b4ee004a190f4eaa49010d934e4b48ac8cd81598e9b6aff0ac251b39c39bbc35dfbbf65774986744cc4e1f005a0cb331e9dec SHA512 ab053d2382569d82cffd8c654a660e22af0888e96e1de44877d1798247fe22dde04c29630dd1161a996062acda15aaa6f6da087bf67d284897b41c2e84c0466e
 EBUILD notmuch-0.28.3.ebuild 5092 BLAKE2B 84f7d8dcd9c0d301f0f96d52920d6767ddd8b146a9ed87f0b859ef40d5bb690c5784ae2f68368fc02dea10cac0631b116a526c61f1a7a5b258ad335d81c1b4c0 SHA512 e3f374fd1ed932491f12580a00e7a0cb238eb80d5b7473e927700341a497f0c2ed4191d2dc84f7bb742f3ef292787e0c2e724b06cf5d083302b3ace1090c654d
+EBUILD notmuch-0.28.4.ebuild 5092 BLAKE2B 84f7d8dcd9c0d301f0f96d52920d6767ddd8b146a9ed87f0b859ef40d5bb690c5784ae2f68368fc02dea10cac0631b116a526c61f1a7a5b258ad335d81c1b4c0 SHA512 e3f374fd1ed932491f12580a00e7a0cb238eb80d5b7473e927700341a497f0c2ed4191d2dc84f7bb742f3ef292787e0c2e724b06cf5d083302b3ace1090c654d
 MISC metadata.xml 1117 BLAKE2B 08710cbb42c20580235f5cfafa39715c33fb50de24cf98a182418db3c52ee1de5a1ee0e0775ae5756fee301c952995a1e7da52b9c13e5bd8c8b2fc0d1d74a5d2 SHA512 c420e475e5d16d35cceb1162c14eae143e5f539e771561d525af4ab0f0853e700b9a3209ee1a7aa9b4269c235737304c435d463cd8b1cf201402152ff0a6a4f3
diff --git a/net-mail/notmuch/notmuch-0.28.4.ebuild b/net-mail/notmuch/notmuch-0.28.4.ebuild
new file mode 100644
index 000000000000..95e5689f032e
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.28.4.ebuild
@@ -0,0 +1,231 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
+	distutils-r1 toolchain-funcs
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="https://notmuchmail.org/"
+SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz
+	test? ( ${HOMEPAGE%/}/releases/test-databases/database-v1.tar.xz )"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y.  Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~x86 ~x64-solaris"
+REQUIRED_USE="
+	nmbug? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( crypt emacs python valgrind )
+	"
+IUSE="crypt doc emacs mutt nmbug python test valgrind"
+
+CDEPEND="
+	!!<app-shells/bash-completion-1.9
+	>=dev-libs/glib-2.22:2
+	>=dev-libs/gmime-3.0.3:3.0
+	>=dev-libs/xapian-1.4.8:=
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	sys-apps/texinfo
+	>=sys-libs/zlib-1.2.5.2
+	sys-libs/talloc
+	crypt? ( dev-libs/gmime:3.0[crypt] )
+	emacs? ( >=virtual/emacs-23 )
+	python? ( ${PYTHON_DEPS} )
+	"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+	test? (
+		app-misc/dtach
+		|| ( >=app-editors/emacs-23[libxml2] >=app-editors/emacs-vcs-23[libxml2] )
+		sys-devel/gdb
+		crypt? ( app-crypt/gnupg dev-libs/openssl )
+	)
+	valgrind? ( dev-util/valgrind )
+	"
+RDEPEND="${CDEPEND}
+	crypt? ( app-crypt/gnupg )
+	nmbug? ( dev-vcs/git )
+	mutt? (
+		dev-perl/File-Which
+		dev-perl/Mail-Box
+		dev-perl/MailTools
+		dev-perl/String-ShellQuote
+		dev-perl/Term-ReadLine-Gnu
+		virtual/perl-Digest-SHA
+		virtual/perl-File-Path
+		virtual/perl-Getopt-Long
+		virtual/perl-Pod-Parser
+	)
+	"
+
+DOCS=( AUTHORS NEWS README )
+SITEFILE="50${PN}-gentoo.el"
+MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
+PATCHES=(
+	"${FILESDIR}"/0001-Use-loopback-IP-address-rather-than-name.patch
+	"${FILESDIR}"/0002-Fix-jobserver-unavailable-warning.patch
+)
+
+bindings() {
+	local ret=0
+
+	if use $1; then
+		pushd bindings/$1 || die
+		shift
+		"$@"
+		ret=$?
+		popd || die
+	fi
+
+	return $ret
+}
+
+pkg_pretend() {
+	if has_version '<net-mail/notmuch-0.18'; then
+		ewarn
+		ewarn "There are few not backward compatible changes between"
+		ewarn "<notmuch-0.18 and >=notmuch-0.18.  See NEWS file"
+		ewarn "(0.18 section) for details before first use!"
+		ewarn
+	fi
+}
+
+pkg_setup() {
+	if use emacs; then
+		elisp-need-emacs 23 || die "Emacs version too low"
+	fi
+}
+
+src_unpack() {
+	unpack "${P}".tar.gz
+	if use test; then
+		mkdir -p "${S}"/test/test-databases || die
+		cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	bindings python distutils-r1_src_prepare
+	bindings python mv README README-python || die
+	mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+	# assure that new Makefile.config will be generated
+	rm -f Makefile.config || die
+
+	sed -e 's@^install: all install-man install-info$@install: all install-info@' -i Makefile.local
+
+	if use test; then
+		append-cflags -g
+		append-cxxflags -g
+	fi
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+}
+
+src_configure() {
+	python_setup  # for sphinx
+
+	local myeconfargs=(
+		--bashcompletiondir="$(get_bashcompdir)"
+		--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+		--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+		--without-desktop
+		--without-ruby
+		--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+		$(use_with emacs)
+		$(use_with doc api-docs)
+	)
+	tc-export CC CXX
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	python_setup  # for sphinx
+
+	V=1 default
+	bindings python distutils-r1_src_compile
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		emake notmuch-mutt.1
+		popd || die
+	fi
+
+	if use doc; then
+		pydocs() {
+			pushd docs || die
+			emake html
+			rm -r html/_sources || die
+			rm html/{objects.inv,.buildinfo} || die
+			mkdir -p ../html && mv html ../html/python || die
+			popd || die
+		}
+		LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
+	fi
+}
+
+src_test() {
+	pax-mark -m notmuch
+	LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" V=1 default
+	pax-mark -ze notmuch
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		doman doc/_build/man/man?/*.?
+	fi
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+	fi
+
+	if use nmbug; then
+		dobin devel/nmbug/nmbug
+		dobin devel/nmbug/notmuch-report
+	fi
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		dobin notmuch-mutt
+		doman notmuch-mutt.1
+		insinto /etc/mutt
+		doins notmuch-mutt.rc
+		dodoc README-mutt
+		popd || die
+	fi
+
+	DOCS="" bindings python distutils-r1_src_install
+	use doc && bindings python dodoc -r html
+}
+
+pkg_preinst() {
+	if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
+		elog "To enable notmuch support in mutt, add the following line into"
+		elog "your mutt config file, please:"
+		elog ""
+		elog "  source /etc/mutt/notmuch-mutt.rc"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}