gentoo Easter resync : 12.04.2020

4 files changed, 232 insertions, 11 deletions

diff --git a/net-dns/avahi/Manifest b/net-dns/avahi/Manifest
index 0ed16f7f4b8b..bfde7c7c3a1d 100644
--- a/net-dns/avahi/Manifest
+++ b/net-dns/avahi/Manifest
@@ -7,7 +7,9 @@ AUX avahi-0.7-python3.patch 2810 BLAKE2B 523515d5d324e5b74d60abbdbc88469fec55ce3
 AUX avahi-0.7-qt5.patch 6033 BLAKE2B 10c7879f6e28942a32497c84dcf523f742cb13112d9e9c23f74967c2d6c05e6f463406716c144edc1bd4588c8c76693473765d9d678f6517c4a57615d0364b91 SHA512 cd8b900a5a068add3b7aa9080491938d469795c26e1a1869ee581b95d877ded4d120cb4db768fb4d97535a72e66c3fabf6617cdca2c9bdb50ff54e24d17b1f51
 AUX avahi-0.7-remove-empty-avahi_discover.patch 2593 BLAKE2B 0fddfd46a3fc3e66960e7c2b6028e825e703e2e3f5b3d672dc204e37b87d101bffa285857c5dc41c69fc03bb3e7935fdec774492a31d4ce59ed9b06c4a0a20f4 SHA512 7bdd2ec5f16fb2850a78c983d35ca1d76b6e0d45eb17267213d3fb95b07d213f042bfa9ae07fd16b6334cc4459c5e87ae28942db69cb1987a074d6e787f19f70
 DIST avahi-0.7.tar.gz 940047 BLAKE2B 8299577bf27ee65fad5d743dbf94202b148a6fc86825cae303f94c44482eea07cf6570d970ca286e81a787d6a64598b7123f2ac17a259ddc50ef431b9c94b530 SHA512 61f656da7614d8cca1862180038f571db3474c84f05db4d3509f614cdbf8b1a1047661b7e24d63682d5b48ed1bfa1b08b3c9e6dbe9222bcd62d99bc168a11abe
-EBUILD avahi-0.7-r2.ebuild 5259 BLAKE2B f730b961de58a8df4ab0ba9f2d35f7461d6c12291a349884fe62ffab205c3dbf9c9e0cc4fc9a4edd3f741533ea02e27024f5bf5794345d6619bad6f11835019b SHA512 0e5be607cce829fa4fc6280a005c6a2cfe0f9649439735c763a9a931aac26253d7987705a130835cd9c6a25bd5d9f47021f02c85eb86d223db73021b9a5bf45b
+DIST avahi-0.8.tar.gz 953319 BLAKE2B ddede1b8790ff3057ea5f4bb710e95578229e078a7abac83121e043017dda1ab3d971c723f920fdd4f3d98b88bd2cf21f9645bec1b7bbd2ea194cb399a5f5b46 SHA512 27bba9a551152dfc7e721f326042e7bfce55d227044a6cbaee04d6fb0e3f59c36e159c2b7a4dd42d1c955cdf37cc1c303e91991c08928bbded91d796e9a22abe
+EBUILD avahi-0.7-r2.ebuild 5260 BLAKE2B 6f90b55386b45cc491790ecea1f858ecfc682880cf463ff142a6ca921838b45a667d8cf453ce621b8532d108d64d97a840fd37cf9db4c6689f925381f3b301af SHA512 564eb6e982eb5d5750a2011187c340b54bbfc78f7d5e928b5841f0a54c98b54af0fa22c8cbacb7809ecc5f5259b93a858b27e9145f0cf0ba2b12574dcef05c75
 EBUILD avahi-0.7-r4.ebuild 5215 BLAKE2B 0d387cb0af825bd7813bdf0f99bdfbc83dc8f7f69a4c0e374bf0ff51522074453197f659019395cb4efcc50719b56c6206eade55c7ce28e075d70c48a140e2aa SHA512 ac32afae86f2347d0961978b8189345e0bb2ff9feda118f2075be148d8dcdb02da591ed5e93d417a2d8a050e206fb2ba6729e8f22422bed7bc052791c8587556
 EBUILD avahi-0.7-r5.ebuild 5337 BLAKE2B 315366bd28af27c4b3c718dbad3fde275a141831fa42b0c6bee76338295846d5ad7ab7964b41c8fec66b2c2fd22c2fa82aaaf2413b3fbf6bcf8719c1b7fe9c57 SHA512 69da22a77a5d3da0232a03a3f8ef09d9dcfe31e3c6fc0d9fc14cbe94affe6891d41607d9ae2d42b4c818a13813ada698dcd80c1ffb4c79357f8801fae355664f
-MISC metadata.xml 935 BLAKE2B 890b4a3ab97241ba254dcf68b97a6a8b2ae4af914dc2348b8eb9d6c3182c1d2dfbd5eca8dac009e30f4662b88001c159ac5479a100bfc48a956ac2d603b6343e SHA512 7d2114e25574532405b5ff6db66b833aef68772d5b699d8885e9f1005a1785298e5b71288a858572a1270c6a4d9d2ad98aac7f79f4df6713dea79778280c82d8
+EBUILD avahi-0.8-r2.ebuild 5449 BLAKE2B f483042160766dd30df2e95f305bae5bda4467f2e18c2c0a9c35da4cf405bd4c6b03bc5fa49698a78671036e1b7ca344ac0c4fb7262099074ae0be5ceefa256a SHA512 0615d12dfcd747456fdc9696da4733b11f5c245bb65a3a4f2abf4f527c95af02d3aaabef80093f97727a9e629d984c4172bd1703aaa4eccfbafb99225031b058
+MISC metadata.xml 1381 BLAKE2B 8cb0652562c645d37af7992e3c7aef13b2188b0f3747ff08c79a3da42b004e848690b2587253e9aab17ffb90c72bdd5de6f055310499b26f22a6e125d1ac4a39 SHA512 6ba95a2a869bffeb5df08db973b4154749f668500b004fb6f0a08f829ab1528e8366ba6cc0a0c005055e84d361432f62998eea944085c312d7c7adfe4c7b6af7
diff --git a/net-dns/avahi/avahi-0.7-r2.ebuild b/net-dns/avahi/avahi-0.7-r2.ebuild
index 7455288a1d55..90fbd6a1d881 100644
--- a/net-dns/avahi/avahi-0.7-r2.ebuild
+++ b/net-dns/avahi/avahi-0.7-r2.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://github.com/lathiat/avahi/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~s390 sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86"
 IUSE="autoipd bookmarks dbus doc gdbm gtk gtk3 howl-compat +introspection ipv6 kernel_linux mdnsresponder-compat mono nls python qt5 selinux test"
 RESTRICT="!test? ( test )"
 
diff --git a/net-dns/avahi/avahi-0.8-r2.ebuild b/net-dns/avahi/avahi-0.8-r2.ebuild
new file mode 100644
index 000000000000..6f09403c3f26
--- /dev/null
+++ b/net-dns/avahi/avahi-0.8-r2.ebuild
@@ -0,0 +1,220 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="gdbm"
+inherit autotools flag-o-matic multilib-minimal mono-env python-r1 systemd
+
+DESCRIPTION="System which facilitates service discovery on a local network"
+HOMEPAGE="http://avahi.org/"
+SRC_URI="https://github.com/lathiat/avahi/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc ~x86"
+IUSE="autoipd bookmarks +dbus doc gdbm gtk gtk2 howl-compat +introspection ipv6 kernel_linux mdnsresponder-compat mono nls python qt5 selinux systemd test"
+
+REQUIRED_USE="
+	python? ( dbus gdbm ${PYTHON_REQUIRED_USE} )
+	mono? ( dbus )
+	howl-compat? ( dbus )
+	mdnsresponder-compat? ( dbus )
+	systemd? ( dbus )
+"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/libdaemon
+	dev-libs/libevent:=[${MULTILIB_USEDEP}]
+	dev-libs/expat
+	dev-libs/glib:2[${MULTILIB_USEDEP}]
+	gdbm? ( sys-libs/gdbm:=[${MULTILIB_USEDEP}] )
+	qt5? ( dev-qt/qtcore:5 )
+	gtk2? ( x11-libs/gtk+:2[${MULTILIB_USEDEP}] )
+	gtk?  ( x11-libs/gtk+:3[${MULTILIB_USEDEP}] )
+	dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
+	kernel_linux? ( sys-libs/libcap )
+	introspection? ( dev-libs/gobject-introspection:= )
+	mono? (
+		dev-lang/mono
+		gtk2? ( dev-dotnet/gtk-sharp:2 )
+	)
+	python? (
+		${PYTHON_DEPS}
+		dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+		introspection? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )
+	)
+	bookmarks? (
+		${PYTHON_DEPS}
+		>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	acct-user/avahi
+	acct-group/avahi
+	acct-group/netdev
+	autoipd? (
+		acct-user/avahi-autoipd
+		acct-group/avahi-autoipd
+	)
+	${DEPEND}
+	selinux? ( sec-policy/selinux-avahi )
+"
+BDEPEND="
+	dev-util/glib-utils
+	doc? ( app-doc/doxygen )
+	app-doc/xmltoman
+	dev-util/intltool
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+MULTILIB_WRAPPED_HEADERS=( /usr/include/avahi-qt5/qt-watch.h )
+
+# These patches do not apply cleanly but may need to be re-instated.
+# I'll leave them commented out for now.
+#PATCHES=(
+#	"${FILESDIR}/${PN}-0.7-qt5.patch"
+#	"${FILESDIR}/${PN}-0.7-CVE-2017-6519.patch"
+#	"${FILESDIR}/${PN}-0.7-remove-empty-avahi_discover.patch"
+#	"${FILESDIR}/${PN}-0.7-python3.patch"
+#	"${FILESDIR}/${PN}-0.7-python3-unittest.patch"
+#	"${FILESDIR}/${PN}-0.7-python3-gdbm.patch"
+#)
+
+pkg_setup() {
+	use mono && mono-env_pkg_setup
+	use python || use bookmarks && python_setup
+}
+
+src_prepare() {
+	default
+
+	if ! use ipv6; then
+		sed -i \
+			-e "s/use-ipv6=yes/use-ipv6=no/" \
+			avahi-daemon/avahi-daemon.conf || die
+	fi
+
+	sed -i \
+		-e "s:\\.\\./\\.\\./\\.\\./doc/avahi-docs/html/:../../../doc/${PF}/html/:" \
+		doxygen_to_devhelp.xsl || die
+
+	eautoreconf
+
+	# bundled manpages
+	multilib_copy_sources
+}
+
+src_configure() {
+	# those steps should be done once-per-ebuild rather than per-ABI
+	use sh && replace-flags -O? -O0
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local myconf=(
+		--disable-monodoc
+		--disable-python-dbus
+		--disable-qt3
+		--disable-qt4
+		--disable-static
+		--enable-manpages
+		--enable-glib
+		--enable-gobject
+		--enable-xmltoman
+		--localstatedir="${EPREFIX}/var"
+		--with-distro=gentoo
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+		$(use_enable dbus)
+		$(use_enable gdbm)
+		$(use_enable gtk2 gtk)
+		$(use_enable gtk  gtk3)
+		$(use_enable howl-compat compat-howl)
+		$(use_enable mdnsresponder-compat compat-libdns_sd)
+		$(use_enable nls)
+		$(multilib_native_use_enable autoipd)
+		$(multilib_native_use_enable doc doxygen-doc)
+		$(multilib_native_use_enable introspection)
+		$(multilib_native_use_enable mono)
+		$(multilib_native_use_enable python)
+		$(multilib_native_use_enable test tests)
+	)
+
+	if use python; then
+		myconf+=(
+			$(multilib_native_use_enable dbus python-dbus)
+			$(multilib_native_use_enable introspection pygobject)
+		)
+	fi
+
+	if use mono; then
+		myconf+=( $(multilib_native_use_enable doc monodoc) )
+	fi
+
+	if ! multilib_is_native_abi; then
+		myconf+=(
+			# used by daemons only
+			--disable-libdaemon
+			--with-xml=none
+		)
+	fi
+
+	myconf+=( $(multilib_native_use_enable qt5) )
+
+	econf "${myconf[@]}"
+}
+
+multilib_src_compile() {
+	emake
+
+	multilib_is_native_abi && use doc && emake avahi.devhelp
+}
+
+multilib_src_install() {
+	emake install DESTDIR="${D}"
+	use bookmarks && use python && use dbus && use gtk2 || \
+		rm -f "${ED}"/usr/bin/avahi-bookmarks
+
+	# https://github.com/lathiat/avahi/issues/28
+	use howl-compat && dosym avahi-compat-howl.pc /usr/$(get_libdir)/pkgconfig/howl.pc
+	use mdnsresponder-compat && dosym avahi-compat-libdns_sd/dns_sd.h /usr/include/dns_sd.h
+
+	if multilib_is_native_abi && use doc; then
+		docinto html
+		dodoc -r doxygen/html/.
+		insinto /usr/share/devhelp/books/avahi
+		doins avahi.devhelp
+	fi
+
+	# The build system creates an empty "/run" directory, so we clean it up here
+	rmdir "${ED}"/run || die
+}
+
+multilib_src_install_all() {
+	if use autoipd; then
+		insinto /lib/rcscripts/net
+		doins "${FILESDIR}"/autoipd.sh
+
+		insinto /lib/netifrc/net
+		newins "${FILESDIR}"/autoipd-openrc.sh autoipd.sh
+	fi
+
+	dodoc docs/{AUTHORS,NEWS,README,TODO}
+
+	find "${ED}" -name '*.la' -type f -delete || die
+}
+
+pkg_postinst() {
+	if use autoipd; then
+		elog
+		elog "To use avahi-autoipd to configure your interfaces with IPv4LL (RFC3927)"
+		elog "addresses, just set config_<interface>=( autoipd ) in /etc/conf.d/net!"
+		elog
+	fi
+
+	systemd_reenable avahi-daemon.service
+}
diff --git a/net-dns/avahi/metadata.xml b/net-dns/avahi/metadata.xml
index dab8c0571291..0832dd78f287 100644
--- a/net-dns/avahi/metadata.xml
+++ b/net-dns/avahi/metadata.xml
@@ -6,15 +6,14 @@
 		<name>Anthony G. Basile</name>
 	</maintainer>
 	<use>
-		<flag name="autoipd">Build and install the IPv4LL (RFC3927) network address
-		configuration daemon</flag>
-		<flag name="bookmarks">Install the avahi-bookmarks application (requires
-		<pkg>dev-python/twisted-core</pkg> and <pkg>dev-python/twisted-web</pkg>)</flag>
+		<flag name="autoipd">Build and install the IPv4LL (RFC3927) network address configuration daemon</flag>
+		<flag name="bookmarks">Install the avahi-bookmarks application (requires <pkg>dev-python/twisted</pkg>)</flag>
 		<flag name="howl-compat">Enable compat libraries for howl</flag>
-		<flag name="gtk3">Build the avahi-ui-gtk3 library, and use gtk3 for the
-		avahi utilities under USE=utils</flag>
-		<flag name="mdnsresponder-compat">Enable compat libraries for
-		mDNSResponder</flag>
+		<flag name="gtk"  restrict="&lt;net-dns/avahi-0.8-r2">Use gtk2 for the avahi utilities (overridden by USE=gtk3) and build the avahi-ui library</flag>
+		<flag name="gtk3" restrict="&lt;net-dns/avahi-0.8-r2">Use gtk3 for the avahi utilities (overrides USE=gtk) and build the avahi-ui-gtk3 library</flag>
+		<flag name="gtk2" restrict="&gt;=net-dns/avahi-0.8-r2">Use gtk2 for the avahi utilities (overridden by USE=gtk) and build the avahi-ui library</flag>
+		<flag name="gtk"  restrict="&gt;=net-dns/avahi-0.8-r2">Use gtk3 for the avahi utilities (overrides USE=gtk2) and build the avahi-ui-gtk3 library</flag>
+		<flag name="mdnsresponder-compat">Enable compat libraries for mDNSResponder</flag>
 	</use>
 	<upstream>
 		<remote-id type="github">lathiat/avahi</remote-id>