gentoo resync : 24.12.2018

2 files changed, 150 insertions, 0 deletions

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index a5a4aeb0d8f6..c23ce0ee2abe 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,6 +1,8 @@
 DIST kvirc-5.0_pre20180819121252.tar.gz 6049652 BLAKE2B b4712e089a26498a7a3e4df10fe0def377814a9cc4082f55c2177da4929bc2fb02fbc947ee0603b62175a5cee657f6316ca246a275e96df71bd9d938453d4604 SHA512 de7ccb0f698488599ba3f58ca46ef2427632bdf1870d576baea8634e530cbe7654f60d4cdd58447301c4401941ef8b4e810f4d3eb4d6468a2899b80484380ea7
 DIST kvirc-5.0_pre20181013192652.tar.gz 5961689 BLAKE2B 9ee5536688e5e193b88e6425591d309396cd1c135622fd682fcc86e832ee72010493877d33bddd3a86bf6c18d34b252e6a4689f7001252e149eefbfd100da977 SHA512 1856f3fab772f04e01e6a367e101bdde0732c4439399f821cd50ffd4173b89de023e1da20327692387b3f002bda0f0880737a6f5f001e0112ae45e1257b0db24
+DIST kvirc-5.0_pre20181205184837.tar.gz 5968276 BLAKE2B eb1c2a38cedbae3f7e7951bdd4250e349d8c6745a24df30f81ccebf8fa0ac9bdca27f835b0d2bda261baff81d018eae58c5169656791f4436ff221cba7890e85 SHA512 fbfcf1b1bcd9dfb1207669ee61a7fa8023ceeb2b679e95c378ed1224020c901fb4a6b68b7505704874e935df2228be4ccfd36121a87aafc5ace41c5392058132
 EBUILD kvirc-5.0_pre20180819121252.ebuild 3838 BLAKE2B c2bbe3f8ae2479d18b887207ab70cc2799004987052232e2e1e23674b0539fc90fdbb3854b9169d3f770561e9e75340caf280bc8515a2668d69c9b46607b6d8f SHA512 d34667e43f9efee5b9d835afb8f2aab0376d80bd9b2d4bd055b2af3886effaaf62d5ec1b98e723c318db539d1068012047b7b7ffe1d463a917ace14f96eee13d
 EBUILD kvirc-5.0_pre20181013192652.ebuild 3838 BLAKE2B 092d287a6db4c94e03203d2b75fcd1848c66ecd27098d3221a144f24e92dd27672670e69044cea1b726f2b559f63ce4818a92e949907208122d708764c9fa43b SHA512 71cb533d92cfa5b787f9963dd65fa82345a7612f1b3ec7402cf0f396e90a890cf3c2ba9244578455ec087df42d34273dc9e06e9a974eebb50516ba2889996877
+EBUILD kvirc-5.0_pre20181205184837.ebuild 3840 BLAKE2B c4b856b8bb86ada99ff408f24f09cc0dad909f9bd8b13018f5fd3e7afb9658c2125b9dc97fe39dc54bcc9da7cf40004da9d7e15f522cb8099bdcf04f83dcf3ef SHA512 a145fa0e65293defc3babda017fb5b51db7cf96b0f0acb018a2bb20988f7564bb8c779a6e8cc9b50cb057e4c2dcad7c7a347fd85eaa23a564e2228382dbd9567
 EBUILD kvirc-9999.ebuild 3777 BLAKE2B 1fd03974614fb4b6c2bdec28d7a836ad8cbc242741ae143be2db1915b3f5724c5cb0f62e61ac5b55501fd1252b88f11aaff3115e5a58800bb1434d274eff8193 SHA512 e666615ce16b7a42fc9a638fe95decb92fa0a26c2abe78ed8264802123de090a46095d6770b98fa18ecd3d2e5dbae6b4187a8d4b641269713a9c6f0140a886f1
 MISC metadata.xml 618 BLAKE2B 5a6a28876a22cedbca154051a389fed0e7ef25039319786ed2303b580b1e421b648038237e0157678fb96e1b45839e725299e56584bcb770593f60f305932145 SHA512 af08ad67affb8dbe4ae6afbb2a251e5bd44e5fb30f9332dddebbb6dd504fa25b449b5b4c3a5c1f0337c6a7751b2395eb049cf94206a44cce2a7ab1df1d1b3eae
diff --git a/net-irc/kvirc/kvirc-5.0_pre20181205184837.ebuild b/net-irc/kvirc/kvirc-5.0_pre20181205184837.ebuild
new file mode 100644
index 000000000000..9423a1c8ccd7
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.0_pre20181205184837.ebuild
@@ -0,0 +1,148 @@
+# Copyright 2009-2018 Arfrever Frehtes Taifersar Arahesis
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=(python2_7)
+
+inherit cmake-utils flag-o-matic gnome2-utils python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	inherit vcs-snapshot
+
+	KVIRC_GIT_REVISION="f06b4f0397fa7feb23713e4fe4c00759d2cced71"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="kvirc"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon[qt5(+)] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant:0= )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	gsm? ( media-sound/gsm )"
+
+DOCS=()
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=yes
+		-DWANT_VERBOSE=yes
+
+		-DWANT_CRYPT=yes
+		-DWANT_DCC_VOICE=yes
+		-DWANT_IPC=yes
+		-DWANT_IPV6=yes
+		-DWANT_TRANSPARENCY=yes
+
+		-DWANT_AUDIOFILE=$(usex audiofile)
+		-DWANT_DCC_VIDEO=$(usex dcc_video)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_DOXYGEN=$(usex doc)
+		-DWANT_GETTEXT=$(usex nls)
+		-DWANT_GSM=$(usex gsm)
+		-DWANT_KDE=$(usex kde)
+		-DWANT_MEMORY_PROFILE=$(usex profile)
+		-DWANT_OGG_THEORA=$(usex theora)
+		-DWANT_OPENSSL=$(usex ssl)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PERL=$(usex perl)
+		-DWANT_PHONON=$(usex phonon)
+		-DWANT_PYTHON=$(usex python)
+		-DWANT_QTDBUS=$(usex dbus)
+		-DWANT_QTWEBKIT=$(usex webkit)
+		-DWANT_SPELLCHECKER=$(usex spell)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=no
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}