gentoo xmass resync : 25.12.2021

1 files changed, 87 insertions, 0 deletions

diff --git a/net-libs/ldns/ldns-1.8.1.ebuild b/net-libs/ldns/ldns-1.8.1.ebuild
new file mode 100644
index 000000000000..a81c575be2e7
--- /dev/null
+++ b/net-libs/ldns/ldns-1.8.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8,9,10} )
+inherit python-single-r1 multilib-minimal
+
+DESCRIPTION="a library with the aim to simplify DNS programming in C"
+HOMEPAGE="http://www.nlnetlabs.nl/projects/ldns/"
+SRC_URI="http://www.nlnetlabs.nl/downloads/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc examples python static-libs"
+
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+BDEPEND="
+	python? ( dev-lang/swig )
+	doc? ( app-doc/doxygen )
+"
+DEPEND="
+	python? ( ${PYTHON_DEPS} )
+	>=dev-libs/openssl-1.1.1l-r1:0=[${MULTILIB_USEDEP},static-libs?]
+	examples? ( net-libs/libpcap )
+"
+RDEPEND="${DEPEND}
+	!<net-dns/ldns-utils-1.8.0-r2
+"
+
+RESTRICT="test" # missing test directory
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/ldns-config
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/ldns-1.8.1-pkgconfig.patch"
+	)
+	default
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_with python pyldns) \
+		$(multilib_native_use_with python pyldnsx) \
+		--with-ssl="${EPREFIX}"/usr \
+		$(multilib_native_with drill) \
+		$(multilib_native_use_with examples) \
+		--disable-rpath
+}
+
+multilib_src_compile() {
+	default
+
+	if multilib_is_native_abi && use doc ; then
+		emake doxygen
+	fi
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi && use doc ; then
+		dodoc -r doc/html
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc Changelog README*
+
+	find "${D}" -name '*.la' -delete || die
+	use python && python_optimize
+
+	insinto /usr/share/vim/vimfiles/ftdetect
+	doins libdns.vim
+}