gentoo resync : 03.07.2021

5 files changed, 191 insertions, 12 deletions

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index 3652afa650ba..143b71b7df01 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,4 +1,6 @@
 DIST kvirc-5.2_pre20200605155236.tar.gz 6170072 BLAKE2B 2652bcae16263615ccbf494d8265a1ecf997525dbfa70d4ace0c3f6ae58231ce575dfe444a60e2751bb7741445bf44297fafb260c05bad6d637f8dc89eb254b4 SHA512 84499fe13337f114587ff267d5e85e39ef61d99e88c84cfc9f0341a5db2e17b50d644bf8483de420c3629f073d6e3eeb81e25de357a723f54e39f154cb4b7da1
-EBUILD kvirc-5.2_pre20200605155236-r1.ebuild 4701 BLAKE2B 6a4f172adfbaf392deea9b8278bf4c72a632fab5f8b6a17510b035e728bce0511f903cf6ce282d706a1ff5162ce5014e9787fa530c6c87f8c3e28ce2f154a966 SHA512 9d2ad051316f3a129b527b8ba58a2c2f8faea808ec23055703037225f46c3609f46e1e099c069d046e143416898413952bcb2a9877c29eed6e4147603c1a661c
-EBUILD kvirc-9999.ebuild 4326 BLAKE2B 8bec9ae6434f0378b4f01814bf927dcf1bbdeb2906fb5f4bfc26fc068105df93cbea0803aeb95cf92077c001e0ff932f01d599240e8f50777369b34a5c831f13 SHA512 fc701d0994a82a6b5c8004a36cf4ccd6e0cb93ebd361d678baf8645436eb2618fa86bf74e0aea1ae5c6d55cb92abe02d330ea3903c7f1345da11bb818bb6de3c
-MISC metadata.xml 638 BLAKE2B 66f7c48cfa5e35db6763821efcf483ca829d50e9b534076fbefb209e6c3c46880b2c110d2305a4bc1e6580781e4ef5fb646e83a23a3fbf609801a84c0ddbc108 SHA512 68853129b4bf5b62be097022091d3402eaa33da641483f666c05e6eaae195f1b6672bf18313b0f98155aa16a4429d543d2885a04e7ea008065cb7d9e2bdda9e8
+DIST kvirc-5.2_pre20210630233331.tar.gz 6173417 BLAKE2B dcdb5fed3250de08d8e2896ba799e142ee04fff409006d7b7d06bdcf1cf2f6df9f7abeeb055e550d99f9cca6182d68b4f5b9ff224f78d91b1efb7f42118458e5 SHA512 625712cc69a2ab3a33b72b2e9935bec8f307ef1f8d5a9a0672d7eb8e7daa5ab3e6202a2b8932493c30374f0451821db161e47cb3af840c0324e27ca2e58272ef
+EBUILD kvirc-5.2_pre20200605155236-r1.ebuild 4697 BLAKE2B 784afc228a3ae0cd17a693b8c0f310fc282e68288b421e6fe7adfa53bfdb53696f616f2217bed8e601dc9c0d84c072be18783472cba7cd94da202f7b32e42aa4 SHA512 c3fdb6fb8bab951a787dcb40010eb3cbb868941abb16c64460db0cf7131586ddc551436aa432a9fb37b1320425077044ef9c323f58eaa0633d3d53bf36e8a071
+EBUILD kvirc-5.2_pre20210630233331.ebuild 4385 BLAKE2B f2da5634a15e6762af628324d8f8a0d86589d845d175fbf10e02bef8182081a79dfde26c5161b8637eb336b1c88c04170febef5e35ef3ff60014c9bd83e5c95f SHA512 545e94d07f2b450508c90ec7ee1a84cc3503d3afece0bca8273e28da2d2713ef282c38785a30082e2f91bb622fea861dfd396c78ef823cc78ff5515b97049b34
+EBUILD kvirc-9999.ebuild 4322 BLAKE2B 6d56fd720c48322b592fdc8d016900f2ebfac4c13b4ece9790aef2022e7b628c1ab2ca4e868fb2abb7b80f0d7496bd7a0da8e157180d78577d29cf6dcd09bba3 SHA512 e173009ac0d28e8d78fabeb2cd871af5e76c1443c80083b5959208fd22ba8a4dada7360c8ec836d45caa9b1347c97f99e51058da9b748970d7bd414428b7c0c1
+MISC metadata.xml 638 BLAKE2B 826b6313262009d9f59123268c64bf9dbf483a15d517ef8eac920cdf90079c4cd5fd16f54aa6c0de1ca2bdc4373534507ed07a3de9c4eaf5cfa1a134f1db02e7 SHA512 eaff2974be880f79976afb0115df513e717768ed5080dc9a824001c214ac42e8b8e9931994d49f8608ddd1ec47eb9ddc7aad8279f5fc04358af2f31feb8255a0
diff --git a/net-irc/kvirc/kvirc-5.2_pre20200605155236-r1.ebuild b/net-irc/kvirc/kvirc-5.2_pre20200605155236-r1.ebuild
index d5d66657bf4e..c92018013e98 100644
--- a/net-irc/kvirc/kvirc-5.2_pre20200605155236-r1.ebuild
+++ b/net-irc/kvirc/kvirc-5.2_pre20200605155236-r1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI="7"
 CMAKE_MAKEFILE_GENERATOR="emake"
-PYTHON_COMPAT=(python{3_7,3_8,3_9})
+PYTHON_COMPAT=(python{3_8,3_9})
 
 inherit cmake flag-o-matic python-single-r1 xdg-utils
 
@@ -30,7 +30,7 @@ fi
 LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="amd64 ~ppc ~ppc64 x86"
-IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+IUSE="audiofile +dbus dcc-video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
 REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
 
 BDEPEND="dev-lang/perl:0
@@ -53,7 +53,7 @@ DEPEND="dev-qt/qtcore:5
 	x11-libs/libXScrnSaver
 	audiofile? ( media-libs/audiofile )
 	dbus? ( dev-qt/qtdbus:5 )
-	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	dcc-video? ( dev-qt/qtmultimedia:5[widgets] )
 	kde? (
 		kde-frameworks/kcoreaddons:5
 		kde-frameworks/ki18n:5
@@ -121,7 +121,7 @@ src_configure() {
 		-DWANT_TRANSPARENCY=ON
 
 		-DWANT_AUDIOFILE=$(usex audiofile ON OFF)
-		-DWANT_DCC_VIDEO=$(usex dcc_video ON OFF)
+		-DWANT_DCC_VIDEO=$(usex dcc-video ON OFF)
 		-DWANT_DEBUG=$(usex debug ON OFF)
 		-DWANT_DOXYGEN=$(usex doc ON OFF)
 		-DWANT_GETTEXT=$(usex nls ON OFF)
diff --git a/net-irc/kvirc/kvirc-5.2_pre20210630233331.ebuild b/net-irc/kvirc/kvirc-5.2_pre20210630233331.ebuild
new file mode 100644
index 000000000000..06907a5543b4
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.2_pre20210630233331.ebuild
@@ -0,0 +1,177 @@
+# Copyright 2009-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=(python{3_8,3_9})
+
+inherit cmake flag-o-matic python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	KVIRC_GIT_REVISION="d86b79f657bb7388d7ec1d3e0d91e7c4221c2394"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc-video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="dev-lang/perl:0
+	>=dev-util/cmake-3.16
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+DEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc-video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon[qt5(+)] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant:0= )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+RDEPEND="${DEPEND}
+	gsm? ( media-sound/gsm )"
+
+if [[ "${PV}" != "9999" ]]; then
+	S="${WORKDIR}/KVIrc-${KVIRC_GIT_REVISION}"
+fi
+
+DOCS=()
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=ON
+		-DWANT_VERBOSE=ON
+
+		-DWANT_CRYPT=ON
+		-DWANT_DCC_VOICE=ON
+		-DWANT_IPC=ON
+		-DWANT_IPV6=ON
+		-DWANT_TRANSPARENCY=ON
+
+		-DWANT_AUDIOFILE=$(usex audiofile ON OFF)
+		-DWANT_DCC_VIDEO=$(usex dcc-video ON OFF)
+		-DWANT_DEBUG=$(usex debug ON OFF)
+		-DWANT_DOXYGEN=$(usex doc ON OFF)
+		-DWANT_GETTEXT=$(usex nls ON OFF)
+		-DWANT_GSM=$(usex gsm ON OFF)
+		-DWANT_KDE=$(usex kde ON OFF)
+		-DWANT_MEMORY_PROFILE=$(usex profile ON OFF)
+		-DWANT_OGG_THEORA=$(usex theora ON OFF)
+		-DWANT_OPENSSL=$(usex ssl ON OFF)
+		-DWANT_OSS=$(usex oss ON OFF)
+		-DWANT_PERL=$(usex perl ON OFF)
+		-DWANT_PHONON=$(usex phonon ON OFF)
+		-DWANT_PYTHON=$(usex python ON OFF)
+		-DWANT_QTDBUS=$(usex dbus ON OFF)
+		-DWANT_QTWEBKIT=$(usex webkit ON OFF)
+		-DWANT_SPELLCHECKER=$(usex spell ON OFF)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=OFF
+	)
+	if use python; then
+		mycmakeargs+=(
+			-DPython3_INCLUDE_DIR="$(python_get_includedir)"
+			-DPython3_LIBRARY="$(python_get_library_path)"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		cmake_src_compile devdocs
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		(
+			docinto html
+			dodoc -r "${BUILD_DIR}/doc/api/html/"*
+		)
+	fi
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/net-irc/kvirc/kvirc-9999.ebuild b/net-irc/kvirc/kvirc-9999.ebuild
index d73b347ff47d..2393d5ae4c23 100644
--- a/net-irc/kvirc/kvirc-9999.ebuild
+++ b/net-irc/kvirc/kvirc-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI="7"
 CMAKE_MAKEFILE_GENERATOR="emake"
-PYTHON_COMPAT=(python{3_7,3_8,3_9})
+PYTHON_COMPAT=(python{3_8,3_9})
 
 inherit cmake flag-o-matic python-single-r1 xdg-utils
 
@@ -30,7 +30,7 @@ fi
 LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS=""
-IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+IUSE="audiofile +dbus dcc-video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
 REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
 
 BDEPEND="dev-lang/perl:0
@@ -53,7 +53,7 @@ DEPEND="dev-qt/qtcore:5
 	x11-libs/libXScrnSaver
 	audiofile? ( media-libs/audiofile )
 	dbus? ( dev-qt/qtdbus:5 )
-	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	dcc-video? ( dev-qt/qtmultimedia:5[widgets] )
 	kde? (
 		kde-frameworks/kcoreaddons:5
 		kde-frameworks/ki18n:5
@@ -117,7 +117,7 @@ src_configure() {
 		-DWANT_TRANSPARENCY=ON
 
 		-DWANT_AUDIOFILE=$(usex audiofile ON OFF)
-		-DWANT_DCC_VIDEO=$(usex dcc_video ON OFF)
+		-DWANT_DCC_VIDEO=$(usex dcc-video ON OFF)
 		-DWANT_DEBUG=$(usex debug ON OFF)
 		-DWANT_DOXYGEN=$(usex doc ON OFF)
 		-DWANT_GETTEXT=$(usex nls ON OFF)
diff --git a/net-irc/kvirc/metadata.xml b/net-irc/kvirc/metadata.xml
index c447f818e684..9636c611569e 100644
--- a/net-irc/kvirc/metadata.xml
+++ b/net-irc/kvirc/metadata.xml
@@ -10,7 +10,7 @@
 		<name>Mike Gilbert</name>
 	</maintainer>
 	<use>
-		<flag name="dcc_video">Support video connections over DCC protocol</flag>
+		<flag name="dcc-video">Support video connections over DCC protocol</flag>
 		<flag name="phonon">Support Phonon for audio output</flag>
 	</use>
 	<upstream>