gentoo resync : 22.06.2019

1 files changed, 63 insertions, 0 deletions

diff --git a/net-im/telegram-desktop-bin/telegram-desktop-bin-1.7.7.ebuild b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.7.7.ebuild
new file mode 100644
index 000000000000..55d80d8203c1
--- /dev/null
+++ b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.7.7.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop xdg
+
+DESCRIPTION="Official desktop client for Telegram (binary package)"
+HOMEPAGE="https://desktop.telegram.org"
+SRC_URI="
+	https://github.com/telegramdesktop/tdesktop/archive/v${PV}.tar.gz -> tdesktop-${PV}.tar.gz
+	amd64? ( https://github.com/telegramdesktop/tdesktop/releases/download/v${PV}/tsetup.${PV}.tar.xz )
+	x86? ( https://github.com/telegramdesktop/tdesktop/releases/download/v${PV}/tsetup32.${PV}.tar.xz )
+"
+
+LICENSE="GPL-3-with-openssl-exception"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+
+QA_PREBUILT="usr/lib/${PN}/Telegram"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=media-libs/fontconfig-2.13
+	>=sys-apps/dbus-1.4.20
+	x11-libs/libX11
+	>=x11-libs/libxcb-1.10[xkb]
+"
+
+S="${WORKDIR}/Telegram"
+
+src_install() {
+	exeinto /usr/lib/${PN}
+	doexe "Telegram"
+	newbin "${FILESDIR}"/${PN} "telegram-desktop"
+
+	local icon_size
+	for icon_size in 16 32 48 64 128 256 512; do
+		newicon -s "${icon_size}" \
+			"${WORKDIR}/tdesktop-${PV}/Telegram/Resources/art/icon${icon_size}.png" \
+			telegram.png
+	done
+
+	domenu "${WORKDIR}/tdesktop-${PV}"/lib/xdg/telegramdesktop.desktop
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	einfo
+	einfo "Previous versions of ${PN} have created "
+	einfo "\"~/.local/share/applications/telegram.desktop\". These files"
+	einfo "conflict with the one shipped by portage and should be removed"
+	einfo "from all homedirs. (https://bugs.gentoo.org/618662)"
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}