gentoo resync : 25.09.2021

1 files changed, 46 insertions, 0 deletions

diff --git a/net-libs/libnsl/libnsl-2.0.0-r1.ebuild b/net-libs/libnsl/libnsl-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..99b3fb7a8a12
--- /dev/null
+++ b/net-libs/libnsl/libnsl-2.0.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal preserve-libs
+
+DESCRIPTION="Public client interface for NIS(YP) in a IPv6 ready version"
+HOMEPAGE="https://github.com/thkukuk/libnsl"
+SRC_URI="https://github.com/thkukuk/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+# This is a core package which is depended on by e.g. PAM in some cases.
+# Please use preserve-libs.eclass in pkg_{pre,post}inst to cover users
+# with FEATURES="-preserved-libs" or another package manager if SONAME
+# changes.
+SLOT="0/3"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+DEPEND=">=net-libs/libtirpc-1.2.0:=[${MULTILIB_USEDEP}]"
+RDEPEND="${DEPEND}
+	!<sys-libs/glibc-2.26
+"
+
+multilib_src_configure() {
+	local myconf=(
+		--enable-shared
+		$(use_enable static-libs static)
+	)
+
+	ECONF_SOURCE=${S} econf "${myconf[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/libnsl.so.2
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/libnsl.so.2
+}