gentoo auto-resync : 01:09:2022 - 19:24:10

1 files changed, 42 insertions, 0 deletions

diff --git a/net-libs/libsearpc/libsearpc-3.2.0_p1.ebuild b/net-libs/libsearpc/libsearpc-3.2.0_p1.ebuild
new file mode 100644
index 000000000000..b9dac0542a45
--- /dev/null
+++ b/net-libs/libsearpc/libsearpc-3.2.0_p1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+# Upstream is moving tags repeatedly, then we use commit hash.
+RELEASE_COMMIT="54145b03f4240222e336a9a2f402e93facefde65" #tag v3.2_latest
+
+inherit autotools python-single-r1
+
+DESCRIPTION="A simple C language RPC framework"
+HOMEPAGE="https://github.com/haiwen/libsearpc/ http://seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/${RELEASE_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.26.0
+	>=dev-libs/jansson-2.2.1:="
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/simplejson[${PYTHON_USEDEP}]
+	')"
+
+S="${WORKDIR}/${PN}-${RELEASE_COMMIT}"
+
+src_prepare() {
+	default
+	sed -i -e "s/(DESTDIR)//" ${PN}.pc.in || die
+	eautoreconf
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files
+	find "${ED}" -name '*.la' -delete || die
+}