gentoo resync : 18.12.2020

3 files changed, 209 insertions, 2 deletions

diff --git a/net-dns/unbound/Manifest b/net-dns/unbound/Manifest
index f189ab432992..9042801d716b 100644
--- a/net-dns/unbound/Manifest
+++ b/net-dns/unbound/Manifest
@@ -15,5 +15,6 @@ EBUILD unbound-1.10.1-r1.ebuild 5424 BLAKE2B 85fe1509a5c82edf8985ce6cfa80325db99
 EBUILD unbound-1.11.0.ebuild 6003 BLAKE2B 5e92333ca334d085b994fd9dcfc4b9eb97c0355b130472dd434b6a892bcde8439ae33f4413f8aa5e9e6867891750e152c28892a88f9d88e5848f20ebcee459b0 SHA512 4d6061372950b54091b0fae9c1e2d8eb93b75a60a081d0f8431239457bd5311bdb78109f55e08779c50cab4a8bc0f07281f95d51b8b1dd83f4eac03b40b6e2b7
 EBUILD unbound-1.12.0-r1.ebuild 6075 BLAKE2B 06c59fcad9b6351fdca6d0f7f5e71a2802005ade6c9f285a8a0b52a3158084638c698831c9b61158582f48223e22b48eddc300780dad2e7c8cee8f78887d1f91 SHA512 422b16aadcd2b8f38f03cd2fe8c22dff94bac532ad837bc1f81c1c2a3cddafccacc7fca70b41f7debb8ece6a04660a8f1e4b78a2ae18180e8ea4f475e8c21335
 EBUILD unbound-1.12.0.ebuild 6008 BLAKE2B dd27e2b8d4d1c320af8e268ae5f0d9f95d26782137bfb11deebe44533904da8716d894bfacdcd3bbd187c0d1d52d9e6a57a330f75ced2cb3d1b802f705bc352e SHA512 df2940e7037f61717bc8c53a6ce386d189b4bffbb4a8881074798718087ab78e10e5c840070f629432f2ca328727b585ba2695703f9572ba5913fe8ad461d415
-EBUILD unbound-1.13.0.ebuild 6075 BLAKE2B 06c59fcad9b6351fdca6d0f7f5e71a2802005ade6c9f285a8a0b52a3158084638c698831c9b61158582f48223e22b48eddc300780dad2e7c8cee8f78887d1f91 SHA512 422b16aadcd2b8f38f03cd2fe8c22dff94bac532ad837bc1f81c1c2a3cddafccacc7fca70b41f7debb8ece6a04660a8f1e4b78a2ae18180e8ea4f475e8c21335
+EBUILD unbound-1.13.0-r1.ebuild 6123 BLAKE2B b415d7c63e1354bad6811412a05412e0d848ec18e6ba72bfb92f26f537ec6338f4c8423e899fc26dfa058f083a51810c4af9e34a5f549f0735c130683fdeda7e SHA512 2cd8aa239ec804e9690c59b61be0c3a45303783e4c7944cf498dad204a1c073fd77396172733186f120fa0ff7c2640798262ffcf9c805201e967df0783be589f
+EBUILD unbound-1.13.0.ebuild 6073 BLAKE2B d579436b4f1ec822d0f03fe1278a9ad2ce4286dd6a302c0b9f325274d9360ea6c2fa876ce0ed9b2bf67d4abaa83eec6ac60c0d1844538b99d92116619bbabbfb SHA512 163016e35575a4e5c14866a57da1f6181f53350a7bf895979f9e837ad0d2f8bd72b00b7317ca941fecf5cc0fe8709c3ec9903e458695684bbbc15067c8e6e2cb
 MISC metadata.xml 1444 BLAKE2B ff1a69e8795fc834ba6b365ee389743bc8d2a2e82375a07c757ad6fcf5cad4cbfec321bba6ce4f8e505414a5cdce09e8257f97eb1fe199bc1fb911a769f7a6b5 SHA512 a96d5847589f861d2d3e7a416e5af0dafc0940a60f997456bf6a3a9c09e3e2910a8fe9474474e81b907cd9093525125539ad93345f84dbf6d10454a3aa5cbf4f
diff --git a/net-dns/unbound/unbound-1.13.0-r1.ebuild b/net-dns/unbound/unbound-1.13.0-r1.ebuild
new file mode 100644
index 000000000000..daaba00dd008
--- /dev/null
+++ b/net-dns/unbound/unbound-1.13.0-r1.ebuild
@@ -0,0 +1,206 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit autotools flag-o-matic multilib-minimal python-single-r1 systemd
+
+MY_P=${PN}-${PV/_/}
+DESCRIPTION="A validating, recursive and caching DNS resolver"
+HOMEPAGE="https://unbound.net/ https://nlnetlabs.nl/projects/unbound/about/"
+SRC_URI="https://nlnetlabs.nl/downloads/unbound/${MY_P}.tar.gz"
+
+LICENSE="BSD GPL-2"
+SLOT="0/8" # ABI version of libunbound.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~x86"
+IUSE="debug dnscrypt dnstap +ecdsa ecs gost +http2 libressl python redis selinux static-libs systemd test threads"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+# Note: expat is needed by executable only but the Makefile is custom
+# and doesn't make it possible to easily install the library without
+# the executables. MULTILIB_USEDEP may be dropped once build system
+# is fixed.
+
+CDEPEND="acct-group/unbound
+	acct-user/unbound
+	>=dev-libs/expat-2.1.0-r3[${MULTILIB_USEDEP}]
+	>=dev-libs/libevent-2.0.21:0=[${MULTILIB_USEDEP}]
+	libressl? ( >=dev-libs/libressl-2.2.4:0[${MULTILIB_USEDEP}] )
+	!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
+	dnscrypt? ( dev-libs/libsodium[${MULTILIB_USEDEP}] )
+	dnstap? (
+		dev-libs/fstrm[${MULTILIB_USEDEP}]
+		>=dev-libs/protobuf-c-1.0.2-r1[${MULTILIB_USEDEP}]
+	)
+	ecdsa? (
+		!libressl? ( dev-libs/openssl:0[-bindist] )
+	)
+	http2? ( net-libs/nghttp2 )
+	python? ( ${PYTHON_DEPS} )
+	redis? ( dev-libs/hiredis:= )"
+
+BDEPEND="virtual/pkgconfig"
+
+DEPEND="${CDEPEND}
+	python? ( dev-lang/swig )
+	test? (
+		net-dns/ldns-utils[examples]
+		dev-util/splint
+		app-text/wdiff
+	)
+	systemd? ( sys-apps/systemd )"
+
+RDEPEND="${CDEPEND}
+	net-dns/dnssec-root
+	selinux? ( sec-policy/selinux-bind )"
+
+# bug #347415
+RDEPEND="${RDEPEND}
+	net-dns/dnssec-root"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5.7-trust-anchor-file.patch
+	"${FILESDIR}"/${PN}-1.6.3-pkg-config.patch
+	"${FILESDIR}"/${PN}-1.10.1-find-ar.patch
+)
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	# required for the python part
+	multilib_copy_sources
+}
+
+src_configure() {
+	[[ ${CHOST} == *-darwin* ]] || append-ldflags -Wl,-z,noexecstack
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable gost) \
+		$(use_enable dnscrypt) \
+		$(use_enable dnstap) \
+		$(use_enable ecdsa) \
+		$(use_enable ecs subnet) \
+		$(multilib_native_use_enable redis cachedb) \
+		$(use_enable static-libs static) \
+		$(use_enable systemd) \
+		$(multilib_native_use_with python pythonmodule) \
+		$(multilib_native_use_with python pyunbound) \
+		$(use_with threads pthreads) \
+		$(use_with http2 libnghttp2) \
+		--disable-flto \
+		--disable-rpath \
+		--enable-event-api \
+		--enable-ipsecmod \
+		--enable-tfo-client \
+		--enable-tfo-server \
+		--with-libevent="${EPREFIX}"/usr \
+		$(multilib_native_usex redis --with-libhiredis="${EPREFIX}/usr" --without-libhiredis) \
+		--with-pidfile="${EPREFIX}"/run/unbound.pid \
+		--with-rootkey-file="${EPREFIX}"/etc/dnssec/root-anchors.txt \
+		--with-ssl="${EPREFIX}"/usr \
+		--with-libexpat="${EPREFIX}"/usr
+
+		# http://unbound.nlnetlabs.nl/pipermail/unbound-users/2011-April/001801.html
+		# $(use_enable debug lock-checks) \
+		# $(use_enable debug alloc-checks) \
+		# $(use_enable debug alloc-lite) \
+		# $(use_enable debug alloc-nonregional) \
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	systemd_dounit contrib/unbound.service
+	systemd_dounit contrib/unbound.socket
+}
+
+multilib_src_install_all() {
+	use python && python_optimize
+
+	newinitd "${FILESDIR}"/unbound-r1.initd unbound
+	newconfd "${FILESDIR}"/unbound-r1.confd unbound
+
+	systemd_newunit "${FILESDIR}"/unbound_at.service "unbound@.service"
+	systemd_dounit "${FILESDIR}"/unbound-anchor.service
+
+	dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES}
+
+	# bug #315519
+	dodoc contrib/unbound_munin_
+
+	docinto selinux
+	dodoc contrib/selinux/*
+
+	exeinto /usr/share/${PN}
+	doexe contrib/update-anchor.sh
+
+	# create space for auto-trust-anchor-file...
+	keepdir /etc/unbound/var
+	fowners root:unbound /etc/unbound/var
+	fperms 0770 /etc/unbound/var
+	# ... and point example config to it
+	sed -i \
+		-e '/# auto-trust-anchor-file:/s,/etc/dnssec/root-anchors.txt,/etc/unbound/var/root-anchors.txt,' \
+		"${ED}/etc/unbound/unbound.conf" \
+		|| die
+
+	# Used to store cache data
+	keepdir /var/lib/${PN}
+	fowners root:unbound /var/lib/${PN}
+	fperms 0770 /var/lib/${PN}
+
+	find "${ED}" -name '*.la' -delete || die
+	if ! use static-libs ; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}
+
+pkg_postinst() {
+	if [[ ! -f "${EROOT}/etc/unbound/unbound_control.key" ]] ; then
+		einfo "Trying to create unbound control key ..."
+		if ! unbound-control-setup &>/dev/null ; then
+			ewarn "Failed to create unbound control key!"
+		fi
+	fi
+
+	if [[ ! -f "${EROOT}/etc/unbound/var/root-anchors.txt" ]] ; then
+		einfo ""
+		einfo "If you want unbound to automatically update the root-anchor file for DNSSEC validation"
+		einfo "set 'auto-trust-anchor-file: ${EROOT}/etc/unbound/var/root-anchors.txt' in ${EROOT}/etc/unbound/unbound.conf"
+		einfo "and run"
+		einfo ""
+		einfo "  su -s /bin/sh -c '${EROOT}/usr/sbin/unbound-anchor -a ${EROOT}/etc/unbound/var/root-anchors.txt' unbound"
+		einfo ""
+		einfo "as root to create it initially before starting unbound for the first time after enabling this."
+		einfo ""
+	fi
+
+	# Our user is not available on prefix
+	use prefix && return
+
+	local _perm_check_testfile=$(mktemp --dry-run "${EPREFIX}"/etc/unbound/var/.pkg_postinst-perm-check.XXXXXXXXX)
+	su -s /bin/sh -c "touch ${_perm_check_testfile}" unbound &>/dev/null
+	if [ $? -ne 0 ] ; then
+		ewarn "WARNING: unbound user cannot write to \"${EPREFIX}/etc/unbound/var\"!"
+		ewarn "Run the following commands to restore default permission:"
+		ewarn ""
+		ewarn "    chown root:unbound ${EPREFIX}/etc/unbound/var"
+		ewarn "    chmod 0770 ${EPREFIX}/etc/unbound/var"
+	else
+		# Cleanup -- no reason to die here!
+		rm -f "${_perm_check_testfile}"
+	fi
+}
diff --git a/net-dns/unbound/unbound-1.13.0.ebuild b/net-dns/unbound/unbound-1.13.0.ebuild
index b899f7ff0e35..a63ec2835321 100644
--- a/net-dns/unbound/unbound-1.13.0.ebuild
+++ b/net-dns/unbound/unbound-1.13.0.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://nlnetlabs.nl/downloads/unbound/${MY_P}.tar.gz"
 
 LICENSE="BSD GPL-2"
 SLOT="0/8" # ABI version of libunbound.so
-KEYWORDS="~alpha ~amd64 arm ~arm64 ~hppa ~mips ~ppc ~ppc64 x86"
+KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~mips ppc ~ppc64 x86"
 IUSE="debug dnscrypt dnstap +ecdsa ecs gost +http2 libressl python redis selinux static-libs systemd test threads"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 RESTRICT="!test? ( test )"