gentoo resync : 21.07.2018

2 files changed, 210 insertions, 0 deletions

diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index 3a1683d8b42b..425bd96db62e 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -7,6 +7,7 @@ DIST notmuch-0.25.2.tar.gz 882672 BLAKE2B 8bd90b87cf60a1eac8c331c4d67cfc511db91b
 DIST notmuch-0.25.3.tar.gz 883151 BLAKE2B 511f93c310e8b82f1b629735cbe626ab1ba8eabf23245ba4aa4c936d4c5d868d9e6d5b0d626f16ce6087245a293cf1acd8bb2e2dd0639729af4b92d558c78051 SHA512 1c0fcfdeb7a7eddcd10a8175676679ef6985407732d5bcc15edd327d9985017696cef3287c0398c628a604ae3fbab5d222d71537e37265cf6a594b4914e4599a
 DIST notmuch-0.25.tar.gz 882093 BLAKE2B ea0f5568ec0bf6a1d2c177468f4ec25fabfd416162c01a0d861e78164f15f2cc0176e1a012250a2a6bb45a6c7c2f6ffa651ad15776d44fed8ec191026b0f04c7 SHA512 5f4961818c8c0350e3fbbedd86f407a55fecf211971003a770d99ea2db89bb6b98c2294e114d6abff4d40985f506b7f4b52736a7ee5c78390eb4f2363a65c6f5
 DIST notmuch-0.26.1.tar.gz 906523 BLAKE2B da0b06361d586d84bea5c6e28adf7850dcb119e9f70ae67e06ff1438b9d20f4b04707d3e6ee6e755d569d15b8a720506b4c242c0c84258e8f5c8996caa62fc47 SHA512 f0d95a0f03535495037c73ab18d1251ece505284736efa5a535fe9bc8aea33954b5c87e5dcdfd30670c8df53178294be520a63e5b19beac7d90f166e616d19dd
+DIST notmuch-0.26.2.tar.gz 907187 BLAKE2B 81212555d729bd05be2edfb0f3dfd604de9d5f3e99e79ebd24a195441bd3778c7c72abe0b6b569dc1cf2ad9d94af1cbe3ca3aff77f521888b7be2eb08444dde1 SHA512 ebd8460c5f08cb8c79dabc1bc1bc32e1f2e1f123d304bb20205d4dedb982186336fd43d0e39acf020ea2563278bee0a063ceb3bf276f1251c099d8fcdd5098e7
 EBUILD notmuch-0.23.7.ebuild 4582 BLAKE2B 5e3d91233776f8bea407db340ad5ad083628f0d4d06849934e8dc78385acdb64bf2f9e1d804399636170f1524efc1b3d778a0ed5e4f2e32e01588b111947949f SHA512 abb5e69be4ee2405ec9e59683b040d7e6c2492403f3bff5d103cf2e957e9293a9f91b21a839d847e13f690b531c39b9e8df5eb6bf044e76ef26707800a47765e
 EBUILD notmuch-0.24.2.ebuild 4770 BLAKE2B 40bb192f400a0114976120b1b15294ce015d36637001e25a354aec5c686316e2045136091c71727ff003264be198780e132f7cce087310e5225a3a584d919a49 SHA512 d2a176d88df335783fcad6a397a44d6726c723f1d70fafafe986dadf138ba1410199a2b1347baf69d6589357c18931c1c9b791eb9437558ffb16afae9de3d654
 EBUILD notmuch-0.25.1.ebuild 4772 BLAKE2B 42b44d62a5a98be224f06a02573cd24397e05889d9a9d3f8aea67dcd56db2b869feccd457ae27dd1ab323e97a8e5e50ca9f3782c5c00887f884d8250a06f54b8 SHA512 19f4076e1415ff6498cabc8b900e589652b94b4cfb0cbee47b7c52eedca26b747df1a3f4157e2ba123c3a350b3c5cafd00e1635d100aff701a0e19bc9e325845
@@ -14,4 +15,5 @@ EBUILD notmuch-0.25.2.ebuild 4849 BLAKE2B f3feb24632beb2d89bcf32d89e4f00d5813e62
 EBUILD notmuch-0.25.3.ebuild 4849 BLAKE2B f3feb24632beb2d89bcf32d89e4f00d5813e62a1b6d5e8392458982e5d829dada98492cf778d46fe43d0df0618f7748d705d99f1c406683299c16f407b40c0d9 SHA512 76825642fd0d738345f2d9f2043d527c4d60d36b12cb5e44530af3190a9e7c760f1bd840744f8bec59b145a634d5207e7636413671b3914336acd881e0734623
 EBUILD notmuch-0.25.ebuild 4849 BLAKE2B f3feb24632beb2d89bcf32d89e4f00d5813e62a1b6d5e8392458982e5d829dada98492cf778d46fe43d0df0618f7748d705d99f1c406683299c16f407b40c0d9 SHA512 76825642fd0d738345f2d9f2043d527c4d60d36b12cb5e44530af3190a9e7c760f1bd840744f8bec59b145a634d5207e7636413671b3914336acd881e0734623
 EBUILD notmuch-0.26.1.ebuild 4843 BLAKE2B 1c44fad5564715905905f067ff901b93ab24acdfc1a15c12a86dd020ddd0c6da8b729b18d40ab390442417604736a69497bc254cbead3606fc1741a7a32dd08d SHA512 700c71470ba40612225b11fef08e69ad4f1056016bfab9714c132c9e4842edeb9e6b53b465ddbb7fb9927d00d68f84f10071b465153e4c6ad8c5f519470c0fe2
+EBUILD notmuch-0.26.2.ebuild 4843 BLAKE2B 1c44fad5564715905905f067ff901b93ab24acdfc1a15c12a86dd020ddd0c6da8b729b18d40ab390442417604736a69497bc254cbead3606fc1741a7a32dd08d SHA512 700c71470ba40612225b11fef08e69ad4f1056016bfab9714c132c9e4842edeb9e6b53b465ddbb7fb9927d00d68f84f10071b465153e4c6ad8c5f519470c0fe2
 MISC metadata.xml 1117 BLAKE2B 08710cbb42c20580235f5cfafa39715c33fb50de24cf98a182418db3c52ee1de5a1ee0e0775ae5756fee301c952995a1e7da52b9c13e5bd8c8b2fc0d1d74a5d2 SHA512 c420e475e5d16d35cceb1162c14eae143e5f539e771561d525af4ab0f0853e700b9a3209ee1a7aa9b4269c235737304c435d463cd8b1cf201402152ff0a6a4f3
diff --git a/net-mail/notmuch/notmuch-0.26.2.ebuild b/net-mail/notmuch/notmuch-0.26.2.ebuild
new file mode 100644
index 000000000000..bcf492e422d9
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.26.2.ebuild
@@ -0,0 +1,208 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
+	distutils-r1 toolchain-funcs
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="https://notmuchmail.org/"
+SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz
+	test? ( ${HOMEPAGE%/}/releases/test-databases/database-v1.tar.xz )"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y.  Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~x86 ~x64-solaris"
+REQUIRED_USE="
+	nmbug? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( crypt emacs python valgrind )
+	"
+IUSE="crypt doc emacs mutt nmbug python test valgrind"
+
+CDEPEND="
+	!!<app-shells/bash-completion-1.9
+	>=dev-libs/glib-2.22:2
+	>=dev-libs/gmime-2.6.21:2.6
+	>=dev-libs/xapian-1.2.7-r2:=
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	>=sys-libs/zlib-1.2.5.2
+	sys-libs/talloc
+	crypt? ( >=dev-libs/gmime-2.6.21:2.6[smime] )
+	emacs? ( >=virtual/emacs-23 )
+	python? ( ${PYTHON_DEPS} )
+	"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
+		>=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb
+		crypt? ( app-crypt/gnupg dev-libs/openssl ) )
+	valgrind? ( dev-util/valgrind )
+	"
+RDEPEND="${CDEPEND}
+	crypt? ( app-crypt/gnupg )
+	nmbug? ( dev-vcs/git )
+	mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
+		dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
+		virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
+		virtual/perl-Pod-Parser )
+	"
+
+DOCS=( AUTHORS NEWS README )
+SITEFILE="50${PN}-gentoo.el"
+MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
+
+bindings() {
+	local ret=0
+
+	if use $1; then
+		pushd bindings/$1 || die
+		shift
+		"$@"
+		ret=$?
+		popd || die
+	fi
+
+	return $ret
+}
+
+pkg_pretend() {
+	if has_version '<net-mail/notmuch-0.18'; then
+		ewarn
+		ewarn "There are few not backward compatible changes between"
+		ewarn "<notmuch-0.18 and >=notmuch-0.18.  See NEWS file"
+		ewarn "(0.18 section) for details before first use!"
+		ewarn
+	fi
+}
+
+pkg_setup() {
+	if use emacs; then
+		elisp-need-emacs 23 || die "Emacs version too low"
+	fi
+}
+
+src_unpack() {
+	unpack "${P}".tar.gz
+	if use test; then
+		mkdir -p "${S}"/test/test-databases || die
+		cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	bindings python distutils-r1_src_prepare
+	bindings python mv README README-python || die
+	mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+	# assure that new Makefile.config will be generated
+	rm -f Makefile.config || die
+
+	if use test; then
+		append-cflags -g
+		append-cxxflags -g
+	fi
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bashcompletiondir="$(get_bashcompdir)"
+		--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+		--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+		--without-desktop
+		--without-ruby
+		--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+		$(use_with emacs)
+		$(use_with doc api-docs)
+	)
+	tc-export CC CXX
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	V=1 default
+	bindings python distutils-r1_src_compile
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		emake notmuch-mutt.1
+		popd || die
+	fi
+
+	if use doc; then
+		pydocs() {
+			pushd docs || die
+			emake html
+			rm -r html/_sources || die
+			rm html/{objects.inv,.buildinfo} || die
+			mkdir -p ../html && mv html ../html/python || die
+			popd || die
+		}
+		LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
+	fi
+}
+
+src_test() {
+	pax-mark -m notmuch
+	LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" V=1 default
+	pax-mark -ze notmuch
+}
+
+src_install() {
+	default
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+	fi
+
+	if use nmbug; then
+		dobin devel/nmbug/nmbug
+		dobin devel/nmbug/notmuch-report
+	fi
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		dobin notmuch-mutt
+		doman notmuch-mutt.1
+		insinto /etc/mutt
+		doins notmuch-mutt.rc
+		dodoc README-mutt
+		popd || die
+	fi
+
+	DOCS="" bindings python distutils-r1_src_install
+	use doc && bindings python dodoc -r html
+}
+
+pkg_preinst() {
+	if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
+		elog "To enable notmuch support in mutt, add the following line into"
+		elog "your mutt config file, please:"
+		elog ""
+		elog "  source /etc/mutt/notmuch-mutt.rc"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+
+	if has_version '<dev-libs/xapian-1.4'; then
+		elog "Regular expression searches supported for from: and subject:"
+		elog "require >=dev-libs/xapian-1.4."
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}