gentoo resync : 08.01.2021

2 files changed, 278 insertions, 0 deletions

diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index 43a370a82051..4cc873adb7e4 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -4,10 +4,12 @@ DIST database-v1.tar.xz 204876 BLAKE2B 846a8d2f17edb61ed1c3d3c655becd1f60b404677
 DIST notmuch-0.29.3.tar.xz 660536 BLAKE2B bd5d62eba06102acbc0615cd97ac9ff5578c1f68d50b24a79ea9fb1ea77850d84e0713fb648cb04e74a61ac3321ea5ef82db714786adf38ea10d00c5846decff SHA512 b1e0b47ebf2d2de0ccd39976782eb8a7b417e36f2f9d78ef19e27e55719a02ee919508843a0eaf258f58138914ab2e8796d2fc1782b9cfe2d8937abb6184be65
 DIST notmuch-0.30.tar.xz 711904 BLAKE2B fb1523f3939b78797e448e804fc52c4fe1e4e8ff87b346917488d3911027b9ccb67b9fddf611f0e960fd1e158463cbe005e038f31bb54549e2a922926dd512bd SHA512 a5c812eb141c293c61b5483eafd31d3e3ab19b2c84429a1558986c415d30ead4afa79db64b2672e9549a40f5eb4c69e54ea5ccccbeeaeb9c783051c3f965a65e
 DIST notmuch-0.31.2.tar.xz 713388 BLAKE2B 20029f55206b66e7956316fca2d16ae53a49fc196ea2e730ae5ebd96ce893fa2065b7eee9b625629bbb0d3816a70d98e8943920cf8895ef81a97a1d8dc59dd62 SHA512 b134ef79648cb6fe9f17b2f1b600d651d57359ae9fa576c808b794aa64a09955f0597a624cc3c498da4ef56e44bca6bb485bc402c2dff48cd000959f9a9ceeaa
+DIST notmuch-0.31.3.tar.xz 713900 BLAKE2B 64aa5c707a74544d31f1dce4e49f3e19cf8c733dfe6f0761dec5522eae94bacf0c01ab7c8212373f1857eeecbad569482365a53a10f56dfee72cefc8d3f4f05a SHA512 99119216b7ef7f9e336b11d03ebb61d9667a8fbddcf6fccc49b17d07f07867f0342b2766375e164b58eaa9a43237ec4d6567d616fe8813b929d28b203aedfa44
 DIST notmuch-0.31.tar.xz 713144 BLAKE2B 91b0a01543e438e6ccb40a01ad0a100a5c6ae15fe832bb29367d4bc288dae5a915f89a743ecee814041caf53430e2593cb4b5f69faaec396ad6dacfe8cc67d2f SHA512 928acc07b9dbed4275e7d39d94202bea7685e9d433a7bf4c07e40e191ed4fe8cf15ac04c18792e46f4605ffac548b942998005d8176a58ad76c82d4085a408e5
 EBUILD notmuch-0.29.3-r2.ebuild 5062 BLAKE2B cdf68691f7dbc729d6c95dc974a3fb3b747a33d0b80338fc9b0474a970b78674628c242ce14af83b4d57eee1cba1f3c3d343dfcfffe2d8d0ee628f78b94f8767 SHA512 d76b455c44244eb1775604b0510f96c30aea175492ea4982d9a5b93d8601834a120286f29b8e41c6e694209a09be72727848e24bf5b8b3723729c2458095cc08
 EBUILD notmuch-0.30-r1.ebuild 4343 BLAKE2B f53eff50b205bffdb6016118997a5b5176a88ca704999e2b4f3bef4f107a79e7e89e68010fc35bd756aa8cbbe168f73700eba9b33ec8f1ce32a676b1b592e5da SHA512 bde0d770ca18d3c55c79be0b4e6fb360f61bf0f404397448fb311c1cf107b07b5f9633643a04a0e6615acd61934635845d1a2a47283795e3fd69c050939858b1
 EBUILD notmuch-0.31-r2.ebuild 6375 BLAKE2B 936a7e27bc21361d9692a36dd029d4ccbc28997dd4fda3c72c5ba5b79021be102a39efd6b5d95b4aa59fd008b2d07b5cbfaaef72b4ae31e08febc6b1c396a061 SHA512 6fd4ef53415e8c24b8fdc5ff8bffb548960f12c4b4cbdb001da1bb322604f05d059fd05ed7a90787f9209f1d9e61101ee7af5405b3be133b9efb29efc2ec14e0
 EBUILD notmuch-0.31.2.ebuild 6349 BLAKE2B fbb52800618b2f5771224803ae2bec343550aa0117ad6fb208e8805a7e605383eabf1229db8807fa26042214a7e82ad15a33aa001898a2dcb58bc013856fd39b SHA512 2365a6466da920adeed601a70c745dd9cc3562472a85768be50caf9d5f087f572d1e4ad0e659432a5e72af8fdf86d22ae9c28c03337e9341a4651d1fb5bf72ae
+EBUILD notmuch-0.31.3.ebuild 6389 BLAKE2B 648f57a0481a6d3a9b076eddcf9d594e515d61623b43ae4153802f16fa861b41ce4bcf728cada139eb52855b58669d326a23755212e12daba7f37d3823fd6712 SHA512 0c3b4b501b32b6fe35b3dd8c4f3a2608c2930005f39b280bedb65697b10691c5a0e9e420416c25809551b398a9b1f70fb69a3ab01b299d4e7723b900b068c34e
 EBUILD notmuch-0.31.ebuild 4460 BLAKE2B 21bea26e7e287937cd45a553abb14cb40420b2bb93886165533f6808d4734e594bd0184fb4b8dd6230b2264dc09f80dd89eeea70f678e7a56981e11f743c1121 SHA512 e12a5c8403c7f7e0ce32a1f002a4e6153b01df9436a517f692b18860a919aac83787a59ae6a00820b2d6fae7661a14a4f822d16b79c2e037f539afddfba04f62
 MISC metadata.xml 1288 BLAKE2B cc1d703a011971c9d6c89237847c84caeb83d1a6b62d95ee9cb1b0138919ea24cce578d7f55cdb749b448d6f2c9c77895285127d9c509532b5b58c66db2528a1 SHA512 68066c76c92534adb837ade1aa93a6e58f2d1b288e9cb75753af2c9dc1feac145be1976163b535f4bd5671f73f0dc93f204fe74ede74c10f081bba1d3be3d1dd
diff --git a/net-mail/notmuch/notmuch-0.31.3.ebuild b/net-mail/notmuch/notmuch-0.31.3.ebuild
new file mode 100644
index 000000000000..b769f25d2179
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.31.3.ebuild
@@ -0,0 +1,276 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+NEED_EMACS="24.1"
+PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
+
+inherit bash-completion-r1 desktop distutils-r1 elisp-common eutils flag-o-matic pax-utils toolchain-funcs xdg-utils
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="https://notmuchmail.org/"
+SRC_URI="https://notmuchmail.org/releases/${P}.tar.xz
+	test? ( https://notmuchmail.org/releases/test-databases/database-v1.tar.xz )"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y. Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc64 ~x86 ~x64-macos"
+REQUIRED_USE="
+	apidoc? ( doc )
+	nmbug? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( crypt emacs python valgrind )
+"
+IUSE="apidoc crypt doc emacs mutt nmbug python test valgrind"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	apidoc? (
+		app-doc/doxygen
+		dev-lang/perl
+	)
+	doc? (
+		dev-python/sphinx
+		sys-apps/texinfo
+	)
+	python? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+COMMON_DEPEND="
+	dev-libs/glib
+	dev-libs/gmime:3.0[crypt]
+	>=dev-libs/xapian-1.4.0:=
+	sys-libs/talloc
+	sys-libs/zlib:=
+	emacs? ( >=app-editors/emacs-${NEED_EMACS}:* )
+	python? (
+		${PYTHON_DEPS}
+		virtual/python-cffi[${PYTHON_USEDEP}]
+	)
+"
+
+DEPEND="${COMMON_DEPEND}
+	test? (
+		>=app-editors/emacs-${NEED_EMACS}:*[libxml2]
+		app-misc/dtach
+		sys-devel/gdb
+		crypt? (
+			app-crypt/gnupg
+			dev-libs/openssl
+		)
+	)
+	valgrind? ( dev-util/valgrind )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	crypt? ( app-crypt/gnupg )
+	mutt? (
+		dev-perl/File-Which
+		dev-perl/Mail-Box
+		dev-perl/MailTools
+		dev-perl/String-ShellQuote
+		dev-perl/Term-ReadLine-Gnu
+		virtual/perl-Digest-SHA
+		virtual/perl-File-Path
+		virtual/perl-Getopt-Long
+		virtual/perl-Pod-Parser
+	)
+	nmbug? ( dev-vcs/git )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_setup() {
+	use emacs && elisp-check-emacs-version
+}
+
+src_unpack() {
+	unpack "${P}".tar.xz
+	if use test; then
+		mkdir -p "${S}"/test/test-databases || die
+		cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	use python && distutils-r1_src_prepare
+
+	mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+	# Override 'install' target, we want to install manpages with doman, but let it install texinfo files.
+	sed -i "s/all install-man install-info/all $(usex doc install-info '')/" "Makefile.local" || die
+
+	use test && append-flags '-g'
+
+	# Non-autoconf configure
+	[[ ${CHOST} == *-solaris* ]] &&	append-ldflags '-lnsl' '-lsocket'
+}
+
+src_configure() {
+	python_setup # For sphinx
+
+	tc-export CC CXX
+
+	local myconf=(
+		--bashcompletiondir="$(get_bashcompdir)"
+		--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+		--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+		--without-desktop
+		--without-ruby
+		--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+		$(use_with apidoc api-docs)
+		$(use_with doc docs)
+		$(use_with emacs)
+	)
+
+	econf "${myconf[@]}"
+}
+
+python_compile() {
+	pushd bindings/python-cffi > /dev/null || die
+	distutils-r1_python_compile
+	popd > /dev/null || die
+
+	# TODO: we want to drop those, research revdeps
+	pushd bindings/python > /dev/null || die
+	distutils-r1_python_compile
+	popd > /dev/null || die
+}
+
+python_compile_all() {
+	use doc	&& emake -C bindings/python/docs html
+}
+
+src_compile() {
+	python_setup # For sphinx
+
+	# prevent race in emacs doc generation
+	# FileNotFoundError: [Errno 2] No such file or directory: '..work/notmuch-0.31/emacs/notmuch.rsti'
+	if use emacs; then
+		use doc && emake -j1 -C emacs docstring.stamp V=1 #nowarn
+	fi
+
+	emake V=1
+
+	use python && distutils-r1_src_compile
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt > /dev/null || die
+		emake notmuch-mutt.1
+		popd > /dev/null || die
+	fi
+}
+
+python_test() {
+	# we only have tests for cffi bindings
+	pushd bindings/python-cffi > /dev/null || die
+	rm -f tox.ini || die
+	pytest -vv || die "Tests failed with ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+src_test() {
+	local test_failures=()
+	# NOTMUCH_TEST_SERIALIZE is needed to avoid using gnu parallel (if it's installed)
+	pax-mark -m notmuch
+	NOTMUCH_TEST_SERIALIZE=1 \
+	LD_LIBRARY_PATH="${S}/lib" \
+		nonfatal emake test V=1 OPTIONS="--verbose --tee" || test_failures+=( "'emake tests'" )
+	pax-mark -ze notmuch
+
+	# both lib and bin needed for testsuite.
+	if use python; then
+		LD_LIBRARY_PATH="${S}/lib" \
+			PATH="${S}:${PATH}" \
+			nonfatal distutils-r1_src_test || test_failures+=( "'python tests'" )
+	fi
+
+	[[ ${test_failures} ]] && die "Tests failed: ${test_failures[@]}"
+}
+
+python_install() {
+	pushd bindings/python-cffi > /dev/null || die
+	distutils-r1_python_install
+	popd > /dev/null || die
+
+	pushd bindings/python > /dev/null || die
+	distutils-r1_python_install
+	popd > /dev/null || die
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		pushd doc/_build/man/man1 > /dev/null || die
+		ln notmuch.1 notmuch-setup.1 || die
+		popd > /dev/null || die
+		if use apidoc; then
+			# rename overly generic manpage to avoid clashes
+			mv doc/_build/man/man3/deprecated.3 \
+				doc/_build/man/man3/notmuch-deprecated.3 || die
+		fi
+		doman doc/_build/man/man?/*.?
+	fi
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+		domenu emacs/notmuch-emacs-mua.desktop
+	fi
+
+	if use nmbug; then
+		# TODO: those guys need proper deps
+		python_fix_shebang devel/nmbug/{nmbug,notmuch-report}
+		dobin devel/nmbug/{nmbug,notmuch-report}
+	fi
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt > /dev/null || die
+		dobin notmuch-mutt
+		# this manpage is built by pod2man
+		doman notmuch-mutt.1
+		insinto /etc/mutt
+		doins notmuch-mutt.rc
+		dodoc README-mutt
+		popd > /dev/null || die
+	fi
+
+	local DOCS=( README{,.rst} INSTALL NEWS )
+	einstalldocs
+
+	if use python; then
+		use doc && local HTML_DOCS=( bindings/python/docs/html/. )
+		distutils-r1_src_install
+	fi
+}
+
+pkg_preinst() {
+	local _rcfile="/etc/mutt/notmuch-mutt.rc"
+	if use mutt && ! [[ -e "${EROOT}"${_rcfile} ]]; then
+		elog "To enable notmuch support in mutt, add the following line"
+		elog "to your mutt config file:"
+		elog ""
+		elog "  source ${_rcfile}"
+	fi
+}
+
+pkg_postinst() {
+	if use emacs; then
+		elisp-site-regen
+		xdg_desktop_database_update
+	fi
+}
+
+pkg_postrm() {
+	if use emacs; then
+		elisp-site-regen
+		xdg_desktop_database_update
+	fi
+}